VFP 愛用者社區

[CPS0204]

http://www.caneis.com.tw/home/information/citycode.htm
可由vfp 抓至cursor dbf中
欄位1=中文城市名
欄位2=英文名
欄位3=代碼



請高手幫忙謝謝

[Patrick Wu]

城市代號：TPE
城市英文：TAIPEI
國家英文：TAIWAN
城市中文：桃園國際機場
國家中文：台灣
格林威治：+8

是要這樣嗎 ???
如是 這是 後學 的強項

[syntech]

[garfield]

XD

func 請大家幫幫我
para url
一個網頁畫面就有全部資料,
請直接複製貼到excel, 存excel 5.0格式.
在vfp create table , append from excel檔 typehttp://vfp.sunyear.com.tw/templates/subSilver/images/lang_chinese_traditional_taiwan/quick_reply.gif xls

[tuberose]

Clear
oIE = Createobject("internetexplorer.application")
oIE.Visible = .F.
oIE.Navigate("http://www.caneis.com.tw/home/information/citycode.htm")
tStartSecond = Seconds()
Do While oIE.Busy = .T. Or oIE.ReadyState#4
If Seconds() - tStartSecond > 10
Exit
Endif
=Inkey(0.5)
Enddo

Create Cursor 城市代碼 (中文城市名 C(20), 英文城市名 C(20), 代碼 C(4))

For I = 4 To 21
nTableNum = "oIE.Document.getElementsByTagName('table').[" + Alltrim(Str(I)) + "]"
objCollection = &nTableNum
objTable = objCollection

For Each objRow In objTable.Rows
If Type("objRow.cells(1).innertext") = "C" And ;
!Empty(Alltrim(objRow.cells(0).innertext)) ;
And objRow.cells(0).innertext <> "中文城市名稱" And ;
objRow.cells(0).innertext <> "城市名稱"
Insert Into 城市代碼 Values (objRow.cells(0).innertext, ;
objRow.cells(1).innertext, objRow.cells(2).innertext)
Endif
If Type("objRow.cells(5).innertext") = "C" And ;
!Empty(Alltrim(objRow.cells(4).innertext)) ;
And objRow.cells(4).innertext <> "中文城市名稱" And ;
objRow.cells(4).innertext <> "城市名稱"
Insert Into 城市代碼 Values (objRow.cells(4).innertext, ;
objRow.cells(5).innertext, objRow.cells(6).innertext)
Endif
Next
Endfor
Wait Window "完成." Timeout 1

oIE.Quit()

Go Top
Browse Last Title "城市代碼"

[CPS0204]

tuberose真是高手,謝謝


這就是我要的!

[tuberose]

Update :

oIE = Createobject("internetexplorer.application")
oIE.Visible = .F.
oIE.Navigate("http://www.caneis.com.tw/home/information/citycode.htm")
tStartSecond = Seconds()
Do While oIE.Busy = .T. Or oIE.ReadyState#4
If Seconds() - tStartSecond > 10
Exit
Endif
=Inkey(0.5)
Enddo

Create Cursor 城市代碼 (中文城市名 C(20), 英文城市名 C(20), 代碼 C(4))

For I = 4 To 21
nTableNum = "oIE.Document.getElementsByTagName('table').[" + Transform(I) + "]"
objTable = &nTableNum

For Each objRow In objTable.Rows
If Type("objRow.cells(1).innertext") = "C" And Len(Alltrim(objRow.cells(0).innertext)) > 3 ;
And objRow.cells(0).innertext <> "中文城市名稱" And objRow.cells(0).innertext <> "城市名稱"
Insert Into 城市代碼 Values (objRow.cells(0).innertext, objRow.cells(1).innertext, objRow.cells(2).innertext)
Endif
If Type("objRow.cells(5).innertext") = "C" And Len(Alltrim(objRow.cells(4).innertext)) > 3 ;
And objRow.cells(4).innertext <> "中文城市名稱" And objRow.cells(4).innertext <> "城市名稱"
Insert Into 城市代碼 Values (objRow.cells(4).innertext, objRow.cells(5).innertext, objRow.cells(6).innertext)
Endif
Next
Endfor
Wait Window "完成." Timeout 1

oIE.Quit()

Go Top
Browse Last Title "城市代碼"

[tuberose]

版本 2 ： 文本方式

*!* Enumerates/Detect the number of tables and rows and columns and Cells in HTTP.

Clear
Set Safety Off
CRLF = Chr(13) + Chr(10)
cStr = ""
oIE = Createobject("internetexplorer.application")
oIE.Visible = .T.
oIE.Navigate("http://www.caneis.com.tw/home/information/citycode.htm") && Your Web
tStartSecond = Seconds()
Do While oIE.Busy = .T. Or oIE.ReadyState#4
If Seconds() - tStartSecond > 10
Exit
Endif
Inkey(0.5)
Enddo

*!* How many table(s) in the HTTP ?
cStr = "===================================" + CRLF
cStr = cStr + "A total number of tables : " + Alltrim(Str(oIE.Document.getElementsByTagName("Table").Length)) + CRLF
cStr = cStr + "===================================" + CRLF

*!* Enumerate each table.
For I = 0 To oIE.Document.getElementsByTagName("Table").Length - 1
nTableNum = "oIE.Document.getElementsByTagName('table').[" + Alltrim(Str(I)) + "]"
objCollection = &nTableNum
cStr = cStr + "Table : " + Alltrim(Str(I)) + CRLF
objTable = objCollection

nRow = objTable.Rows.Length && the number of Rows
nColumn = objTable.cells.Length/objTable.Rows.Length && the number of Columns
nCell = objTable.cells.Length && the number of Cells
cStr = cStr + "Rows number : " + Alltrim(Str(nRow)) + CRLF
cStr = cStr + "Columns number : " + Alltrim(Str(nColumn)) + CRLF
cStr = cStr + "Cells number : " + Alltrim(Str(nCell)) + CRLF
cStr = cStr + "..................." + CRLF

*!* Enumerate each cell in this table.
For Each objRow In objTable.Rows
For J = 0 To objTable.Rows.Length - 1
If Type("objRow.cells(J).innertext") = "C"
cStr = cStr + " " + Padr(objRow.cells(J).innertext, 24, ' ')
Endif
Endfor
cStr = cStr + CRLF
Next
cStr = cStr + CRLF + "===================================" + CRLF

Next
oIE.Quit()
=Strtofile(cStr, "MyDoc.txt")
Modify File MyDoc.txt

[CPS0204]

謝謝!可以使用!

請幫忙再轉入dbf 一下(每天都要讀到的交叉匯率檔)
http://yamstock.megatime.com.tw/rate.htm

謝謝大大

[tuberose]

*!* Get Rate Date.

Clear
Wait Window "请稍等片刻......" Nowait
oIE = Createobject("Internetexplorer.Application")
oIE.Visible = .T. && Or .F.
oIE.Navigate("http://yamstock.megatime.com.tw/rate.htm") && Your Web
tStartSecond = Seconds()
Do While oIE.Busy = .T. Or oIE.ReadyState#4
If Seconds() - tStartSecond > 10 && Or 10+
Exit
Endif
Inkey(0.5)
Enddo
* Wait Wind "请稍等片刻......"
Create Cursor 交叉匯率表 ( 美金 C(6), 台幣 C(6), 日圓 C(6), ;
港幣 C(6), 人民幣 C(6), 英鎊 C(6), 歐元 C(6), 加幣 C(6), ;
澳幣 C(6), 泰銖 C(6), 紐幣 C(6), 南非幣 C(6) )

objTable = oIE.Document.getElementsByTagName("table").[2]

lnNum = 1
For Each objRow In objTable.Rows
If lnNum > 3
Insert Into 交叉匯率表 Values ( ;
Padl(objRow.cells(0).Innertext, 6, " " ), Padl(objRow.cells(1).Innertext, 6, " " ), ;
Padl(objRow.cells(2).Innertext, 6, " " ), Padl(objRow.cells(3).Innertext, 6, " " ), ;
Padl(objRow.cells(4).Innertext, 6, " " ), Padl(objRow.cells(5).Innertext, 6, " " ), ;
Padl(objRow.cells(6).Innertext, 6, " " ), Padl(objRow.cells(7).Innertext, 6, " " ), ;
Padl(objRow.cells(.Innertext, 6, " " ), Padl(objRow.cells(9).Innertext, 6, " " ), ;
Padl(objRow.cells(10).Innertext, 6, " " ), Padl(objRow.cells(11).Innertext, 6, " " ) )
Endif
lnNum = lnNum + 1
Next

oIE.Quit()
Wait Window "完成." Timeout 1
Browse Last Title "交叉匯率表"

[tuberose]

Update :

*!* Get Rate Date.

Wait Window "请稍等片刻......" Nowait
oIE = Createobject("Internetexplorer.Application")
oIE.Visible = .T.
oIE.Navigate("http://yamstock.megatime.com.tw/rate.htm") && Your Web
tStartSecond = Seconds()
Do While oIE.Busy = .T. Or oIE.ReadyState#4
If Seconds() - tStartSecond > 10 && Or 10+
Exit
Endif
Inkey(0.5)
Enddo
* Wait Window "请稍等片刻......"
Create Cursor 交叉匯率表 ( 币种 C(6), 美金 C(6), 台幣 C(6), 圓 C(6), ;
日港幣 C(6), 人民幣 C(6), 英鎊 C(6), 歐元 C(6), 加幣 C(6), ;
澳幣 C(6), 泰銖 C(6), 紐幣 C(6), 南非幣 C(6) )

objTable = oIE.Document.getElementsByTagName("table").[2]

lnNum = 1
For Each objRow In objTable.Rows
If lnNum > 3
Insert Into 交叉匯率表 Values ( Padl(objRow.cells(0).Innertext, 6, " " ), ;
Padl(objRow.cells(1).Innertext, 6, " " ), Padl(objRow.cells(2).Innertext, 6, " " ), ;
Padl(objRow.cells(3).Innertext, 6, " " ), Padl(objRow.cells(4).Innertext, 6, " " ), ;
Padl(objRow.cells(5).Innertext, 6, " " ), Padl(objRow.cells(6).Innertext, 6, " " ), ;
Padl(objRow.cells(7).Innertext, 6, " " ), Padl(objRow.cells(.Innertext, 6, " " ), ;
Padl(objRow.cells(9).Innertext, 6, " " ), Padl(objRow.cells(10).Innertext, 6, " " ), ;
Padl(objRow.cells(11).Innertext, 6, " " ), Padl(objRow.cells(12).Innertext, 6, " " ) )
Endif
lnNum = lnNum + 1
Next

oIE.Quit()
Wait Window "完成." Timeout 1
Browse Last Title "交叉匯率表"

[215001]

不錯的範例.先收藏起來

上面 日圓,日港幣 好像有問題,字放錯位置了

[CPS0204]

謝謝,高手真多

[tuberose]

对不起，是我打错了，谢谢上面的网友的指正。
源代码：
Create Cursor 交叉匯率表 ( 币种 C(6), 美金 C(6), 台幣 C(6), 圓 C(6), ;
日港幣 C(6), 人民幣 C(6), 英鎊 C(6), 歐元 C(6), 加幣 C(6), ;
澳幣 C(6), 泰銖 C(6), 紐幣 C(6), 南非幣 C(6) )

改成：
Create Cursor 交叉匯率表 ( 币种 C(6), 美金 C(6), 台幣 C(6), 日圓 C(6), ;
港幣 C(6), 人民幣 C(6), 英鎊 C(6), 歐元 C(6), 加幣 C(6), ;
澳幣 C(6), 泰銖 C(6), 紐幣 C(6), 南非幣 C(6) )