VFP 愛用者社區

[sunghsia]

******************************************
* 拷備至 *.PRG 檔
*****************************************


ouserform=CREATEOBJECT("userform")
ouserform.SHOW

DEFINE CLASS userform AS form
CAPTION="Form1"
CURRENTX=51
CURRENTY=110
DRAWWIDTH=1
FORECOLOR=0
HEIGHT=201
LEFT=95
NAME="Form1"
TOP=52
VISIBLE=.T.
WIDTH=201
_S1=100
_S2=100
_M1=100
_M2=100
_H1=100
_H2=100

ADD OBJECT Timer1 AS Timer WITH ;
HEIGHT=0,;
INTERVAL=100,;
LEFT=0,;
NAME="Timer1",;
TOP=0,;
WIDTH=0

PROCEDURE ACTIVATE
store 100 to x, y
this.circle(100,100,100)
for s=0 to 59 && 繪刻度
x1 = x + (100 * Sin(S * 6 * 0.01745))
y1 = y + (100 * -Cos(S * 6 * 0.01745))
x2 = x + (90 * Sin(S * 6 * 0.01745))
y2 = y + (90 * -Cos(S * 6 * 0.01745))
this.drawwidth= iif(mod(s,5)=0,3,1)
this.line(x1,y1 , x2,y2)
endfor
READ EVENTS
ENDPROC


PROCEDURE CLICK
Clear Events
thisform.Release
ENDPROC


PROCEDURE Timer1.TIMER
store 100 to x , y
H=val(left(time(),2)) && 時
M=val(substr(time(),4,2)) && 分
S=val(right(time(),2)) &&秒
IF THIS.INTERVAL<500
S=S+VAL(RIGHT(SYS(3),3))/1000
ENDIF


X1 = x + (80 * Sin(S * 6 * 0.01745))
y1 = y + (80 * -Cos(S * 6 * 0.01745))
x2 = x + (77 * Sin((M +S/60)*6 * 0.01745))
y2 = y + (77 * -COS((M +S/60)*6 * 0.01745))
x3 = x + (55 * Sin((H + M / 60) * 30 * 0.01745))
y3 = Y + (55 * -Cos((H + M / 60) * 30 * 0.01745))

thisform.forecolor = thisform.backcolor
thisform.line(x,y , thisform._S1,thisform._S2)
thisform.line(x,y , thisform._M1,thisform._M2)
thisform.line(x,y , thisform._H1,thisform._H2)

thisform.forecolor= 0
thisform.line(x,y , x1,y1)
thisform.line(x,y , x2,y2)
thisform.line(x,y , x3,y3)

thisform._S1 = x1
thisform._S2 = y1
thisform._M1 = x2
thisform._M2 = y2
thisform._H1 = x3
thisform._H2 = y3

thisform.caption= time() + " 點擊時鐘離開"
ENDPROC

ENDDEFINE