 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 1 樓
|
 發表於: 星期五 四月 02, 2004 1:13 am 文章主題: 預讀取技術在BOM顯示中的應用(轉貼) |
 |
|
預讀取技術在BOM顯示中的應用
郭坤 群華信息技術有限公司
[摘要]隨著計算機技術的發展，全球掀起了信息化的熱潮，實施ERP成為企業信息化最重要的一部分。BOM在ERP系統中起著信息紐帶的作用，本文闡述了如何利用「預讀取技術」對BOM樹狀信息進行實時、快速顯示。
[關鍵字]ERP（Enterprise Resource Planning – 企業資源計劃） BOM（Bill of material – 物料清單） 預讀取技術（Prepare Reading）
1 前言
隨著計算機技術的發展，全球掀起了信息化的熱潮。從1965年第一代ERP（企業資源計劃）開始，幾十年來，經過長期的生產實踐，不斷吸收先進的管理思想，ERP成為了當代企業信息化最重要的一部分。BOM（物料清單），又稱「產品結構表」或「產品結構樹」；在化工及其他領域，也稱為「配方」或「要素表」。它應用於客戶訂單、計劃編製、配套領產、加工跟蹤、採購外協、成本計算、產品報價、產品設計等多個模塊，是ERP中的信息紐帶。
那麼，下面以常用開發軟件Visual Basic 6和SQL Server 2000為例，就實際的開發情況與讀者探討一下如何保證實時、快速顯示BOM樹結構。
2 常用方案比較
BOM本身是樹狀結構，我們通常採用TreeView控件進行實現，產生類似於Windows中資源管理器的效果。要進行實時與快速顯示，關鍵在於如何對BOM結構進行加載，下面就常用於BOM開發中的幾種方法進行比較。
2.1 完全加載法
在查詢某個物料的結構時，一次性將所有層次完全加載，通常採用遞歸的方法來實現。本法編程簡單，只需一次加載。但在物料結構複雜，層次較多時運行速度較慢，並且對於查詢過程中已修改的結構無法實時查看。
2.2 單層加載法
在查詢某個物料的結構時，僅加載其下一層物料，通常在Click事件中進行編碼。本法是屬於按需查詢，只有當用戶點擊了相應的物料，才會查詢其下結構。在實際過程中運行速度快，並且能夠保證實時查詢。但是，在界面上無法清晰顯示某物料的下層物料是否還有子層，需要多次點擊，即無法讓用戶知道是否已到最後一層。
2.3 預讀取加載法
在查詢某個物料的結構時，動態加載其下兩層。這樣在保證了實時查詢的前提下，既提高了速度，又使用戶可以清晰查看結構。
3 分析設計
3.1 靜態圖（類結構）
frmBom
clsSubProduct
-m_strCnn:String
-n_subProduct:RecordSet
-n_ConnectionString:String
-DoLoadNode(inout vNode:Node)
-DoQuery(in strProductID:String)
-btnQuery_Click()
-tvwBom_Expand(in Node:Node)
-tvwBom_NodeClick(in Node:Node)
+get_ConnectionString():String
+let_ConncctionString(in strValue:String)
+get_SubProduct():RecordSet
-Class_Initialize()
+DoQuery(in strProductID:String)
-Class_Terminate()
3.2 數據庫設計
CREATE TABLE 物料檔案
(
物料編碼 VARCHAR(20),
物料名稱 VARCHAR(100),
CONSTRAINT PK_物料檔案 PRIMARY KEY (物料編碼)
)
CREATE TABLE 物料清單
(
物料編碼 VARCHAR(20),
上級編碼 VARCHAR(20),
單位用量 NUMERIC(18, ,
CONSTRAINT PK_物料清單 PRIMARY KEY (物料編碼,上級編碼)
)
3.3 詳細設計
3.3.1 類frmBom
3.3.1.1 文件名：frmBom.frm
3.3.1.2 界面控件列表：
控件類型
控件名稱
屬性設置
Label
Lbl
Name:lbl
AutoSize:True
Caption:」物料編碼」
TextBox
txtProductID
Name:txtProductID
Text:」」
CommandButton
btnQuery
Name:btnQuery
Caption:」查詢」
TreeView
tvwBom
Name:tvwBom
3.3.1.3 代碼：
| 代碼: | Option Explicit
Dim m_strCnn As String '定義模塊級連接字符串變量
Private Sub DoLoadNode(ByRef vNode As Node)
'功能：在TreeView�[載下級物料編碼
'輸入：被�[載的物料節點
'輸出：無
Dim cSubProduct As clsSubProduct
Dim cSubProduct2 As clsSubProduct
Dim nod As Node
Dim nod2 As Node
Dim intI As Integer
'清除所有下級NODE
For intI = 0 To vNode.Children - 1
tvwBom.Nodes.Remove vNode.Child.Key
Next intI
'重新裝入所有下級節點
Set cSubProduct = New clsSubProduct
With cSubProduct
.ConnectionString = m_strCnn
.DoQuery vNode.Tag
While Not .SubProduct.EOF
'�[載第一層子節點
Set nod = tvwBom.Nodes.Add(vNode.Key, tvwChild, vNode.Key & "_" & .SubProduct.Fields("物料編碼").Value, .SubProduct.Fields("物料名稱").Value)
nod.Tag = .SubProduct.Fields("物料編碼").Value
'--------------------------------------------------------
'如果要完全�[載則在此進行遞歸調用
'DoLoadNode nod
'--------------------------------------------------------
Set cSubProduct2 = New clsSubProduct
cSubProduct2.ConnectionString = m_strCnn
cSubProduct2.DoQuery nod.Tag
While Not cSubProduct2.SubProduct.EOF
'�[載第二層子節點
Set nod2 = tvwBom.Nodes.Add(nod.Key, tvwChild, nod.Key & "_" & cSubProduct2.SubProduct.Fields("物料編碼").Value, cSubProduct2.SubProduct.Fields("物料名稱").Value)
nod2.Tag = cSubProduct2.SubProduct.Fields("物料編碼").Value
cSubProduct2.SubProduct.MoveNext
Wend
.SubProduct.MoveNext
Wend
End With
Set cSubProduct = Nothing
End Sub
Private Sub DoQuery(ByVal strProductID As String)
Dim strPID As String
Dim nod As Node
strPID = strProductID
tvwBom.Nodes.Clear
Set nod = tvwBom.Nodes.Add(, tvwNext, "B_" & strPID, strPID)
nod.Tag = strPID
'調用節點�[載子�{序
DoLoadNode nod
End Sub
Private Sub btnQuery_Click()
DoQuery txtProductID.Text
End Sub
Private Sub Form_Load()
'連接字符串，要根據實際�}發環境作相應修改
m_strCnn = "Provider=SQLOLEDB.1;" & _
"Persist Security Info=False;" & _
"User ID=sa;" & _
"Initial Catalog=BOM;" & _
"Data Source=(local)"
End Sub
Private Sub tvwBom_Expand(ByVal Node As MSComctlLib.Node)
'展�}節點時�[載子層
DoLoadNode Node
End Sub
Private Sub tvwBom_NodeClick(ByVal Node As MSComctlLib.Node)
'單擊節點時�[載子層
DoLoadNode Node
End Sub
3.3.2 類clsSubProduct
3.3.2.1 文件名：clsSubProduct.cls
3.3.2.2 代碼：
Option Explicit
Private m_subProduct As ADODB.Recordset
Private m_ConnectionString As String
Public Property Get ConnectionString() As String
ConnectionString = m_ConnectionString
End Property
Public Property Let ConnectionString(ByVal strValue As String)
m_ConnectionString = strValue
End Property
Public Property Get SubProduct() As ADODB.Recordset
Set SubProduct = m_subProduct
End Property
Private Sub Class_Initialize()
Set m_subProduct = New ADODB.Recordset
End Sub
Public Sub DoQuery(ByVal strProductID As String)
Dim strPID As String
strPID = strProductID
With m_subProduct
.ActiveConnection = m_ConnectionString
.CursorLocation = adUseClient
.CursorType = adOpenStatic
.LockType = adLockReadOnly
.Open "SELECT 物料編碼,(SELECT 物料名稱 FROM 物料檔案 WHERE 物料檔案.物料編碼 = 物料清單.物料編碼) AS 物料名稱 FROM 物料清單 WHERE 上級編碼 = '" & strPID & "'"
End With
End Sub
Private Sub Class_Terminate()
Set m_subProduct = Nothing
End Sub |
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!
學會VFP使用者社區的搜尋,Code才會更有趣~
############################# |
|
| 回頂端 |
|
 |
elleryq
註冊時間: 2007-06-21
文章: 768
第 2 樓
|
| 發表於: 星期五 四月 02, 2004 9:05 am 文章主題: |
|
|
| 代碼是用 VB 寫的吧~~ |
|
| 回頂端 |
|
|
syntech
註冊時間: 2003-05-16
文章: 4252
來自: Taipei,Taiwan
第 3 樓
|
| 發表於: 星期五 四月 02, 2004 10:24 am 文章主題: |
|
|
VFP 要動態作treeview, 嗯..... 有點小麻煩......
這種預讀取是沒用的,
因為bom的變更是件大事,
一般而言,bom 的變化是隨當時的產品及成本而變,
而由設計部門提出,經許可後實施,
所以會變動,但是不會經常變動,
可以看的出來,基本上沒有所謂"realtime"的要求,
這其實也表示本文作者是軟體業出身,不是產業出身,
我也常常作一些無聊的功能.... 
當然,M.R.P. & M.R.P.II 應該要追求快速的bom 展開程序,
可是當面對少量多樣的時代時,
單單快速的bom 展開程序已經不能滿足需求,
作個簡單計算,
倘若有2000種不同的產品4000個不同交期要投入生產或採購,
假設平均展開一種要0.5秒,每次都重新展開,
4000個不同交期光光考慮展開就需要2000秒,等於34分鐘,
再加上網路delay,client/server運算資源,還要計算庫存等其他運算,
時間還會再拉長.
這還是訂單排程的情況,若是平衡排程,時間還會繼續增加.
VFP 因為可以對cursor作index,所以還能維持相當快的速度,
若是有些工具無法對cursor作index,變成循序搜尋的話,
情況還會繼續惡化.
再回到本文,會發現他提到的方式其實是不能滿足要求的.
當然,也許他只是針對所謂'bom展開'的部分作說明.
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
|
nelsonchuang
註冊時間: 2003-09-04
文章: 564
來自: 臺灣
第 4 樓
|
| 發表於: 星期二 四月 06, 2004 10:07 am 文章主題: BOM預覽 |
|
|
他只是說預覽吧!不是說計算,應該說只是把資料丟到TREEVIEW,如果是幾百筆的資料在VFP也還好百,要是上萬筆的展開,那當然使用者要等一等了,而且SQL抓資料下來要比TABLE底下做INDEX來得慢啊!
VB的TREEVIEW執效率有沒有VFP好我就不知道了,我新來的同事說VFP執行比較快,不過照我看來可能是因為資料是在SQL SERVER的關係吧!
_________________
大家好,請多指教 |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
