 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
CPS0204
註冊時間: 2014-08-24
文章: 482
第 1 樓
|
 發表於: 星期一 二月 29, 2016 7:22 pm 文章主題: 如何快速分解字串 |
 |
|
例:客戶代碼a;客戶代碼b;客戶代碼c;
如何求得一個欄位為 cust_no c(最長為10碼) 的cursor
例:原字元不定長度,最後一碼不管有無;
可能為 a001,或a001;.............希望求得a001 一筆資料錄
或a001;b15............希望求得a001,b15兩筆資料錄
或a01;c3;d00008;e033;a01 ........希望求得a01,c3,d00008,e033等四筆資料錄.重覆的去除
請問應如何設計?謝謝 |
|
| 回頂端 |
|
 |
perry
註冊時間: 2014-07-20
文章: 203
第 2 樓
|
| 發表於: 星期一 二月 29, 2016 7:51 pm 文章主題: |
|
|
如果您資料區分是[ ; ]的話,試試下面這個方式!!
| 代碼: |
priv aa,bb,cc,dd,j1,j2,i
aa='a01;d800a;c03;a01;cc002;c03'
*前後�[識別碼
bb=IIF(left(aa,1)=';','',';')+aa+iif(righ(aa,1)=';','',';')
sele 0
crea curs test (cust_no c(10))
cc=occu(';',aa) &&計算識別碼總數
for i=1 to cc-1
j1=at(';',aa,i)
j2=at(';',aa,i+1)
*取出客戶代號
dd=subs(aa,j1+1,j2-j1-1)
inse into test valu (dd)
next
sele 0
sele cust_no from test grou by cust_no into curs testx
go top
brow
use in testx
use in test
|
|
|
| 回頂端 |
|
|
CPS0204
註冊時間: 2014-08-24
文章: 482
第 3 樓
|
| 發表於: 星期一 二月 29, 2016 7:55 pm 文章主題: OK |
|
|
| 當中的bb好像沒用到? |
|
| 回頂端 |
|
|
perry
註冊時間: 2014-07-20
文章: 203
第 4 樓
|
| 發表於: 星期二 三月 01, 2016 6:27 am 文章主題: |
|
|
寫太快沒改到= ='''
| 代碼: |
.
.
cc=occu(';',bb) &&計算識別碼總數
for i=1 to cc-1
j1=at(';',bb,i)
j2=at(';',bb,i+1)
*取出客戶代號
dd=subs(bb,j1+1,j2-j1-1)
inse into test valu (dd)
next
.
.
|
要這樣才能正常截取字串!! |
|
| 回頂端 |
|
|
syntech
註冊時間: 2003-05-16
文章: 4252
來自: Taipei,Taiwan
第 5 樓
|
| 發表於: 星期二 三月 01, 2016 9:54 am 文章主題: |
|
|
http://stevenblack.com/articles/text-and-string-handling-in-VFP/
VFP 7 : WORDS(),WORDNUM()
VFP 9 : GETWORDNUM(),GETWORDCOUNT()
| 代碼: |
Str_a = 'a01;c3;d00008;e033;a01 ........'
Str_Count = GETWORDCOUNT(Str_a,';')
for i=1 to Str_Count
? GETWORDNUM(Str_a,i,';')
next
|
---
其實我是剛剛才知道的,
PHP 有 split() 可以用,
但是 不知道VFP 有沒有類似的可以用.
GOOGLE一下,發現VFP7以上有提供類似函式
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
|
oldbb
註冊時間: 2007-02-28
文章: 83
第 6 樓
|
| 發表於: 星期三 三月 02, 2016 8:04 am 文章主題: |
|
|
FOR i = 1 TO ALINES(aSS, "a01;c3;d00008;e033;a01 ........", ";")
? aSS[i]
ENDFOR |
|
| 回頂端 |
|
|
ezpos
註冊時間: 2011-04-20
文章: 323
第 7 樓
|
| 發表於: 星期三 三月 09, 2016 12:01 am 文章主題: |
|
|
Declare aryInfo[3]
getstr2array(@aryInfo,tcInfo)
**********************************
* 用途:字串轉陣列.taArray需用傳址方式
* 參數:
* 傳值:
* 範例:
**********************************
Function getstr2array(taArray,tcStr,tcDelimitor,tnColCnt)
If Para()<4
tnColCnt=1
Endif
If Para()<3
tcDelimitor=','
Endif
Local lnRowCnt,lnStartPos,lnLenght,i,J,lnDCnt,lnElementCnt
lnElementCnt=Occurs(tcDelimitor,tcStr)+1
lnRowCnt=Ceiling( (lnElementCnt)/tnColCnt )
Dimension taArray[lnRowCnt,tnColCnt]
tcStr=Iif( Left(tcStr,1)=tcDelimitor,'',tcDelimitor) +tcStr + ;
IIF( Right(tcStr,1)=tcDelimitor,'',tcDelimitor)
lnDCnt=1
For i=1 To lnRowCnt
For J=1 To tnColCnt
If lnDCnt>lnElementCnt
taArray[i,j]=''
Else
lnStartPos=At(tcDelimitor,tcStr,lnDCnt) + 1
lnLenght=At(tcDelimitor,tcStr,lnDCnt+1) - lnStartPos
taArray[i,j]=Subs(tcStr,lnStartPos,lnLenght)
Endif
lnDCnt=lnDCnt+1
Endfor
Endfor
Endfunc
_________________
ezPos收銀機 簡單好用低成本 http://www.ezpos.info
全新美觀的POS收銀機.POS軟硬體耗材.
軟體客制化.網站規劃....能賺錢的都可以找我
http://www.twelife.com 台灣生活網 |
|
| 回頂端 |
|
|
perry
註冊時間: 2014-07-20
文章: 203
第 8 樓
|
| 發表於: 星期三 三月 09, 2016 6:43 am 文章主題: |
|
|
若只是要字串去掉重複的,
自己開發沒版本限制的函數才實際!!
| 代碼: |
proc exacstr
lpar data_str,data_deli
priv aa,bb,cc,dd,j,j1,j2
if para()<1 or vartype(data_str)#'C'
retu
endi
data_deli=iif(para()<2,',',data_deli)
aa=iif(left(data_str,1)=data_deli,'',data_deli)+allt(data_str)+iif(righ(data_str,1)=data_deli,'',data_deli)
bb=occu(data_deli,aa)
store '' to cc,dd
for j=1 to bb-1
j1=at(data_deli,aa,j)+1
j2=at(data_deli,aa,j+1)
cc=allt(subs(aa,j1,j2-j1))
dd=dd+iif(at(data_deli+cc+data_deli,data_deli+dd)<1,cc+data_deli,'')
next
retu dd
|
aa='a01;d800a;c03;a01;cc002;c03'
aa=exacstr(aa,';')
?aa
** 題外話
自行開發的功能 如:獨立的下拉式功能選單以 .prg 方式
只要所有變數物件名稱定義為 私有(Private)
依 Window 特性,可重複(VFP容許的記憶體範圍內)無限同時執行,
彼此變數值不會干擾!!
| 代碼: |
** tsk24.prg
proc tsk24
lpar xomy_str
priv my_str
my_str=iif(para()<1,1,iif(vartype(xomy_str)#'N',1,xomy_str))
?my_str
do tsk241 with my_str
?my_str
|
| 代碼: |
**tsk241.prg
proc tsk241
lpar xomy_str
priv my_str
my_str=iif(para()<1,1,iif(vartype(xomy_str)#'N',1,xomy_str))
my_str=my_str+1
if my_str<5
?my_str
do tsk24 with my_str
endi
|
當您執行 do tsk24 看看會發生什麼事 |
|
| 回頂端 |
|
|
perry
註冊時間: 2014-07-20
文章: 203
第 9 樓
|
| 發表於: 星期四 三月 10, 2016 11:18 pm 文章主題: |
|
|
dd=dd+iif(at(data_deli+cc+data_deli,data_deli+dd)<1,cc+data_deli,'')
資料長度不一致,要改成這樣,比對時才不會誤判= ='''
aa='001;003;01;200;00;040;0003;0200;001'
bb=exacstr(aa,';')
?bb |
|
| 回頂端 |
|
|
lygcw9603
註冊時間: 2011-12-25
文章: 130
第 10 樓
|
| 發表於: 星期五 三月 15, 2024 8:55 pm 文章主題: |
|
|
| 試試：alines() |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
