VFP 愛用者社區

Batman · 註冊時間: 2003-11-15 文章: 348 第 1 樓

Grid內的Container內textbox, 如何可與其他Column同步HighLight? 謝謝幫助

ckp6250 · 註冊時間: 2004-07-30 文章: 1644 第 2 樓

如果不在Container內的話應該比較好辦,
若一定要包在Container內
那麼 , 在 Grid 的 BeforeRowColChange 及 AfterRowColChange
自行改變textbox的 backcolor , 是否可行呢?

ckp6250 · 註冊時間: 2004-07-30 文章: 1644 第 3 樓

如果直接在Column上而不在Container內的話應該比較好辦,
若一定要包在Container內
那麼 , 在 Grid 的 BeforeRowColChange 及 AfterRowColChange
自行改變textbox的 backcolor , 是否可行呢?

Batman · 註冊時間: 2003-11-15 文章: 348 第 4 樓

不行的, 會全部改變, 在網上查了一下, 原來不是簡單的問題, 不過早已有人解決了, 問題在國內上不到Google, 真是....唉

aizz · 註冊時間: 2007-01-29 文章: 171 第 5 樓

Batman · 註冊時間: 2003-11-15 文章: 348 第 6 樓

我都想, 公司機, 不敢亦不可安裝那些東東的

oldbb · 註冊時間: 2007-02-28 文章: 83 第 7 樓

2、3樓的思路應該可以，GRID可控制各單元格的COLOR。

Batman · 註冊時間: 2003-11-15 文章: 348 第 8 樓

不行的, 在 Grid 的 BeforeRowColChange 及 AfterRowColChange 會改變全部textbox的 backcolor, 現在在試backstyle_access, 希望可做到

oldbb · 註冊時間: 2007-02-28 文章: 83 第 9 樓

VFP HELP 講到：
Column Object 可以使用 DynamicBackColor 和 DynamicForeColor 特性製造出特效。

Batman · 註冊時間: 2003-11-15 文章: 348 第 10 樓

所有的DynamicBackColor 和 DynamicForeColor...凡等等, 是祗可改變Column直接下的物件, 不包Column下加入的Container, DyanmicCurrentControl也祗是挑選一些物件, 如3張圖片如何顯示那1張, 但多圖片時, 雖然可置條件, 亦加不了那麼多物件, 若Column下的某個Cell內的物件執行單一動作, dynamic...亦做不副了

Batman · 註冊時間: 2003-11-15 文章: 348 第 11 樓

所有的DynamicBackColor 和 DynamicForeColor...凡等等, 是祗可改變Column直接下的物件, 不包Column下加入的Container, DyanmicCurrentControl也祗是挑選一些物件, 如3張圖片如何顯示那1張, 但多圖片時, 雖然可置條件, 亦加不了那麼多物件, 若Column下的某個Cell內的物件執行單一動作, dynamic...亦做不副了

oldbb · 註冊時間: 2007-02-28 文章: 83 第 12 樓

DynamicBackColor 和 DynamicForeColor對Column下的Container有作用的，但測試發現動作不同步，是否方法有些不對頭。

** Test.prg
CREATE CURSOR dd (f1 I, f2 I)
INSERT INTO dd VALUES (1,2)
INSERT INTO dd VALUES (3,4)
INSERT INTO dd VALUES (5,6)
GO TOP
of = CREATEOBJECT("_Form")
of.Show(1)
RETURN

DEFINE CLASS _Form AS Form
Height = 300
Width = 420
ADD OBJECT Grid1 AS _Grid
ENDDEFINE

DEFINE CLASS _Grid AS Grid
Visible = .T.
nRecno = 0
PROCEDURE Init
this.Column1.RemoveObject("Text1")
this.Column1.AddObject("Container1", "_Container")
this.Column1.Sparse = .F.
ENDPROC
PROCEDURE AfterRowColChange(nColIndex)
this.nRecno = RECNO()
this.Column1.DynamicBackColor = [IIF(this.nRecno == RECNO(), RGB(255,0,0), RGB(0,255,0))]
ENDPROC
ENDDEFINE

DEFINE CLASS _Container AS Container
Visible = .T.
FUNCTION BackColor_ASSIGN(vNewVal)
this.BackColor = BITAND(vNewVal, 0x00FFFFFF)
ENDFUNC
ENDDEFINE

oldbb · 註冊時間: 2007-02-28 文章: 83 第 13 樓

問題找到了，原來要重繪，這裏加多句就OK：this.SetFocus

PROCEDURE AfterRowColChange(nColIndex)
this.nRecno = RECNO()
this.Column1.DynamicBackColor = [IIF(this.nRecno == RECNO(), RGB(255,0,0), RGB(0,255,0))]
this.SetFocus
ENDPROC

Batman · 註冊時間: 2003-11-15 文章: 348 第 14 樓

謝謝OldBB幫助, 要消化一下,發表於: 星期五四月 24, 2015 11:21 pm,發表於: 星期六四月 25, 2015 6:28 am, 你好有毅力, 太感動了, 謝謝
不知Container下的Textbox能否做到?

oldbb · 註冊時間: 2007-02-28 文章: 83 第 15 樓

能觸動到Container，下屬的就好辦。
加個TextBox：
DEFINE CLASS _Container AS Container
Visible = .T.
BorderStyle = 0

ADD OBJECT Text1 AS TextBox WITH BorderStyle=0

PROCEDURE Init
this.Text1.Width = this.Parent.Width
this.Text1.Height = this.Parent.Parent.RowHeight
this.Text1.ControlSource = "dd.f1"
ENDPROC

FUNCTION BackColor_ASSIGN(vNewVal)
this.Text1.BackColor = BITAND(vNewVal, 0x00FFFFFF)
ENDFUNC
ENDDEFINE