VFP 愛用者社區

[Ruey]

Inno Setup Compiler Version 3.0.7
http://www.jrsoftware.org/
http://www.jrsoftware.org/files/site1/is32.exe
http://www.jrsoftware.org/files/site1/issrc.zip



ISTool 的精靈步驟程序，即可幫你輕鬆地作出安裝程式 Script 檔，
然後再載入 Inno Setup 或 My Inno Setup Extensions 進行編譯。
http://www.istool.org/downloads.aspx



安裝程式生成工具使用教學(簡體)
http://www.cnpug.com/seamanly/hhzp/mise/isxjiaocheng.htm#creatinginstallions

[Ruey]

;原作者lleey lleey@163.com
; 這是由《My Inno Setup Extensions》程序建立的腳本向導程序.
; 有關怎樣建立此腳本的方法請參考幫助以及D:\Inno Setup 2\BDEInst\中的readme文件
; 編寫本腳本所用到的知識（如為什么要復制那些文件、目的是什么，為什么要對注冊表文件進行那樣的修改等）請參考有關文獻。
; 如有疑問請來信共同探討。lleey@163.com
; 愿此腳本對所有志同道合者的學習、開發有所幫助，共同推動IB應用！

[Setup]
AppName=《飛行學院航空理論試題庫系統》
AppVerName=Exam2003
AppPublisher=空軍第十三飛行學院理論訓練處
DefaultDirName={pf}\Exam
DefaultGroupName=Exam
OutputBaseFilename=ExamSetup
Uninstallable=yes
; 如果要在NT 3.51以上版本上運行安裝程序則變下面的注釋行變為運行行即可
; MinVersion=4,3.51

[Types]
;設置若干個安裝主題，供用戶根據不同目的選擇安裝
Name: "ExamBase"; Description: "安裝服務器和題庫"
Name: "Exam"; Description: "安裝組卷子系統"
Name: "MakeBase"; Description: "安裝建庫子系統"
Name: "Custom"; Description: "用戶自由選擇安裝"; Flags: iscustom

[Components]
;本節列出待安裝的所有組件。如果[Type]節中的一個安裝主題需要某個組件，就在此組件對應的Types:保留字后面列出此主題名
Name: IB7clt; Description: 客戶機數據庫系統; Types: ExamBase Exam MakeBase Custom; Flags: fixed
Name: IB7svr; Description: 服務器數據庫系統; Types: ExamBase Custom
Name: Base; Description: 題庫; Types: ExamBase Custom
Name: Maketable; Description: 建庫子系統; Types: MakeBase Custom
Name: Exam; Description: 組卷子系統; Types: Exam Custom

[Dirs]
;設置安裝目錄。其中數據庫系統包括服務器和客戶機均放在C:\windows\system\interbase7文件夾下、而數據庫則放在應用程序存放
;目錄的\base子文件夾下。
Name: {sys}\InterBase7
Name: {sys}\InterBase7\bin;
Name: {app}\base; Components:Base

[Tasks]
Name: "desktopicon"; Description: "創建一個桌面圖標(&D) "; GroupDescription: "添加圖標: "; MinVersion: 4,4; Components: MakeTable exam
[Files]
;==========================================================
;復制數據庫系統。對于任何用到IB7的應用此部分都是一樣的。 ||
;==========================================================
;復制IB7的系統數據庫admin.ib，僅當該文件不存在時復制、卸載時不刪除、只適用于IB7svr組件。以下不再贅述。
Source: E:\Borland\InterBase7\admin.ib; DestDir: {sys}\InterBase7; CopyMode: onlyifdoesntexist; Flags: uninsneveruninstall; Components: IB7svr
Source: E:\Borland\InterBase7\ibconfig; DestDir: {sys}\InterBase7; CopyMode: normal; Components: IB7svr
Source: E:\Borland\InterBase7\interbase.msg; DestDir: {sys}\InterBase7; CopyMode: normal; Flags: sharedfile; Components: IB7clt
;將設置3050耑口的文件復制到臨時目錄。
Source: E:\Borland\InterBase7\Set3050.exe; DestDir: {tmp}; Flags: deleteafterinstall
Source: E:\Borland\InterBase7\bin\ibguard.exe; DestDir: {sys}\InterBase7\bin; CopyMode: alwaysskipifsameorolder; Components: IB7svr; Flags: sharedfile
Source: E:\Borland\InterBase7\bin\ibserver.exe; DestDir: {sys}\InterBase7\bin; CopyMode: alwaysskipifsameorolder; Components: IB7svr; Flags: sharedfile
Source: E:\Borland\InterBase7\bin\instreg.exe; DestDir: {sys}\InterBase7\bin; Components: IB7clt
Source: C:\Windows\System\gds32.dll; DestDir: {sys}; CopyMode: alwaysskipifsameorolder; Flags: sharedfile; Components: IB7clt
Source: C:\Windows\System\msvcrt.dll; DestDir: {sys}; CopyMode: onlyifdoesntexist; Flags: uninsneveruninstall sharedfile; Components: IB7clt
;復制許可証
Source: "E:\Borland\InterBase7\ib_license.dat"; DestDir: "{sys}\InterBase7"; CopyMode: normal; Components: IB7svr
; 在Win9x/Me系統下復制服務器中止服務器文件 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Source: E:\Borland\InterBase7\bin\stopsrv.exe; DestDir: {sys}\InterBase7\bin; CopyMode: alwaysskipifsameorolder; MinVersion: 4.0,0; Components: IB7svr
; 在NT/2000系統下復制將IB7設置為NT服務的文件 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Source: E:\Borland\InterBase7\bin\instsvc.exe; DestDir: {sys}\InterBase7\bin; CopyMode: alwaysskipifsameorolder; MinVersion: 0,4.0; Components: IB7svr
;==================================================================================================
;復制組卷子系統。以上是關于數據庫系統的復制，以下是應用程序的復制，各用戶可自由決定下面的復制內容||
;==================================================================================================
Source: "E:\Exam\bintest\exam.exe"; DestDir: "{app}"; DestName: "exam.exe"; CopyMode: normal; Components: Exam
Source: "E:\Exam\bintest\exam.ini"; DestDir: "{app}"; CopyMode: normal; Components: Exam
Source: "E:\Exam\bintest\ExamHor.dot"; DestDir: "{app}"; CopyMode: normal; Components: Exam
Source: "E:\Exam\bintest\ExamVer.dot"; DestDir: "{app}"; CopyMode: normal; Components: Exam
Source: "E:\Exam\bintest\config.ini"; DestDir: "{app}"; CopyMode: normal; Components: Exam Maketable
;復制建庫子系統
Source: "E:\Exam\Maketable\Maketable.exe"; DestDir: "{app}"; CopyMode: normal; Components: Maketable
Source: "E:\exam\PrtTable\PrtTable.exe"; DestDir: "{app}"; CopyMode: normal; Components: Maketable
;復制題庫
Source: "E:\exam\Base\Exam.ib"; DestDir: "{app}\base"; CopyMode: normal; Components: Base


[Registry]
;====================================================
;此部分是對注冊表的修改，具體內容可參考相關文檔說明||
;====================================================
; 僅對Win9x/Me ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Root: HKLM; Subkey: Software\Microsoft\Windows\CurrentVersion\Run; ValueType: string; ValueName: InterBaseGuardian; ValueData: {app}\bin\ibguard.exe; MinVersion: 4.0,0; Flags: uninsdeletevalue; Components: IB7svr
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;此行是設置IB7的版本號，務必是真實的版本號，否則會造成其他安裝程序的錯誤判斷
Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: string; ValueName: Version; ValueData: WI-V7.0.1.1; Flags: uninsdeletevalue; Components: IB7svr
Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: string; ValueName: ServerDirectory; ValueData: {sys}\InterBase7\bin; Flags: uninsdeletevalue; Components: IB7svr
Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; Flags: uninsdeletekeyifempty; Components: IB7svr
Root: HKLM; Subkey: Software\Borland\InterBase; Flags: uninsdeletekeyifempty; Components: IB7svr
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 為向下兼容
;Root: HKLM; Subkey: Software\Borland\InterBase; ValueType: DWord; ValueName: UseCount; ValueData: {reg:HKLM\Software\Borland\InterBase, UseCount|0} + 1
;Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: DWord; ValueName: UseCount; ValueData: {reg:HKLM\Software\Borland\InterBase\CurrentVersion, UseCount|0} + 1
; obsolete - Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: string; ValueName: DefaultMode; ValueData: -r; Components: Server
Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: string; ValueName: GuardianOptions; ValueData: 1; Components: IB7svr
Root: HKLM; Subkey: Software\Borland\InterBase\CurrentVersion; ValueType: string; ValueName: ServerDirectory; ValueData: {sys}\InterBase7\bin\; Components: IB7svr
; Software\Borland\InterBase\CurrentVersion\RootDirectory
; &
; Software\Borland\InterBase\CurrentVersion\Version
; 的鍵值由instreg.exe文件自行設置,此文件還將刪除Software\Borland\InterBase鍵名下的空鍵名
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

[Icons]
Name: "{group}\組卷"; Filename: "{app}\exam.exe"; Components: Exam
Name: "{group}\建庫"; Filename: "{app}\maketable.exe"; Components: Maketable
Name: "{group}\打印題庫"; Filename: "{app}\prttable.exe"; Components: Maketable
Name: "{userdesktop}\組卷"; Filename: "{app}\exam.exe"; Components: Exam
Name: "{userdesktop}\建庫"; Filename: "{app}\maketable.exe"; Components: Maketable
Name: "{userdesktop}\打印題庫"; Filename: "{app}\prttable.exe"; Components: Maketable
Name: "{group}\卸載"; Filename: "{app}\unins000.exe"

[Run]
;在結束安裝之前運行此節所規定的內容
;==================================
;運行臨時文件夾中的Set3050.exe，目的是設置3050口，此口是IB7所默認的通信監視口
Filename: {tmp}\Set3050.exe; Flags: runminimized
;運行instreg.exe，目的是對一些特殊的注冊表內容進行設置。
Filename: {sys}\InterBase7\bin\instreg.exe; Parameters: "install ""{sys}\InterBase7"""; Flags: nowait runminimized
; 只對NT/2000，目的是將IB7服務器設置成NT eservice(NT服務）;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Filename: {sys}\InterBase7\bin\instsvc.exe; Parameters: install {sys}\InterBase7 -auto -z; Flags: runminimized; MinVersion: 0,4.0; Components: IB7svr
Filename: {sys}\InterBase7\bin\instsvc.exe; Parameters: start; Flags: nowait runminimized; MinVersion: 0,4.0; Components: IB7svr
; 只對Win9x/Me ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Filename: {sys}\InterBase7\bin\ibguard.exe; Flags: nowait; MinVersion: 4.0,0; Components: IB7svr
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;