 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 1 樓
|
 發表於: 星期六 十二月 29, 2007 3:24 pm 文章主題: [討論] 擷取 ODBC 資料來源名稱及其驅動程式說明清單 |
 |
|
由於我公司準備將 DBF 轉到 SQL Server (總算要弄出 SQL 版了)，雖然寫 VFP 已 8 年半了，始終沒機會碰 DBC，所以這方面的經驗
是一隻大菜鳥，更惶論 SQL Server 了。
首先要將 DBF 資料上移到 SQL Server，雖然 VFP 有 [上移 SQL Server] 精靈可用，但客戶遍佈全省各地，我想若用它做資料上移，
想想總是怪怪的 (在客戶那裏 Step By Step ？而且一次一種 DBC 上移，想想就要喊天啊！)，因為我想由程式自動控制，整批一次轉
換完畢。雖然此精靈可用 DO ... WITH ...，它提供了 9 個參數 (它應該有提供非視覺化執行功能才對)，但打開其 Source，真的是
看天書 (應該是沒耐心看吧)，找不到該 9 個參數的詳細使用說明。若有人知道該 9 個參數如何使用請不吝告知，這樣就可以省了這
個事，在此先跟您說聲感謝。
下面這個自定函數是由 [上移 SQL Server] 精靈的 Source 中擷取改寫出來的 (也參考了微軟線上提供的範例)，寫完後不是我想要的
那個，不過既然寫了，也覺得它應該有地方可以用吧 (如果各位有用得上，能不能告知我用在何處，讓我能多了解)，其中
SQLDataSources 的參數說明，是根據其使用結果，自己加上的說明而已，若有不對也煩請告知我。
程式碼及執行範例如下：
| 代碼: | CLEAR
DIMENSION M_aODBCDataSource(1,2)
=F1_GetODBCDataSourceList("M_aODBCDataSource")
FOR W1_SUB_A = 1 TO ALEN(M_aODBCDataSource,1)
? "DSN = "+M_aODBCDataSource(W1_SUB_A,1)
? "說明 = "+M_aODBCDataSource(W1_SUB_A,2)
?
ENDFOR
FUNCTION F1_GetODBCDataSourceList(L_cArrayName AS String)
* 功能：擷取 ODBC 資料來源名稱及其驅動�{式說明清單
* -------------------------------------------------------------------------- *
* 參數名稱 型態 說明
* -------------- ---- ------------------------------------------------------
* Input:
* L_cArrayName C 1.�}列名稱。代表要接收 DSN 資訊的�}列名稱。
* 2.此�}列變數需事前宣告。
* 3.本函數執行完畢後會將資料來源名稱及其驅動�{式說明清單
* 存入 L_cArrayName 所代表的 n × 2 �}列中。
* -------------------------------------------------------------------------- *
LOCAL W1_nODBCEnv AS Number, W1_iDSNMax AS Integer, W1_iDSNLength AS Integer, W1_iDSNDescMax AS Integer,;
W1_iDSNDescLength AS Integer, W1_iFetchDirection AS Integer, W1_iReturnValue AS Integer,;
W1_cDataSourceName AS String, W1_cDSNDescription AS String, W1_iArrayDim AS Integer, W1_cArrayDim AS String
L_cArrayName = ALLTRIM(L_cArrayName)
#DEFINE SQL_FETCH_FIRST 2
#DEFINE SQL_FETCH_NEXT 1
#DEFINE SQL_SUCCESS 0
#DEFINE MAX_STRING 128
DECLARE INTEGER SQLDataSources IN ODBC32.DLL ;
INTEGER henv, ; && ODBC 環境控制代碼 (由 VAL(SYS(3053)) 取得)
SHORT fdirection, ; && 從目前所在記錄向下抓取第幾個資料來源的資訊
STRING @szDSN, ; && 資料來源的名稱
INTEGER cbDSNMax, ; && �]定抓取 [資料來源名稱] 字串的最大字元數
INTEGER @pcbDSN, ; && 抓取後之 [資料來源名稱] 字串的實際總長度
STRING @szDescription, ; && 與該資料來源相關的驅動�{式說明
INTEGER cbDescriptionMax, ; && �]定抓取 [驅動�{式說明] 字串的最大字元數
INTEGER @pcbDescriptionn && 抓取後之 [驅動�{式說明] 字串的實際總長度
W1_nODBCEnv = VAL(SYS(3053))
W1_iFetchDirection = SQL_FETCH_FIRST && 第一筆的資料來源是空白，所以從第 2 筆�}始抓取
W1_iDSNMax = MAX_STRING
W1_iDSNLength = 0
W1_iDSNDescMax = MAX_STRING
W1_iDSNDescLength = 0
DIMENSION &L_cArrayName.(1,2)
STORE "" TO (L_cArrayName+"(1,1)")
STORE "無任何 ODBC 資料來源" TO (L_cArrayName+"(1,2)")
W1_iArrayDim = 1
W1_iReturnValue = SQL_SUCCESS && 從沒有錯誤�}始
DO WHILE (W1_iReturnValue = SQL_SUCCESS)
W1_cDataSourceName = SPACE(MAX_STRING+1) && 確�{有足夠的空間
W1_cDSNDescription = SPACE(MAX_STRING+1)
W1_iReturnValue = SQLDataSources(W1_nODBCEnv, W1_iFetchDirection, @W1_cDataSourceName, W1_iDSNMax, ;
@W1_iDSNLength, @W1_cDSNDescription, W1_iDSNDescMax, @W1_iDSNDescLength)
W1_iFetchDirection = SQL_FETCH_NEXT && 下一次要抓取的位置
IF W1_iReturnValue = SQL_SUCCESS THEN && 如果沒有錯誤發生
W1_iArrayDim = W1_iArrayDim + 1
W1_cArrayDim = LTRIM(STR(W1_iArrayDim))
DIMENSION &L_cArrayName.(W1_iArrayDim,2)
STORE LEFT(W1_cDataSourceName, W1_iDSNLength) TO (L_cArrayName+"("+W1_cArrayDim+",1)")
STORE LEFT(W1_cDSNDescription, W1_iDSNDescLength) TO (L_cArrayName+"("+W1_cArrayDim+",2)")
ENDIF
ENDDO
IF W1_iArrayDim > 1
STORE "尚未指定 ODBC 資料來源" TO (L_cArrayName+"(1,2)")
ENDIF
CLEAR DLLS "SQLDataSources"
RETURN .T.
|
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
 |
garfield
Site Admin
註冊時間: 2003-01-30
文章: 2157
第 2 樓
|
|
| 回頂端 |
|
|
syntech
註冊時間: 2003-05-16
文章: 4212
來自: Taipei,Taiwan
第 3 樓
|
| 發表於: 星期一 十二月 31, 2007 2:02 pm 文章主題: |
|
|
garfield 兄的做法與我的相同.
我覺得這樣比較簡單.
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 4 樓
|
| 發表於: 星期一 十二月 31, 2007 3:00 pm 文章主題: |
|
|
我沒辦法先在公司建立一個空SQL Server的 DataBase，因為我的客戶到底使用了多少個系統，且它到底有幾家分公司，有些 Table 是按年檔先逐年分割的。這都造成沒法先建立空SQL Server的 DataBase，必須在客戶現有狀況下即時處理。
原則上我應該有頭緒了，我想我集中在 [紅狐論壇] 來統一討論。
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
syntech
註冊時間: 2003-05-16
文章: 4212
來自: Taipei,Taiwan
第 5 樓
|
| 發表於: 星期一 十二月 31, 2007 4:20 pm 文章主題: |
|
|
當然也可以由DBF structure 產生 create table 的命令,
配合spt 也可以轉.
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
|
saint
註冊時間: 2003-07-14
文章: 211
第 6 樓
|
| 發表於: 星期一 十二月 31, 2007 11:39 pm 文章主題: |
|
|
| 可是我還是不解你不能先建立空的DATABSE 是什麼意思，如果由你們公司所賣出去的，難道會不知道結構？所以這和我在紅狐所回覆的是一樣的，沒錯！你是不知道客戶用了多少系統，但是理論上你們還是會知道現場的情形，就算是按年分的檔案，你不也是可以到現場後，由你們的介面來決定要如何搬資料。我說這一段是可以不用寫死，而在 SERVER端建立資料表，這一段可以利用SCRIPT 來完成，這一點應該是沒有問題的，我的重點是，對於資料上傳的這一個動作，也許可以不用寫的那麼好，可以留一點空間加入手動的設定，再由程式來完成它。 |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
