VFP 愛用者社區 首頁 VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
 
 常見問題常見問題   搜尋搜尋   會員列表會員列表   會員群組會員群組   會員註冊會員註冊 
 個人資料個人資料   登入檢查您的私人訊息登入檢查您的私人訊息   登入登入

如何做到同步 "中原標準時間及日期"
前往頁面 上一頁  1, 2
 
發表新主題   回覆主題    VFP 愛用者社區 首頁 -> VFP 討論區
上一篇主題 :: 下一篇主題  
發表人 內容
oldbb



註冊時間: 2007-02-28
文章: 83


第 16 樓
發表發表於: 星期五 三月 06, 2015 7:44 am    文章主題: 引言回覆
可試一下用 stWsaData = SPACE(398) 代替。
回頂端
檢視會員個人資料 發送私人訊息
kalok



註冊時間: 2010-08-26
文章: 284


第 17 樓
發表發表於: 星期一 五月 11, 2015 6:45 am    文章主題: 引言回覆
不要再用 VFP6 了
回頂端
檢視會員個人資料 發送私人訊息
LiChingLin



註冊時間: 2006-04-19
文章: 59


第 18 樓
發表發表於: 星期一 五月 11, 2015 2:28 pm    文章主題: 引言回覆
謝謝
回頂端
檢視會員個人資料 發送私人訊息
LiChingLin



註冊時間: 2006-04-19
文章: 59


第 19 樓
發表發表於: 星期二 五月 12, 2015 4:55 pm    文章主題: 引言回覆
我們沒辦法選擇用或不用vfp6 .... 無奈
vfp9 又沒得下來測試 .. 無法建議上去呀 ..

回 oldbb
其他行也會出錯
只要遇到 0h00 , 0h0200 , 0x202 ....
都會出錯
回頂端
檢視會員個人資料 發送私人訊息
perry



註冊時間: 2014-07-20
文章: 203


第 20 樓
發表發表於: 星期二 五月 12, 2015 6:14 pm    文章主題: 引言回覆
http://www.stdtime.gov.tw/chinese/home.aspx
左下角不是就有校時軟體可下載...
回頂端
檢視會員個人資料 發送私人訊息
oldbb



註冊時間: 2007-02-28
文章: 83


第 21 樓
發表發表於: 星期二 五月 12, 2015 9:09 pm    文章主題: 引言回覆
用VFP6試發現有幾個指令不兼容，改了一下。
代碼:

*
* 網絡時間同步
*
SET TALK OFF
CLEAR

*szNtpIP   = "132.163.4.101"
*szNtpIP   = "132.163.4.102"
szNtpIP   = "132.163.4.103"
*szNtpIP   = "128.138.140.44"
ddNtpPort = 13

_UTC2Current(_GetNetTime(szNtpIP, ddNtpPort))
RETURN

FUNCTION _UTC2Current(szUTC)
    LOCAL stTimeUTC, stTimeZoneInfo, stTimeCurrent
    LOCAL ddYear, ddMonth, ddDay, ddHour, ddMinute, ddSecond

    IF EMPTY(szUTC)
        RETURN
    ENDIF
   
    DECLARE LONG GetTimeZoneInformation          IN Kernel32 STRING@
    DECLARE LONG SystemTimeToTzSpecificLocalTime IN Kernel32 STRING@, STRING@, STRING@
    DECLARE LONG SetLocalTime                    IN Kernel32 STRING@

    stTimeZoneInfo = REPLICATE(CHR(0x00), 172)
    stTimeCurrent  = REPLICATE(CHR(0x00), 16)
   
    ddYear   = INT(VAL(SUBSTR(szUTC, 8, 2))) + 2000
    ddMonth  = INT(VAL(SUBSTR(szUTC, 11, 2)))
    ddDay    = INT(VAL(SUBSTR(szUTC, 14, 2)))
    ddHour   = INT(VAL(SUBSTR(szUTC, 17, 2)))
    ddMinute = INT(VAL(SUBSTR(szUTC, 20, 2)))
    ddSecond = INT(VAL(SUBSTR(szUTC, 23, 2)))

    stTimeUTC = CHR(BITAND(ddYear, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddYear, 0xFF00), 8));
              + CHR(BITAND(ddMonth, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddMonth, 0xFF00), 8));
              + REPLICATE(CHR(0x00), 2);
              + CHR(BITAND(ddDay, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddDay, 0xFF00), 8));
              + CHR(BITAND(ddHour, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddHour, 0xFF00), 8));
              + CHR(BITAND(ddMinute, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddMinute, 0xFF00), 8));
              + CHR(BITAND(ddSecond, 0x00FF));
              + CHR(BITRSHIFT(BITAND(ddSecond, 0xFF00), 8))

    GetTimeZoneInformation(@stTimeZoneInfo)
    SystemTimeToTzSpecificLocalTime(@stTimeZoneInfo, @stTimeUTC, @stTimeCurrent)
   
    IF SetLocalTime(@stTimeCurrent) != 0
        ddYear   = ASC(SUBSTR(stTimeCurrent, 1, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent, 2, 1)), 8)
        ddMonth  = ASC(SUBSTR(stTimeCurrent, 3, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent, 4, 1)), 8)
        ddDay    = ASC(SUBSTR(stTimeCurrent, 7, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent, 8, 1)), 8)
        ddHour   = ASC(SUBSTR(stTimeCurrent, 9, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent,10, 1)), 8)
        ddMinute = ASC(SUBSTR(stTimeCurrent,11, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent,12, 1)), 8)
        ddSecond = ASC(SUBSTR(stTimeCurrent,13, 1)) + BITLSHIFT(ASC(SUBSTR(stTimeCurrent,14, 1)), 8)
       
        MESSAGEBOX("時鐘在 "+;
                    TRANSFORM(ddYear)+"/"+TRANSFORM(ddMonth)+"/"+TRANSFORM(ddDay)+" "+;
                    TRANSFORM(ddHour)+":"+TRANSFORM(ddMinute)+":"+TRANSFORM(ddSecond)+;
                    " 同步成功")
    ELSE
        MESSAGEBOX("時鐘同步失敗，試以管理員身份執行主�{序。")
    ENDIF
ENDFUNC

FUNCTION _GetNetTime(szNtpIP, ddNtpPort)
    LOCAL stWsaData, stSockAddr, szBuffer, dhSocket
    LOCAL i, ddLen

    DECLARE LONG WSAStartup  IN "Ws2_32" LONG, STRING@
    DECLARE LONG WSACleanup  IN "Ws2_32"
    DECLARE LONG socket      IN "Ws2_32" LONG, LONG, LONG
    DECLARE LONG connect     IN "Ws2_32" LONG, STRING@, LONG
    DECLARE LONG recv        IN "Ws2_32" LONG, STRING@, LONG, LONG
    DECLARE LONG closesocket IN "Ws2_32" LONG
    DECLARE LONG inet_addr   IN "Ws2_32" STRING@
    DECLARE LONG htons       IN "Ws2_32" LONG

    stWsaData  = REPLICATE(CHR(0x00), 398)
    szBuffer   = REPLICATE(CHR(0x00), 256)
    stSockAddr = REPLICATE(CHR(0x00), 16)
       
    stSockAddr = CHR(0x02) + CHR(0x00);
               + CHR(BITAND(htons(ddNtpPort), 0x00FF));
               + CHR(BITRSHIFT(BITAND(htons(ddNtpPort), 0xFF00), 8));
               + CHR(BITAND(inet_addr(@szNtpIP), 0x000000FF));
               + CHR(BITRSHIFT(BITAND(inet_addr(@szNtpIP), 0x0000FF00),  8));
               + CHR(BITRSHIFT(BITAND(inet_addr(@szNtpIP), 0x00FF0000), 16));
               + CHR(BITRSHIFT(BITAND(inet_addr(@szNtpIP), 0xFF000000), 24));
               + REPLICATE(CHR(0x00), 8)

    WSAStartup(0x202, @stWsaData)
    dhSocket = socket(2, 1, 6)
    ddLen  = 0
    IF connect(dhSocket, @stSockAddr, LEN(stSockAddr)) != -1
        FOR i = 1 TO 3
            ddLen = recv(dhSocket, @szBuffer, LEN(szBuffer), 0)
            IF ddLen != -1
               EXIT
            ENDIF
        ENDFOR
    ENDIF
    closesocket(dhSocket)
    WSACleanup()
    IF ddLen > 0
        szBuffer = LEFT(szBuffer, ddLen)
        RETURN szBuffer
    ELSE
        MESSAGEBOX("網絡連接異常，時鐘同步失敗。")
        RETURN ""
    ENDIF
ENDFUNC
回頂端
檢視會員個人資料 發送私人訊息
LiChingLin



註冊時間: 2006-04-19
文章: 59


第 22 樓
發表發表於: 星期四 五月 14, 2015 4:59 pm    文章主題: 引言回覆
用
szNtpIP = "128.138.140.44"
可以了

謝謝
回頂端
檢視會員個人資料 發送私人訊息
從之前的文章開始顯示:   
發表新主題   回覆主題    VFP 愛用者社區 首頁 -> VFP 討論區 所有的時間均為 台北時間 (GMT + 8 小時)
前往頁面 上一頁  1, 2
第2頁(共2頁)

 
前往:  
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案


Powered by phpBB © 2001, 2005 phpBB Group
正體中文語系由 phpbb-tw 維護製作