 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
syntech
註冊時間: 2003-05-16
文章: 4212
來自: Taipei,Taiwan
第 16 樓
|
 發表於: 星期一 九月 24, 2012 2:01 pm 文章主題: |
 |
|
那就在報表上列印出標線格線就好,
不需要使用者拿尺在螢幕量.
以報表為準,
7樓不就是這個意思.
另一種方式是列印時加入底色,
例如在GRID中常常看到單數筆什麼色,偶數筆什麼色.
當然轉EXCEL就更清楚.
這種情況下,花點心思把EXCEL表作漂亮比較快.
直接在EXCEL表上加入邊框及色彩.
---
大多數VFP開發者對WINDOWS 如何繪製畫面沒甚麼概念,
很容易把事情想得太簡單,
其實VFP真的就是適合處理資料,
其他的花俏功能最好當作辦不到比較快.
技術細節不想多說. ^_^
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
 |
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 17 樓
|
| 發表於: 星期一 九月 24, 2012 3:37 pm 文章主題: |
|
|
| 搜尋了一下，我覺得，這似乎是Crystal Report的功能？(不確定啦) |
|
| 回頂端 |
|
|
LiuRambo
註冊時間: 2007-11-27
文章: 481
第 18 樓
|
| 發表於: 星期二 十月 02, 2012 11:21 pm 文章主題: |
|
|
報表上加線條應該是很常有的事
而且要去控制何時該出現虛線、實線 甚至雙實線
這樣就可以達到不會搞混 又能讓使用者看得清楚
我們以前的報表一定是4條虛線+1條實線 尤其是A3橫式報表 沒線根本沒辦法看
個人覺得User只是單純"不想看錯" 但這十字功能絕對不是她真正想要的 |
|
| 回頂端 |
|
|
garfield
Site Admin
註冊時間: 2003-01-30
文章: 2157
第 19 樓
|
| 發表於: 星期三 十月 03, 2012 2:37 pm 文章主題: |
|
|
問題很單純, 答案很簡單, 只要隨著滑鼠移動時出現填滿畫面的十字線即可.
使用者順著線看資料比較不會看歪掉.
在form.init 加上這些程式碼
thisform.AddObject('mouselinex','shape')
thisform.AddObject('mouseliney','shape')
thisform.mouselinex.width = 1
thisform.mouselinex.top=1
thisform.mouselinex.height = thisform.Height
thisform.mouseliney.left=1
thisform.mouseliney.width = thisform.Width
thisform.mouseliney.height = 1
thisform.mouselinex.visible=.t.
thisform.mouseliney.visible=.t.
在form.mousemove 加上這些程式碼
LPARAMETERS nButton, nShift, nXCoord, nYCoord
thisform.mouselinex.left = nXCoord
thisform.mouselinex.height=thisform.height
thisform.mouselinex.BorderStyle= MOD(nXCoord,5)+1
thisform.mouseliney.top=nYCoord
thisform.mouseliney.width = thisform.Width
thisform.mouseliney.BorderStyle=MOD(nYCoord,5)+1
_________________
利用>>搜尋<<的功能會比問的還要快得到答案. |
|
| 回頂端 |
|
|
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 20 樓
|
| 發表於: 星期三 十月 03, 2012 3:31 pm 文章主題: |
|
|
| 但，他的問題是在報表預覽時有十字線，而非 Form 上看十字線。 |
|
| 回頂端 |
|
|
yctsai
註冊時間: 2003-04-11
文章: 179
第 21 樓
|
| 發表於: 星期三 十月 03, 2012 4:10 pm 文章主題: |
|
|
1.感謝 garfield,效果很棒,終於有知音
2.感謝 ckp6250,我的問題是在報表預覽時有十字線，而非 Form 上看十字線
3.公布答案,找到一款軟體picpick,有類似十字線,但是garfield最好(picpick其它功能也很強大,可參考) |
|
| 回頂端 |
|
|
garfield
Site Admin
註冊時間: 2003-01-30
文章: 2157
第 22 樓
|
| 發表於: 星期三 十月 03, 2012 6:45 pm 文章主題: |
|
|
哇, 太天真以為很簡單, 其實有點難,
再秀另一個在form裡顯示report ,
但還是一樣在報表上看不到十字線,
| 代碼: |
*-- 報表預部份代碼
Set REPORTBEHAVIOR 90
lcReport=Home(2)+"Solution\Europa\EmployeesMD.frx"
oListener = Createobject('BaseReportListener')
olistener.PreviewContainer=Newobject([ReportForm])
Report Form (lcreport) Object oListener Nowait
*-- 報表預覽窗口
Define Class ReportForm As Form
AutoCenter = .T.
WindowState = 2
BorderStyle = 0
TitleBar = 0
WindowType = 1
BackColor = Rgb(65,65,65)
DataSession = 1
oListener = .Null.
nCurrentPage = 1
nPageHeight = 100
nPageWidth = 100
ScrollBars = 3
Width = 400
Height = 400
AllowOutput = .F.
oTools = .Null.
oGotoPage = .Null.
oPrint = .Null.
Add Object shpPreview As Shape With ;
Top = 10,;
Left = 10,;
Width = 300,;
Height = 300
Procedure Init
DoDefault()
With This As Form
.AddObject('mouselinex','shape')
.AddObject('mouseliney','shape')
.mouselinex.visible=.t.
.mouseliney.visible=.t.
.oTools = Createobject([frxpreviewtoolbar])
.oGotoPage = Createobject([frxgotopageform])
.oPrint = Createobject([frxPrintForm])
With .oTools
.Show()
Bindevent(This.oTools,[CboZooMInteractiveChange],This,[CboZooMInteractiveChange])
Bindevent(.cmdClose,[Click],This,[cmdCloseClick])
Bindevent(.cntPrev.cmdTop,[Click],This,[cmdTopClick])
Bindevent(.cntPrev.cmdPrev,[Click],This,[cmdPrevClick])
Bindevent(.CntNext.cmdNext,[Click],This,[cmdNextClick])
Bindevent(.CntNext.cmdBott,[Click],This,[cmdBottClick])
Bindevent(.cmdgotopage,[Click],This,[ActionGotoPage])
Bindevent(.cmdprint,[Click],This,[Print])
Endwith
.Refresh
Endwith
Endproc
Procedure mousemove
LPARAMETERS nButton, nShift, nXCoord, nYCoord
WITH this
.mouselinex.width = 3
.mouselinex.top=1
.mouselinex.height = .Height
.mouselinex.left = nXCoord
.mouselinex.height= .height
.mouselinex.BorderStyle= MOD(nXCoord,5)+1
.mouseliney.left=1
.mouseliney.width = .Width
.mouseliney.height = 3
.mouseliney.top=nYCoord
.mouseliney.width = .Width
.mouseliney.BorderStyle= MOD(nYCoord/2,2)*2+1
ENDWITH
Endproc
Procedure SetReport
Lparameters oListenerRef
This.oListener = oListenerRef &&將對ReportListener對象的引用保存到表單的oListener屬性中
Endproc
Procedure Show
Lparameters nStyle
With This
If Vartype(.oListener) = "O"
.nPageHeight = .oListener.GetPageHeight() / 10 &&獲得頁面的像素高度�]每英吋96DPI）
.nPageWidth = .oListener.GetPageWidth() / 10 &&獲得頁面的像素寬度
.shpPreview.Height = Int(.nPageHeight) &&�]置形狀的高度
.shpPreview.Width = Int(.nPageWidth) &&�]置形狀的寬度
.Caption = "報表預覽�{序-" + .oListener.CommandClauses.File &&標題中�]含有報表的文件名稱
.Refresh
Endif
DoDefault(nStyle) &&執行默�{的Show方法行為
Endwith
Endproc
Procedure Paint
With This
If Vartype(.oListener)="O"
.oListener.OutputPage(.nCurrentPage,.shpPreview,2)
Endif
.CmdRefresh()
Endwith
Endproc
*-- 按扭的可用狀態
Procedure CMDRefresh
With This
.oTools.cntPrev.cmdPrev.Enabled = Vartype(.oListener) = 'O' And .nCurrentPage > 1
.oTools.cntNext.cmdNext.Enabled = Vartype(.oListener) = 'O' And .nCurrentPage < .oListener.OutputPageCount
.oTools.cntPrev.cmdTop.Enabled = Vartype(.oListener) = 'O' And .nCurrentPage > 1
.oTools.cntNext.cmdBott.Enabled = Vartype(.oListener) = 'O' And .nCurrentPage < .oListener.OutputPageCount
Endwith
Endproc
Procedure QueryUnload
With This
If Vartype(This.oListener) = 'O'
.oListener.PreviewContainer = .Null. &&釋放對報表預覽�{序對象的引用
.oListener.OnPreviewClose(.F.) &&關閉預覽
Endif
.oListener = .Null.
Endwith
Endproc
*-- 最前頁
Procedure cmdTopClick
With Thisform
.nCurrentPage = 1
.oListener.OutputPage(1, .shpPreview, 2) &&顯示第一頁
.CmdRefresh() &&�]置按鈕的可用狀態
* .txtPage.Value = 1
Endwith
Endproc
*-- 前一頁
Procedure cmdPrevClick
With Thisform
.nCurrentPage = .nCurrentPage - 1 &&當前報表頁號減1
.oListener.OutputPage(.nCurrentPage, .shpPreview, 2) &&顯示指定頁
.CmdRefresh() &&�]置按鈕的可用狀態
* .txtPage.Value = .nCurrentPage
Endwith
Endproc
*-- 後一頁
Procedure cmdNextClick
With Thisform
.nCurrentPage = .nCurrentPage + 1 &&當前報表頁號減1
.oListener.OutputPage(.nCurrentPage, .shpPreview, 2) &&顯示指定頁
.CmdRefresh() &&�]置按鈕的可用狀態
*.txtPage.Value = .nCurrentPage
Endwith
Endproc
*-- 最後一頁
Procedure cmdBottClick
With Thisform
.nCurrentPage = .oListener.OutputPageCount
.oListener.OutputPage(.nCurrentPage, .shpPreview, 2) &&顯示最後一頁
.CmdRefresh() &&�]置按鈕的可用狀態
* .txtPage.Value = .nCurrentPage
Endwith
Endproc
*-- 指定頁
Procedure ActionGotoPage
With Thisform
.oTools.Enabled = .F.
.oGoToPage.PageNo = .nCurrentPage
.oGoToPage.PageTotal = .oListener.OutputPageCount
.oGotoPage.Show()
If .oGoToPage.PageNo >= 1 And .oGoToPage.PageNo <= .oListener.OutputPageCount
.nCurrentPage = .oGoToPage.PageNo
.oListener.OutputPage(.nCurrentPage, .shpPreview, 2)
Thisform.CMDRefresh
Else
=Messagebox("頁號無效或已經超出了總頁數",0+48,"提示")
Endif
.oTools.Enabled = .T.
Endwith
Endproc
*-- 關閉按扭
Procedure cmdCloseClick
With Thisform
If Vartype(.oListener) = 'O'
.oListener.PreviewContainer = .Null.
.oListener.OnPreviewClose(.F.)
Endif
.oListener = .Null.
.Release()
Endwith
Endproc
*-- 更改顯示比例
Procedure CboZooMInteractiveChange
Lparameters vVal
With Thisform
If Vartype(.oListener) = "O"
.shpPreview.Height = Int(.nPageHeight * Val(vVal) /100)
.shpPreview.Width = Int(.nPageWidth * Val(vVal) /100)
.oListener.OutputPage(.nCurrentPage, .shpPreview, 2)
Endif
Endwith
Endproc
*-- 打印
Procedure Print
With Thisform
.oTools.Enabled = .F.
.oPrint.PageNo = .nCurrentPage
.oPrint.PageTotal = .oListener.OutputPageCount
.oPrint.Show()
If .oPrint.PrintOk = .T.
Do Case
*-- 打印所有的頁
Case .oPrint.opgPrint.Value = 1 &&打印所有頁
.oListener.CommandClauses.PrintRangeFrom = 1
.oListener.CommandClauses.PrintRangeTo = .oListener.OutputPageCount
*-- 打印當前頁
Case .oPrint.opgPrint.Value = 2
.oListener.CommandClauses.PrintRangeFrom = .nCurrentPage
.oListener.CommandClauses.PrintRangeTo = .nCurrentPage
*-- 打印頁碼範圍
Case .oPrint.opgPrint.Value = 3
.oListener.CommandClauses.PrintRangeFrom = .oPrint.spnPageNoFrom.Value
.oListener.CommandClauses.PrintRangeTo = .oPrint.spnPageNoTo.Value
ENDCASE
WAIT WINDOW [請稍候,系統正在進行打印處理......] NOWAIT
.oListener.PreviewContainer = .Null. &&取消對預覽�{序對象的引用
.oListener.OnPreviewClose(.T.) &&輸出到打印機
.oListener = .Null.
.Release &&關閉表單
Endif
.oTools.Enabled = .T.
.Refresh
Endwith
Endproc
Enddefine
Define Class PreToolbarCommandButton As CommandButton
Height = 22
Width = 23
Top = 0
SpecialEffect = 2
Caption=[]
Enddefine
Define Class BaseReportListener As ReportListener
ListenerType = 1 &&�]置輸出模式
OutputType = 1 &&輸出類型
DynamicLineHeight = .F.
Enddefine
Define Class ReportText As TextBox
Top = 1
Width = 35
Enddefine
*
Define Class CntPrevClass As PreContainert
Add Object cmdtop As PreToolbarCommandButton With ;
Left = 0, ;
Picture = "prefirst.bmp", ;
ToolTipText = [最前頁], ;
Name = "cmdTop"
Add Object cmdPrev As PreToolbarCommandButton With ;
Left = 23, ;
Picture = "preprev.bmp", ;
ToolTipText = "上一頁", ;
Name = "cmdPrev"
Enddefine
Define Class CntNextClass As PreContainert
Add Object cmdNext As PreToolbarCommandButton With ;
Left = 0, ;
Picture = "prenext.bmp", ;
ToolTipText = "下一頁", ;
Name = "cmdNext"
Add Object cmdBott As PreToolbarCommandButton With ;
Top = 0,;
Left = 23,;
Picture = "prelast.bmp",;
ToolTipText = "最後頁",;
Name = "cmdBott"
Enddefine
Define Class frxpreviewtoolbar As Toolbar
Caption = "報表預覽工具條"
Height = 28
KeyPreview = .T.
Left = 0
Top = 0
Width = 564
ShowWindow = 1
previewform = .Null.
specialmousexcoord = 0
Name = "frxpreviewtoolbar"
Movable = .F.
Alias=[]
DataTool = .T.
Add Object cntprev As CntPrevClass With ;
Top = 3, ;
Left = 5, ;
Width = 46, ;
Height = 22, ;
BorderWidth = 0, ;
Name = "cntPrev"
Add Object separator1 As Separator With ;
Top = 3, ;
Left = 58, ;
Height = 0, ;
Width = 0, ;
Name = "Separator1"
Add Object cmdgotopage As PreToolbarCommandButton With ;
Top = 3, ;
Left = 58, ;
Height = 22, ;
Width = 100, ;
Picture = "gotopage.bmp", ;
Caption = " 指定頁", ;
ToolTipText = "指定頁", ;
PicturePosition = 1, ;
Name = "cmdGoToPage"
Add Object separator3 As Separator With ;
Top = 3, ;
Left = 165, ;
Height = 0, ;
Width = 0, ;
Name = "Separator3"
Add Object cntnext As CntNextClass With ;
Top = 3, ;
Left = 165, ;
Width = 46, ;
Height = 22, ;
BorderWidth = 0, ;
Name = "cntNext"
Add Object separator2 As Separator With ;
Top = 3, ;
Left = 218, ;
Height = 0, ;
Width = 0, ;
Name = "Separator2"
Add Object cbozoom As ComboBox With ;
Height = 22, ;
Left = 218, ;
Style = 2, ;
TabStop = .F., ;
ToolTipText = "選擇頁面縮放比例", ;
Top = 3, ;
DisplayCount = 5, ;
RowSourceType = 1,;
RowSource=[25,50,100,150,200,300,400,500],;
Value= [100],;
Name = "cboZoom"
Add Object separator4 As Separator With ;
Top = 3, ;
Left = 325, ;
Height = 0, ;
Width = 0, ;
Name = "Separator4"
Add Object opgpagecount As OpgPageCountClass With ;
ButtonCount = 3, ;
BorderStyle = 0, ;
Height = 22, ;
Left = 325, ;
Top = 3, ;
Width = 77, ;
Name = "opgPageCount"
Add Object separator5 As Separator With ;
Top = 3, ;
Left = 409, ;
Height = 0, ;
Width = 0, ;
Name = "Separator5"
Add Object cmdclose As PreToolbarCommandButton With ;
Top = 3, ;
Left = 409, ;
Height = 22, ;
Width = 75, ;
Picture = "preclose.bmp", ;
Caption = " 關閉", ;
ToolTipText = "關閉預覽", ;
PicturePosition = 1, ;
Name = "cmdClose"
Add Object cmdprint As PreToolbarCommandButton With ;
Top = 3, ;
Left = 484, ;
Height = 22, ;
Width = 75, ;
Picture = "print.bmp", ;
Caption = " 打印", ;
ToolTipText = "打印報表", ;
PicturePosition = 1, ;
Name = "cmdPrint"
Procedure Init
DoDefault()
With This
.Dock(0)
Endwith
Endproc
Procedure CboZoom.InteractiveChange
This.Parent.CboZooMInteractiveChange(This.Value)
Endproc
Procedure CboZooMInteractiveChange
Lparameters vVal
Endproc
Enddefine
*
*-- EndDefine: frxpreviewtoolbar
**************************************************
Define Class PreContainert As Container
Width = 200
Height = 112
BackStyle = 0
Name = "PreContainert"
Procedure Error
Lparameters nError, cMethod, nLine
This.Parent.Error( nError, cMethod, nLine )
Endproc
Procedure SetFocus
Local oControl
For Each oControl In This.Controls
If Type("oControl.TabIndex") = "N"
If oControl.TabIndex = 1
If Pemstatus( m.oControl,"setFocus",5)
oControl.SetFocus()
Nodefault
Endif
Exit
Endif
Endif
Endfor
Endproc
Procedure RightClick
This.Parent.RightClick()
Endproc
Enddefine
*-- 多頁顯示
Define Class OpgPageCountClass As BaseOptiongroup
Add Object Opt1 As BaseOptionButton With ;
Picture = "1page.bmp", ;
PicturePosition = 13, ;
Caption = "", ;
Height = 38, ;
Left = 0, ;
SpecialEffect = 2, ;
Style = 1, ;
ToolTipText = "一 頁", ;
Top = 0, ;
Width = 32, ;
AutoSize = .F., ;
Name = "Opt1"
Add Object Opt2 As BaseOptionButton With ;
Picture = "2page.bmp", ;
PicturePosition = 13, ;
Caption = "", ;
Height = 38, ;
Left = 25, ;
SpecialEffect = 2, ;
Style = 1, ;
ToolTipText = "兩 頁", ;
Top = 0, ;
Width = 32, ;
AutoSize = .F., ;
Name = "Opt2"
Add Object Opt3 As BaseOptionButton With ;
Picture = "4page.bmp", ;
PicturePosition = 13, ;
Caption = "", ;
Height = 38, ;
Left = 50, ;
SpecialEffect = 2, ;
Style = 1, ;
ToolTipText = "四 頁", ;
Top = 0, ;
Width = 32, ;
AutoSize = .F., ;
Name = "Opt3"
Enddefine
*-- 跳轉到指定頁
Define Class frxgotopageform As Form
WindowType = 1
AutoCenter = .T.
Height = 92
Width = 345
ShowWindow = 1
DoCreate = .T.
BorderStyle = 2
Closable = .F.
MaxButton = .F.
MinButton = .F.
*-- Provides the current page number for report output.
PageNo = 0
*-- Provides a PageTotal for report output.
PageTotal = 0
Name = "frxgotopageform"
Caption = [指定頁]
Add Object shp1 As Shape With ;
Top = 15, ;
Left = 12, ;
Height = 66, ;
Width = 224, ;
BackStyle = 0, ;
ZOrderSet = 0, ;
Style = 3, ;
Name = "Shp1"
Add Object spnpageno As BaseSpinner With ;
Height = 21, ;
InputMask = "9999", ;
Left = 52, ;
Top = 36, ;
Width = 138, ;
ZOrderSet = 1, ;
Name = "spnPageno"
Add Object lblcaption As Label With ;
AutoSize = .T.,;
Caption = "跳轉至頁", ;
Left = 20, ;
Top = 8, ;
ZOrderSet = 2, ;
Style = 3, ;
Name = "lblCaption"
Add Object cmdok As PreToolbarCommandButton With ;
Top = 16, ;
Left = 252, ;
Height = 23,;
Width = 75,;
Caption = "確 定", ;
Default = .T., ;
ZOrderSet = 3, ;
Name = "cmdOK"
Add Object cmdcancel As PreToolbarCommandButton With ;
Top = 49, ;
Left = 252, ;
Height = 23,;
Width = 75,;
Cancel = .T., ;
Caption = "取 消", ;
ZOrderSet = 4, ;
Name = "cmdCancel"
Procedure Show
Lparameters nStyle
This.spnPageNo.SpinnerLowValue = 1
This.spnPageNo.SpinnerHighValue = This.PageTotal
*THIS.spnPageNo.KeyboardLowValue = 1
*THIS.spnPageNo.KeyboardHighValue = THIS.pageTotal
This.spnPageNo.Value = This.PageNo
DoDefault(nStyle)
Endproc
Procedure cmdok.Click
This.Parent.PageNo = This.Parent.spnPageNo.Value
This.Parent.Hide()
Endproc
Procedure cmdcancel.Click
This.Parent.Hide()
Endproc
Enddefine
*-- 打印選擇頁
Define Class frxPrintForm As Form
WindowType = 1
AutoCenter = .T.
Height = 155
Width = 345
ShowWindow = 1
DoCreate = .T.
BorderStyle = 2
Closable = .F.
MaxButton = .F.
MinButton = .F.
PrintOk = .F.
*-- Provides the current page number for report output.
PageNo = 0
*-- Provides a PageTotal for report output.
PageTotal = 0
Name = "frxgotopageform"
Caption = [打印]
Add Object shp1 As Shape With ;
Top = 15, ;
Left = 12, ;
Height = 125, ;
Width = 224, ;
BackStyle = 0, ;
ZOrderSet = 0, ;
Style = 3, ;
Name = "Shp1"
Add Object lblcaption As Label With ;
AutoSize = .T.,;
Caption = "頁碼範圍", ;
Left = 20, ;
Top = 8, ;
ZOrderSet = 2, ;
Style = 3, ;
Name = "lblCaption"
Add Object opgPrint As opgPrintClass With ;
Left =30, ;
Top =36
Add Object spnpagenoFrom As BaseSpinner With ;
Height = 21, ;
InputMask = "9999", ;
Left = 30, ;
Top = 105, ;
Width = 80, ;
ZOrderSet = 1, ;
Name = "spnPagenoFrom"
Add Object lblTo As Label With ;
AutoSize = .T.,;
Caption = "至", ;
Left = 115, ;
Top = 108, ;
ZOrderSet = 2, ;
Style = 3, ;
Name = "lblNo"
Add Object spnpagenoTo As BaseSpinner With ;
Height = 21, ;
InputMask = "9999", ;
Left = 130, ;
Top = 105, ;
Width = 80, ;
ZOrderSet = 1, ;
Name = "spnPagenoTo"
Add Object cmdok As PreToolbarCommandButton With ;
Top = 16, ;
Left = 252, ;
Height = 23,;
Width = 75,;
Caption = "打 印", ;
Default = .T., ;
ZOrderSet = 3, ;
Name = "cmdOK"
Add Object cmdcancel As PreToolbarCommandButton With ;
Top = 49, ;
Left = 252, ;
Height = 23,;
Width = 75,;
Cancel = .T., ;
Caption = "取 消", ;
ZOrderSet = 4, ;
Name = "cmdCancel"
Procedure Show
Lparameters nStyle
With This
.opgPrint.value = 1
.spnPageNoFrom.SpinnerLowValue = 1
.spnPageNoFrom.SpinnerHighValue = .PageTotal
.spnPageNoFrom.Value = .PageNo
.spnPageNoTo.SpinnerLowValue = 1
.spnPageNoTo.SpinnerHighValue = .PageTotal
.spnPageNoTo.Value = .PageTotal
.PrintOk = .F.
Endwith
DoDefault(nStyle)
Endproc
Procedure cmdok.Click
* This.Parent.PageNo = This.Parent.spnPageNo.Value
With This.Parent
If .opgPrint.Value = 3
If .spnPageNoFrom.Value > .spnPageNoTo.Value
=Messagebox("終止頁號�]置無效！", 48, "提示")
Return 0
Endif
Endif
.PrintOk = .T.
.Hide()
Endwith
Endproc
Procedure cmdcancel.Click
This.Parent.Hide()
Endproc
Enddefine
Define Class OpgPrintClass As BaseOptiongroup
BorderStyle = 0
Value = 1
Add Object Opt1 As BaseOptionButton With ;
PicturePosition = 13, ;
Caption = "全部", ;
Left = 0, ;
SpecialEffect = 2, ;
ToolTipText = "打印所有頁", ;
Top = 0, ;
AutoSize = .T., ;
Name = "Opt1"
Add Object Opt2 As BaseOptionButton With ;
PicturePosition = 13, ;
Caption = "當前頁", ;
Height = 38, ;
Left = 0, ;
SpecialEffect = 2, ;
ToolTipText = "打印當前頁", ;
Top = 22,;
AutoSize = .T., ;
Name = "Opt2"
Add Object Opt3 As BaseOptionButton With ;
PicturePosition = 13, ;
Caption = "頁碼範圍", ;
Left = 0, ;
SpecialEffect = 2, ;
ToolTipText = "請輸入頁碼範圍", ;
Top = 44, ;
AutoSize = .T., ;
Name = "Opt3"
Enddefine
*-- 微調框
Define Class BaseSpinner As Spinner
Height = 21
KeyboardLowValue = 0
SelectOnEntry = .T.
SpinnerLowValue = 0.00
Width = 121
incomingvalue = 0
Name = "spn"
Procedure resetincoming
This.incomingValue = This.Value
Endproc
Procedure LostFocus
If This.incomingValue <> This.Value
This.action()
Endif
Endproc
Procedure UpClick
If This.incomingValue <> This.Value
This.action()
This.resetIncoming()
Endif
Endproc
Procedure DownClick
If This.incomingValue <> This.Value
This.action()
This.resetIncoming()
Endif
Endproc
Procedure Error
Lparameters nError, cMethod, nLine
This.Parent.Error( nError, cMethod, nLine )
Endproc
Procedure GotFocus
This.resetIncoming()
Endproc
Procedure KeyPress
Lparameters iKey, iModifier
*----------------------------------
* Do not allow nulls to be entered
* with Ctrl-0 :
*----------------------------------
If m.iKey = 48 And 0 < Bitand( m.iModifier, 2 )
Nodefault
Endif
Endproc
Procedure action
Endproc
Procedure LostFocus
If This.Value < This.SpinnerLowValue
This.Value = 1
Endif
If This.Value > This.SpinnerHighValue
This.Value = This.SpinnerHighValue
Endif
DoDefault()
Endproc
Enddefine
*-- 選項按扭
Define Class BaseOptiongroup As OptionGroup
*MemberClassLibrary = "test.prg"
ButtonCount = 0
BackStyle = 0
BorderStyle = 1
Value = 0
Height = 66
Width = 117
Name = "opg"
*-- Specifies if the user can edit a control, or specifies if a table or view associated with a Cursor object allows updates.
ReadOnly = .F.
Procedure enabled_assign
Lparameter lEnabled
For Each optbut In This.Buttons
optbut.Enabled = m.lEnabled
Endfor
Endproc
Procedure readonly_assign
Lparameter lReadOnly
*
* Returning .F. in each button's .When() produces
* a more visually acceptable effect:
*
*for each optbut in this.Buttons
* optbut.Enabled = not m.lReadOnly
*endfor
This.ReadOnly = m.lReadOnly
Endproc
*-- Sets the focus to a control.
Procedure SetFocus
*----------------------------------------------------
* SetFocus() in containers doesn't work so well. This
* compensates for that bug by doing it manually:
*----------------------------------------------------
Local oControl
For Each oControl In This.Buttons
If oControl.TabIndex = 1
oControl.SetFocus()
Nodefault
Exit
Endif
Endfor
Endproc
Procedure RightClick
This.Parent.RightClick()
Endproc
Procedure Error
Lparameters nError, cMethod, nLine
This.Parent.Error( nError, cMethod, nLine )
Endproc
Enddefine
*-- 選項組
Define Class BaseOptionbutton As OptionButton
Caption = "prompt"
Height = 15
Width = 52
AutoSize = .T.
Name = "opt"
Procedure Error
Lparameters nError, cMethod, nLine
This.Parent.Error( nError, cMethod, nLine )
Endproc
Procedure When
If This.Parent.ReadOnly
Return .F.
Else
Return .T.
Endif
Endproc
Procedure KeyPress
Lparameters iKey, iModifier
*----------------------------------
* Do not allow nulls to be entered
* with Ctrl-0 :
*----------------------------------
If m.iKey = 48 And 0 < Bitand( m.iModifier, 2 )
Nodefault
Endif
Endproc
Enddefine
**************************************************************************************************
*
*
**************************************************************************************************
*-- �{序名稱：RptPrint.prg
*-- �{序功能：以自定義的對話框顯示報表的打印�]置，以取代系統打印�]置的一些不足
*-- 使用方法：RptPrint ( [<cReportName>] )
* 或者：do RptPrint [ with <cReportName> ]
*-- �{序說明：cReportName 為 報表文件名�]無須帶擴展名），如果省略的話，則可顯示�]置對話框
* 報表的擴展名以 frx 為準
*-- 原創作者：紅虎
*-- 聯繫方式：E-mail: hu_feng@163.net
* HomePage: http://rts.coolbel.com
* Oicq: 1569040
*-- 編寫日期：2001年1月
Func RptPrint
para rptname
*-- 創建打印�]置對話框
oPrintSetup=createobject("printsetup")
oPrintSetup.show
*-- 定義打印�]置對話框
DEFINE CLASS printsetup AS form
Top = 11
Left = 115
Height = 270
Width = 531
Desktop = .T.
DoCreate = .T.
Caption = "報表打印�]置"
Name = "PRINTSETUP"
*-- 新增屬性
nxcoord = 0 && 可以使點擊對話框就可以拖動的坐標
nycoord = 0
rptname = "" && 報表的文件名
ADD OBJECT shape1 AS shape WITH ;
Top = 12, ;
Left = 12, ;
Height = 144, ;
Width = 504, ;
Enabled = .F., ;
SpecialEffect = 0, ;
Name = "Shape1"
ADD OBJECT label1 AS label WITH ;
AutoSize = .T., ;
Caption = "打印機", ;
Height = 16, ;
Left = 22, ;
Top = 9, ;
Width = 38, ;
Name = "Label1"
*-- 存放目前安裝的打印機的名稱列表
ADD OBJECT printerlist AS combobox WITH ;
Alignment = 0, ;
Height = 22, ;
Left = 112, ;
Style = 2, ;
Top = 33, ;
Width = 260, ;
Name = "PrinterList"
ADD OBJECT label2 AS label WITH ;
AutoSize = .T., ;
Caption = "打印機名(\<N)：", ;
Height = 16, ;
Left = 24, ;
Top = 36, ;
Width = 86, ;
Name = "Label2"
ADD OBJECT label3 AS label WITH ;
AutoSize = .T., ;
Caption = "狀態：", ;
Height = 16, ;
Left = 24, ;
Top = 60, ;
Width = 38, ;
Name = "Label3"
ADD OBJECT label4 AS label WITH ;
AutoSize = .T., ;
Caption = "類型：", ;
Height = 16, ;
Left = 24, ;
Top = 84, ;
Width = 38, ;
Name = "Label4"
ADD OBJECT label5 AS label WITH ;
AutoSize = .T., ;
Caption = "位置：", ;
Height = 16, ;
Left = 24, ;
Top = 108, ;
Width = 38, ;
Name = "Label5"
ADD OBJECT label6 AS label WITH ;
AutoSize = .T., ;
Caption = "紙張：", ;
Height = 16, ;
Left = 24, ;
Top = 132, ;
Width = 38, ;
Name = "Label6"
*-- 顯示打印機的位置的標籤
ADD OBJECT printerlocation AS label WITH ;
AutoSize = .T., ;
Caption = "PrinterLocation", ;
Height = 16, ;
Left = 112, ;
Top = 108, ;
Width = 92, ;
Name = "PrinterLocation"
ADD OBJECT cmdok AS commandbutton WITH ;
Top = 178, ;
Left = 442, ;
Height = 25, ;
Width = 66, ;
Caption = "確定", ;
Default = .T., ;
Name = "cmdOk"
*-- 打印機狀態標籤
ADD OBJECT printerstatus AS label WITH ;
AutoSize = .T., ;
Caption = "PrinterStatus", ;
Height = 16, ;
Left = 112, ;
Top = 60, ;
Width = 80, ;
Name = "PrinterStatus"
ADD OBJECT command1 AS commandbutton WITH ;
Top = 226, ;
Left = 442, ;
Height = 25, ;
Width = 66, ;
Cancel = .T., ;
Caption = "取消", ;
Name = "Command1"
ADD OBJECT shape5 AS shape WITH ;
Top = 171, ;
Left = 14, ;
Height = 84, ;
Width = 252, ;
Enabled = .F., ;
SpecialEffect = 0, ;
Name = "Shape5"
ADD OBJECT label11 AS label WITH ;
AutoSize = .T., ;
Caption = "打印範圍", ;
Height = 16, ;
Left = 24, ;
Top = 168, ;
Width = 50, ;
Name = "Label11"
ADD OBJECT shape6 AS shape WITH ;
Top = 170, ;
Left = 276, ;
Height = 84, ;
Width = 143, ;
Enabled = .F., ;
SpecialEffect = 0, ;
Name = "Shape6"
ADD OBJECT label12 AS label WITH ;
AutoSize = .T., ;
Caption = "份數", ;
Height = 16, ;
Left = 286, ;
Top = 167, ;
Width = 26, ;
Name = "Label12"
*-- 打印範圍選擇
ADD OBJECT optiongroup2 AS optiongroup WITH ;
AutoSize = .F., ;
ButtonCount = 3, ;
BackStyle = 0, ;
BorderStyle = 0, ;
Value = 1, ;
Enabled = .T., ;
Height = 62, ;
Left = 25, ;
Top = 184, ;
Width = 236, ;
Name = "Optiongroup2", ;
Option1.Caption = "全部(\<A)", ;
Option1.Value = 1, ;
Option1.Height = 16, ;
Option1.Left = 5, ;
Option1.Style = 0, ;
Option1.Top = 5, ;
Option1.Width = 69, ;
Option1.AutoSize = .T., ;
Option1.Name = "Option1", ;
Option2.Caption = "當前頁(\<E)", ;
Option2.Height = 16, ;
Option2.Left = 82, ;
Option2.Style = 0, ;
Option2.Top = 5, ;
Option2.Width = 81, ;
Option2.AutoSize = .T., ;
Option2.Name = "Option2", ;
Option3.Caption = "頁碼(\<G)", ;
Option3.Height = 16, ;
Option3.Left = 5, ;
Option3.Style = 0, ;
Option3.Top = 34, ;
Option3.Width = 69, ;
Option3.AutoSize = .T., ;
Option3.Name = "Option3"
*-- 打印起始頁
ADD OBJECT pbpage AS textbox WITH ;
Alignment = 3, ;
Value = 1, ;
Enabled = .F., ;
Height = 20, ;
InputMask = "9999", ;
Left = 120, ;
SelectOnEntry = .T., ;
Top = 219, ;
Width = 49, ;
Name = "pbpage"
*-- 打印分數
ADD OBJECT copy AS spinner WITH ;
Height = 20, ;
KeyboardLowValue = 1, ;
Left = 338, ;
SpinnerLowValue = 1.00, ;
Top = 192, ;
Width = 72, ;
Value = 1, ;
Name = "copy"
*-- 是否逐份打印,還是逐頁
ADD OBJECT check1 AS checkbox WITH ;
Top = 229, ;
Left = 338, ;
Height = 16, ;
Width = 69, ;
AutoSize = .T., ;
Caption = "逐份打印", ;
Value = .T., ;
Name = "Check1"
ADD OBJECT label14 AS label WITH ;
AutoSize = .T., ;
Caption = "份數(\<C)", ;
Height = 16, ;
Left = 288, ;
Top = 194, ;
Width = 50, ;
Name = "Label14"
*-- 結束頁數
ADD OBJECT pepage AS textbox WITH ;
Alignment = 3, ;
Value = _pepage, ;
Enabled = .F., ;
Height = 20, ;
InputMask = "9999", ;
Left = 196, ;
SelectOnEntry = .T., ;
Top = 219, ;
Width = 49, ;
Name = "pepage"
ADD OBJECT label15 AS label WITH ;
AutoSize = .T., ;
Caption = "從", ;
Height = 16, ;
Left = 104, ;
Top = 221, ;
Width = 14, ;
Name = "Label15"
ADD OBJECT label16 AS label WITH ;
AutoSize = .T., ;
Caption = "到", ;
Height = 16, ;
Left = 178, ;
Top = 221, ;
Width = 14, ;
Name = "Label16"
ADD OBJECT command2 AS commandbutton WITH ;
Top = 33, ;
Left = 388, ;
Height = 25, ;
Width = 109, ;
Caption = "打印機�]置(\<S)...", ;
Name = "Command2"
*-- 紙張類型及方向
ADD OBJECT papertype AS label WITH ;
AutoSize = .T., ;
Caption = "PaperType", ;
Height = 16, ;
Left = 112, ;
Top = 132, ;
Width = 56, ;
Name = "PaperType"
*-- 當前頁號
ADD OBJECT pageno AS textbox WITH ;
Alignment = 3, ;
Value = 9999, ;
Enabled = .F., ;
Height = 20, ;
InputMask = "9999", ;
Left = 196, ;
SelectOnEntry = .T., ;
Top = 190, ;
Width = 49, ;
Name = "pageno"
PROCEDURE getprinterinfo
*-- 獲取打印機信息
* 並存放到數組 paPrinter 中
* pnPrinterNo 用來存放打印機的個數
thisform.PrinterLocation.caption = paPrinter(pnPrinterNo,2)
*-- 打印機狀態
thisform.PrinterStatus.caption = sys(13)
ENDPROC
PROCEDURE getpaper
*-- 通過 RPTINFO() 函數來獲得打印機的紙張�]置類型及方向
dime paper_list(41)
paper_list(1) = "Letter, 8 1/2 x 11 in"
paper_list(2) = "Letter Small, 8 1/2 x 11 in"
paper_list(3) = "Tabloid, 11 x 17 in"
paper_list(4) = "Ledger, 17 x 11 in"
paper_list(5) = "Legal, 8 1/2 x 14 in"
paper_list(6) = "Statement, 5 1/2 x 8 1/2 in"
paper_list(7) = "Executive, 7 1/4 x 10 1/2 in"
paper_list(8) = "A3, 297 x 420 mm"
paper_list(9) = "A4, 210 x 297 mm"
paper_list(10) = "A4, Small 210 x 297 mm"
paper_list(11) = "A5, 148 x 210 mm"
paper_list(12) = "B4, 250 x 354 mm"
paper_list(13) = "B5, 182 x 257 mm"
paper_list(14) = "Folio, 8 1/2 x 13 in"
paper_list(15) = "Quarto, 215 x 275 mm"
paper_list(16) = "10 x 14 in"
paper_list(17) = "11 x 17 in"
paper_list(18) = "Note, 8 1/2 x 11 in"
paper_list(19) = "Envelope #9, 3 7/8 x 8 7/8 in"
paper_list(20) = "Envelope #10, 4 1/8 x 9 1/2 in"
paper_list(21) = "Envelope #11, 4 1/2 x 10 3/8 in"
paper_list(22) = "Envelope #12, 4 1/2 x 11 in"
paper_list(23) = "Envelope #14, 5 x 11 1/2 in"
paper_list(24) = "C size sheet"
paper_list(25) = "D size sheet"
paper_list(26) = "E size sheet"
paper_list(27) = "Envelope DL, 110 x 220 mm"
paper_list(28) = "Envelope C5, 162 x 229 mm"
paper_list(29) = "Envelope C3, 324 x 458 mm"
paper_list(30) = "Envelope C4, 229 x 324 mm"
paper_list(31) = "Envelope C6, 114 x 162 mm"
paper_list(32) = "Envelope C65, 114 x 229 mm"
paper_list(33) = "Envelope B4, 250 x 353 mm"
paper_list(34) = "Envelope B5, 176 x 250 mm"
paper_list(35) = "Envelope B6, 176 x 125 mm"
paper_list(36) = "Envelope, 110 x 230 mm"
paper_list(37) = "Envelope Monarch, 3 7/8 x 7.5 in"
paper_list(38) = "6 3/4 Envelope, 3 5/8 x 6 1/2 in"
paper_list(39) = "US Std Fanfold, 14 7/8 x 11 in"
paper_list(40) = "German Std Fanfold, 8 1/2 x 12 in"
paper_list(41) = "German Legal Fanfold, 8 1/2 x 13 in "
RETU PAPER_LIST(prtinfo(2)) + "，" + iif(prtinfo(1)=0,"縱向","橫向")
ENDPROC
PROCEDURE MouseMove
*-- 用鼠標拖動表單的移動
Lparameters nButton, nShift, nxcoord, nycoord
With Thisform
if mdown() and nButton = 1
.top = (nycoord - this.nycoord) + .top + 1
.left = (nxcoord - this.nxcoord) + .left + 1
endif
Endwith
ENDPROC
PROCEDURE MouseDown
*-- 當鼠標在表單上按下時，記下表單的坐標位置
Lparameters nButton, nShift, nxcoord, nycoord
This.nxcoord = nxcoord
This.nycoord = nycoord
ENDPROC
PROCEDURE Init
*-- 表單初始化 ...
With thisform
.rptname = rptname
.MinButton = .F.
.MaxButton = .F.
.Borderstyle= 2
.WindowType = 1
.AutoCenter = .T.
.pageno.value = _pageno
Endwith
if type("paPrinter") = "U" or type("pnPrinterNo") # "N"
public paPrinter(1,2),pnPrinterNo
pnPrinterNo = 1
endif
*-- 獲取打印機信息,並存入數組中
nPrinterNum = APRINTERS(paPrinter)
With ThisForm.PrinterList
if nPrinterNum = 0
.value = "沒有安裝打印機"
else
.clear
For n = 1 to nPrinterNum
.additem(paPrinter(n,1))
Endfor
.listindex = pnPrinterNo
endif
Endwith
*-- 獲取打印機的信息
thisform.GetPrinterInfo()
*-- 獲取紙張及方向
thisform.papertype.caption = thisform.getpaper()
ENDPROC
*-- 改變打印機列表的事件
PROCEDURE printerlist.InteractiveChange
pnPrinterNo = this.listindex
cCurPrinter = thisform.PrinterList.value
set printer to name "&cCurPrinter"
*-- 重新獲取打印機的信息及大小和方向
thisform.GetPrinterInfo
thisform.papertype.caption = thisform.GetPaper()
ENDPROC
PROCEDURE cmdok.Click
*-- �]置打印機
cCurPrinter = thisform.PrinterList.value
set printer to name "&cCurPrinter"
pnPrinterNo = thisform.PrinterList.listindex
*-- 獲得打印範圍
pbpage = 1
pepage = _pepage
With ThisForm.Optiongroup2
do case
case .value = 1
pbpage = 1
pepage = _pepage
case .value = 2
pbpage = _pageno
pepage = _pageno
case .value = 3
pbpage = ThisForm.pbpage.value
pepage = ThisForm.pepage.value
if pbpage > pepage or pbpage > _pepage or pbpage <= 0
messagebox("頁碼�]置錯誤！",48,"警告")
thisform.pbpage.setfocus
retu
endif
endcase
Endwith
RptName = thisform.rptname
if !empty(rptname)
nCopy = thisform.copy.value
isOneByOne = thisform.check1.value
if isOneByOne && 逐份打印
for n=1 to nCopy
wait windo "正在輸出打印 ..." + allt(str(n)) + "/" + allt(str(nCopy)) + "按 ESC 取消！" nowait
if inkey(1) = 27
exit
endif
report form "&RptName" nocon noeject range pbpage,pepage to print
endfor
else
nMax = (pepage-pbpage)*nCopy
i = 1
for n=pbpage to pepage && 逐頁打印
for m=1 to nCopy
wait window "正在輸出打印 ..." + allt(str(i)) + "/" + allt(str(nMax)) + "按 ESC 取消！" nowait
report form "&RptName" nocon noeject range n,n to print
i = i + 1
if inkey(1) = 27
i = 0
exit
endif
endfor
if i=0
exit
endif
endfor
endif
endif
thisform.release
ENDPROC
PROCEDURE command1.Click
thisform.release
ENDPROC
PROCEDURE optiongroup2.InteractiveChange
ThisForm.pbpage.enabled = IIF(this.value = 3,.T.,.F.)
ThisForm.pepage.enabled = ThisForm.pbpage.enabled
thisform.pbpage.setfocus
ENDPROC
PROCEDURE command2.Click
=sys(1037)
thisform.GetPrinterInfo
thisform.papertype.caption = thisform.GetPaper()
ENDPROC
ENDDEFINE
*
*-- 結束定義: printsetup
|
_________________
利用>>搜尋<<的功能會比問的還要快得到答案. |
|
| 回頂端 |
|
|
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 23 樓
|
| 發表於: 星期四 二月 27, 2014 10:51 am 文章主題: |
|
|
以上的方法都有缺點
用外掛軟體,如picpick,雖有十字線,
但若要去按預覽工具列上的按鈕或拉捲軸時,
就不能按啦
而garfield的程式碼,雖然在 form 上有十字線,
但在 Report 上仍然沒有
最後我修改 FoxyPreviewer 的一小段程式碼,
終於解決了這個問題
如圖 |
|
| 回頂端 |
|
|
55812296
註冊時間: 2012-09-19
文章: 49
第 24 樓
|
| 發表於: 星期四 二月 27, 2014 2:42 pm 文章主題: |
|
|
| ckp6250 寫到: | 這個問題，我個人就此打住啦，實在是沒法度，幫不上忙。
換個話題，
如果，有一天，USER希望『滑鼠移到那裡，點二下，像 Google Map一樣，把它局部放大，以利閱讀』，
您會怎麼辦？ |
這就比較簡單 點二下 跑出一個小FORM 裡面顯示該欄資料 |
|
| 回頂端 |
|
|
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 25 樓
|
| 發表於: 星期四 二月 27, 2014 2:55 pm 文章主題: |
|
|
| 55812296 寫到: |
這就比較簡單 點二下 跑出一個小FORM 裡面顯示該欄資料 |
在 Report 預覽時 , 要點二下 , 跑出一個小FORM ,
這可一點都不簡單?
要如何偵測 , 使用者所點的那個 Report 上, 是什麼資料 ? |
|
| 回頂端 |
|
|
arthur
註冊時間: 2003-11-05
文章: 18
第 26 樓
|
| 發表於: 星期六 三月 01, 2014 1:41 pm 文章主題: |
|
|
ckp6250:
FoxyPreviewer我也一直在關注,你是改那一段程序?
能指導嗎? |
|
| 回頂端 |
|
|
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 27 樓
|
| 發表於: 星期六 三月 01, 2014 2:29 pm 文章主題: |
|
|
我是讓使用者在需要十字線時,
按下 ins , 在 mouse 所在的位置上,
去產生那條十字線,
如果使用者移動 mouse , 再重按 ins 時
清掉舊的,重劃新的
Foxypreviewer.prg 修改十幾行,如下
| 代碼: |
Procedure HandledKeyPress( nKeyCode, nShiftAltCtrl )
Do Case
Case nKeyCode = 22 && Ins
vCol = Mcol(0,3)
vRow = Mrow(0,3)
With This.PreviewForm
.Cls
.DrawStyle = 3
.ForeColor = Rgb(255,0,0)
.Line(0,vRow,_Screen.Width,vRow)
.Line(vCol,0,vCol,_Screen.Height*64)
Endwith
Endcase
Return .F.
Endproc
|
其實 , FoxyPreviewer 是 open source ,
能讓我們加油添醋的地方很多,
這是我為何力推的主因 |
|
| 回頂端 |
|
|
arthur
註冊時間: 2003-11-05
文章: 18
第 28 樓
|
| 發表於: 星期六 五月 17, 2014 8:08 pm 文章主題: |
|
|
我依照您的方式測試覺得放在HandledKeyPress()利用捕捉按鍵方式並不太理想,因為:
(1) 用Insert插入按鍵來控制等報表結束後可能改變進入報表前的插入或覆蓋的輸入狀況.
(2) 滑鼠位置如果在沒有字元的地方(報表留白的地方)十字線常常不會出現,這時又要移動滑鼠再按Insert,這要反覆好幾次十字線才會在報表上,這樣讓使用者在操作上不方便.
(3) 第(1)個問題可以用其他功能鍵來代替,但(2)問題仍沒有好的解決方式,因此不用在捕捉鍵盤按鍵方式顯示十字線.
(4) 最後我決定用Ctrl+MouseMove來顯示十字線,也就是當使用者按下Ctrl按鍵不放然後移動滑鼠,則十字線就會依目前滑鼠位置一直畫出新的出來,等使用者決定十字線的位置後再放開Ctrl鍵就可以了.
而此段程序必須寫在:FrxPreView.Vcx->FrxBaseForm->MouseMove()方法程序中. |
|
| 回頂端 |
|
|
arthur
註冊時間: 2003-11-05
文章: 18
第 29 樓
|
| 發表於: 星期六 五月 17, 2014 8:13 pm 文章主題: |
|
|
| FrxPreView.Vcx->FrxBaseForm->MouseMove() |
|
| 回頂端 |
|
|
ckp6250
註冊時間: 2004-07-30
文章: 1644
第 30 樓
|
| 發表於: 星期日 五月 18, 2014 11:12 am 文章主題: |
|
|
這就是 open source 迷人之處
各取所需 , 各改所需
除了 FrxPreView 之外 , Report Sculptor 也有類十字線的功能,
不用改,它自己有
也是 open source
我覺得不遜於 FrxPreView
更有許多特色是 FrePreView 所沒有的
我還沒研究很深入
您可以試看看
http://vfp.sunyear.com.tw/viewtopic.php?t=6307 |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
