VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

MS Access MDB to VFP tables

Summary

Well it started when I found it hard to check rtf files for MSDN subscription index. In last few shipments there were also an MDB in 'UN-SUPPED' directory but my Access is too perfect to use an MDB < g > so I decided to get Access data to VFP tables.

Description

For anyone interested it's also a simple demonstration of converting MDB tables to VFP tables (Here in his particular case I was only dealing with tables, if you want you can access < bg > other as well - VIEW and SYSTEM TABLES. To do that you'd only change ['TABLE'] to something like ['TABLE','VIEW'] But be aware if you also include SYSTEM TABLES you get their names in myMDB cursor however you shouldn't try to execute following SQLEXEC on them).

lcDataBaseName = 'MSDN'
lcMDBDir = 'C:\My Documents\MSDN CD SUBCRIPTION INDEXES\UN-SUPPED'
lcMDBName = 'MSDN APRIL CD SUBCRIPTION INDEX.MDB'
lnConnHandle = SQLSTRINGCONNECT('DSN=MS Access Database;DBQ='+;
lcMDBDir+'\'+lcMDBName+';DefaultDir='+;
lcMDBDir+';DriverId=25;FIL=MS Access;MaxBufferSize=2048;'+;
'PageTimeout=5;UID=admin;')
Create data (lcDataBaseName)
SQLTABLES(lnConnHandle, ['TABLE'], 'myMDB')
Select myMDB
Scan
lcSQL = 'select * from "'+trim(table_name)+'"'
lcCursor = chrtran(trim(table_name),' ','_')
lcTableName = '_'+lcCursor
SQLEXEC(lnConnHandle,lcSQL,lcCursor)
Select (lcCursor)
Copy to (lcTableName)
Add table (lcTableName)
Endscan
SQLDISCONNECT(lnConnHandle)
Modi data
Once you have data in a VFP database you know what to do with it :)

Ruey · 發表於: 星期四六月 05, 2003 2:05 pm 文章主題:

作者Jacky
來源程式設計俱樂部
*********** ConvertAccessDataToVFPData.prg**************
******************* 2003/04/12 ************************
******************** by Jacky *************************
*****************************************************
********************範例說明*************************
***以下範例不需要更動任何程式碼，僅修改檔案名稱即可，
***即 lcDatabaseName_Access, lcTableName_Access,
***lcDatabaseName_VFP 及 lcTableName_VFP。
***它將自動把Access資料轉成VFP資料，
***並自動產生VFP資料庫及資料表格，
***您可以COPY以下程式碼來使用，並把它存成 .prg 檔。
***要知道，用 .prg 檔來轉檔遠比 .scx 檔快得多，
***若資料量龐大，其間差異就非常明顯．．．
***若資料不多，數秒內就轉檔完成
*********************** 程式開始 ******************************
CLOSE DATABASE ALL
SET SAFETY OFF
*********************** 只需修改下列檔案名稱 ****************
lcDatabaseName_Access = "C:\Access檔案\test.mdb" && 把它改成您欲轉檔的Access資料庫(database)
lcTableName_Access = "Table_Access" && 把它改成您欲轉檔的Access資料表格(table)
lcDatabaseName_VFP = "Database_VFP" && 把它改成您心目中的資料庫名稱
lcTableName_VFP = "Table_VFP" && 把它改成您心目中的資料表格名稱
=ConvertAccessToVFP(lcDatabaseName_Access, lcTableName_Access, lcDatabaseName_VFP, lcTableName_VFP)
CLOSE ALL
******************** 以下不必更動 **************************
PROCEDURE ConvertAccessToVFP
PARAMETER cDatabaseName_Access, cTableName_Access, cDatabaseName_VFP, cTableName_VFP

Insertion = .F.
PRIVATE cString
cString = "DRIVER=Microsoft Access Driver (*.mdb);"
cString = cString + "DBQ=" + cDatabaseName_Access

cHandle=SQLSTRINGCONNECT(cString) && 連結並開啟 Access 資料庫
Insertion = .F.
IF cHandle < 0
=MessageBox("連接不上", 48, "注意")
return
ELSE
cSQLString = "SELECT * FROM " + cTableName_Access && SQL查詢字串
=SQLEXEC(cHandle, cSQLString , "temp") && 執行SQL查詢，並將結果儲存於 CURSOR "temp" 中
=SQLDisconnect(cHandle) && 中斷與Access資料庫連結
SELECT temp
IF RECCOUNT() = 0
=MessageBox("查無資料", 48 , "注意")
ELSE
BROWSE NOMODIFY && 先瀏覽Access資料表格內容
Insertion = .T.
ENDIF
ENDIF

IF Insertion = .T.
SELECT temp
********* 函數說明 ***********
*FCount()-----為獲取 Field的數量的函數
*Field()----為獲取Field的名稱的函數
*FSize()-------為獲取Field的位元數的函數
*Type()---------為獲取Field的型態的函數
*****************************
*建立資料庫：
CREATE DATABASE &cDatabaseName_VFP
*建立VFP資料表格，它自動加入資料庫中
cCreateTableString = "CREATE TABLE &cTableName_VFP ( "
FOR i = 1 TO FCount()
DO CASE
CASE i = FCount()
cCreateTableString = cCreateTableString + Field(i) + " " ;
+ Type(Field(i)) + "(" ;
+ ALLTRIM(STR(FSize(Field(i)))) + "))"
OTHERWISE
cCreateTableString = cCreateTableString + Field(i) + " " ;
+ Type(Field(i)) + "(" ;
+ ALLTRIM(STR(FSize(Field(i)))) + "),"
ENDCASE
ENDFOR
&cCreateTableString && 執行 CREATE TABLE 命令
*******************************************
SELECT temp
nFieldCount = FCount()
DIMENSION FieldName(nFieldCount), FieldContents (nFieldCount) &&宣告二個陣列
FOR i = 1 TO nFieldCount
FieldName( i ) = FIELD( i ) &&把欄位名稱儲存於陣列中
ENDFOR
************** 偵測螢幕 pixels ***************
nSreenHeight = SYSMETRIC(2) &&螢幕寬度
DO CASE
CASE nSreenHeight = 768
nRows = 25
nCols = 75
CASE nSreenHeight = 600
nRows = 20
nCols = 55
OTHERWISE
nRows = 25
nCols = 70
ENDCASE
************** 開始轉檔 ***************
SELECT temp
WAIT WINDOW AT nRows, nCols "轉檔中，請稍候．．．" NOWAIT
SCAN
FOR i = 1 TO nFieldCount
STORE &FieldName( i ) TO FieldContents(i) && 把欄位內容儲存於陣列中
ENDFOR
SELECT &cTableName_VFP
APPEND BLANK
FOR i = 1 TO nFieldCount
IF NOT IsNull(FieldContents(i))
REPLACE &FieldName( i ) WITH FieldContents(i)
ENDIF
ENDFOR
ENDSCAN
***************大功告成，驗收成果 **************
WAIT WINDOW AT nRows, nCols - 5 "大功告成，可以驗收成果了！" NOWAIT
SELECT &cTableName_VFP
BROWSE && 瀏覽轉檔後的VFP資料表內容是否與Access一致
ENDIF
***************** 程式結束 ***********************

　　

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 3 樓

Dbc與Mdb互轉的工具

Ruey · 發表於: 星期四六月 12, 2003 1:32 pm 文章主題:

access原碼

Rita · 註冊時間: 2003-04-16 文章: 38 第 5 樓

公司業務上要將dbf的資料轉到業務部處理,
目前是用access裏的匯入功能,不知那位朋友寫過類似vfp的轉檔程式
能幫我們解決這個不方便又不科學的作法
謝謝

saint · 註冊時間: 2003-07-14 文章: 211 第 6 樓

nelsonchuang · 註冊時間: 2003-09-04 文章: 564 來自: 臺灣 第 7 樓

Rita · 註冊時間: 2003-04-16 文章: 38 第 8 樓

謝謝各位的幫忙!!

公司的業務是每日有就要執行一次資料更新,
所以有3個部門就要手動轉3次
這種作法可以改進
所以想碰碰運氣看有無好友遇到過同樣的問題