 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 1 樓
|
 發表於: 星期一 九月 01, 2003 9:06 pm 文章主題: 生成EXCEL檔完整示例(轉貼) |
 |
|
生成EXCEL檔完整示例
| 代碼: | ****************************************
* 生成EXCEL檔完整示例 *
* 1.0 2003.06.13 *
* 雅狐論壇 www.yafox.com *
****************************************
CLOSE DATABASES all
CREATE CURSOR yafox (dm C(4),mc C(10),bz C(40))
INSERT INTO yafox (dm,mc,bz) valueS ("xwy","許文遠","xuwy@21cn.com")
INSERT INTO yafox (dm,mc,bz) valueS ("fox","雅狐論壇"," www.yafox.com")
FOR i=1 TO 100
INSERT INTO yafox (dm,mc,bz) valueS (TRANSFORM(i,"@l 9999"),SUBSTR(SYS(2015),2),"")
NEXT
WAIT "正在訪問 Excel 軟體……" WINDOW NOWAIT
ExcelSheet = GetObject('','Excel.Sheet')
If Type("ExcelSheet")#'O'
WAIT CLEAR
MessageBox( "訪問Excel失敗！請檢查你的系統是否正確安裝 Excel 軟體！",48,"Excel不正常")
RETURN .f.
ENDIF
WAIT "正在�]置Excel，請稍侯…" WINDOW NOWAIT
ExcelApp = ExcelSheet.APPLICATION
*�]置工作區
ExcelApp.VISIBLE = .f.
ExcelApp.ActiveWindow.WindowState = 2
ExcelActiveSheet = ExcelApp.ActiveSheet
ExcelActiveSheet.Name = "yafox"
*�]置頁面資訊
ExcelActiveSheet.PageSetup.PaperSize =9
ExcelActiveSheet.PageSetup.TopMargin =32 *2.84
ExcelActiveSheet.PageSetup.BottomMargin =18 *2.84
ExcelActiveSheet.PageSetup.LeftMargin =19 *2.84
ExcelActiveSheet.PageSetup.RightMargin =19 *2.84
ExcelActiveSheet.PageSetup.HeaderMargin =22 *2.84
ExcelActiveSheet.PageSetup.FooterMargin =13 *2.84
ExcelActiveSheet.PageSetup.Orientation =1
ExcelActiveSheet.PageSetup.PrintTitleRows = "$2:$2"
ExcelActiveSheet.PageSetup.PrintTitleColumns="$A:$A"
ExcelActiveSheet.PageSetup.RightHeader = "&9 許文遠 (C)"
ExcelActiveSheet.PageSetup.CenterFooter = "&9 第 &"+"P 頁 / 共 &"+"N 頁"
ExcelActiveSheet.PageSetup.RightFooter = "&9 www.yafox.com"
ExcelActiveSheet.PageSetup.CenterHorizontally = .t.
ExcelActiveSheet.PageSetup.CenterVertically = .f.
*創建Excel列印格式
If FCOUNT("yafox")>26
ExcelEndColunm=Chr(Int((FCOUNT("yafox")-1)/26)+64)+;
Chr(FCOUNT("yafox")%26+64)
Else
ExcelEndColunm=Chr(FCOUNT("yafox")+64)
ENDIF
ExcelActiveSheet.Rows("1:2").HorizontalAlignment= 3
ExcelActiveSheet.Rows("1:2").VerticalAlignment = 2
ExcelActiveSheet.Rows("1").ShrinkToFit = .t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Name = "宋體"
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Size = 11
ExcelActiveSheet.Rows("1").Font.Size = 13
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Bold = .f.
ExcelActiveSheet.Rows("1:2").Font.Bold = .t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Italic = .f.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Font.Underline = .f.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).WrapText=.t.
ExcelActiveSheet.Columns("A:"+ExcelEndColunm).Orientation =0
ExcelActiveSheet.Columns("A"+ExcelEndColunm).NumberFormatLocal = ""
ExcelActiveSheet.Columns("A").RowHeight = 14
ExcelActiveSheet.Rows("1").RowHeight = 16
ExcelActiveSheet.Columns("A").ColumnWidth = 5
ExcelActiveSheet.Columns("B").ColumnWidth = 10
ExcelActiveSheet.Columns("C").ColumnWidth = 40
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(1).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(2).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(3).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+ALLTRIM(STR(2+RECCOUNT()))).Borders(4).Weight = 2
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(1).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(2).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(3).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"2").Borders(4).Weight = 3
ExcelActiveSheet.Range("A1:"+ExcelEndColunm+"1").MergeCells = .t.
WAIT "正在輸出資料……" WINDOW NOWAIT
*輸出數值
ExcelActiveSheet.Cells( 1, 1).value = "Excel表格生成演示"
ExcelActiveSheet.Cells( 2, 1).value = "代碼"
ExcelActiveSheet.Cells( 2, 2).value = "名稱"
ExcelActiveSheet.Cells( 2, 3).value = "備註"
SCAN
FOR i=1 TO FCOUNT()
ExcelActiveSheet.Cells( 2+RECNO() , i).value = EVALUATE(FIELD(i))
NEXT
ENDSCAN
WAIT CLEAR
ExcelApp.VISIBLE = .t.
MESSAGEBOX("生成Excel完畢")
ExcelApp.ActiveWorkbook.SaveAs("C:\yafox")
ExcelApp.ActiveWorkbook.close
ExcelApp.quit && 關閉Excel
release ExcelSheet
****************************************
*各參數的功能不再此處解釋了,如果需要參見以下貼子
*頁面格式�]置篇 http://www.yafox.com/dispbbs.asp?boardID=7&ID=91
*單元格格式�]置篇 http://www.yafox.com/dispbbs.asp?boardID=7&ID=122 |
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!
學會VFP使用者社區的搜尋,Code才會更有趣~
############################# |
|
| 回頂端 |
|
 |
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
