VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

myf1 作者:前度劉郎

用應用程式角色來保證資料庫的安全性
保護登錄到SQL Server的密碼一直是個頭疼的問題。
不管怎樣，你都必須要建立一個ODBC連接和一個VFP中的資料庫連接，資料庫中連接的密碼則非常容易洩漏，到目前為止，似乎最安全的做法只有用ODBC API 來在運行時建立連接——但問題是，如果用戶是個有經驗的程式師，那麼他會在程式運行時、或者乾脆殺死程式的進程，不讓你的程式中自動在退出時刪除連接的部分代碼運行，這樣他就又有可能得到你的ODBC連接密碼了。
UT雜誌上提供了一個更安全的方法。用這個方法，對方只有反編譯了你的程式才可能得到真正的密碼。這個做法就是使用SQL Server的應用程式角色。
1、策略
首先，你的程式還是要建立一個普通的ODBC連接和一個資料庫連接。秘訣在於：你在 SQL Server 上為用戶建立的是一個只能連接到資料庫、但是沒有任何對任何表物件的 Select 、Update、Delete許可權的 Public 角色。
你的應用程式在啟動時用這個ODBC連接來連接到資料庫，然後，再使用應用程式角色來獲得對資料表物件的訪問許可權。應用程式角色的密碼則隱藏在程式中，因為它不用建立ODBC連接，所以它的密碼也就不容易洩漏。
2、做法
A、伺服器端設置
打開 SQL Server 企業管理器，在你的資料庫目錄下的角色節點上單擊右鍵，選擇【新建資料庫角色】，然後在打開的資料庫角色對話方塊中選擇【應用程式角色】，並設置好密碼。
關閉對話方塊後，選擇這個新建的應用程式角色,單擊右鍵選擇【屬性】，在打開的屬性對話方塊中單擊【許可權】，為這個角色設置訪問每個資料表的許可權。
B、應用程式設置
用只能連接到資料庫、沒有訪問任何表的許可權的ODBC連接來連接到 SQL Server 以後，再使用 SPT 來在當前連接上啟動應用程式角色。
OK，這樣就有一個問題，你這個連接啟動以後，搗蛋的人是不是又可以用這個ODBC連接來玩火了？不行，應用程式角色的啟動只在當前連接上有效，如果要新建一個連接，那麼必須再次啟動應用程式角色。這樣一來，除了你的應用程式以外，沒有任何人能夠利用上已經被啟動的連接了。：）
啟動應用程式角色的辦法：使用系統存儲過程 Sp_Setapprole。T-SQL 的語法是：
sp_setapprole 'rolename', 'password' [, 'encrypt style']
前面兩個參數就是應用程式角色名稱和密碼。第三個參數可用可不用，它表示對密碼的加密方式，NONE 表示不加密，ODBC 表示用ODBC 的加密API來將密碼加密後再發送到伺服器上。
好了，現在我們可以享受應用程式角色只在當前連接上有效的好處了。但是還有一點小問題，你必須知道當前連接上是否已經啟動了應用程式角色，如果在已啟動的連接上試圖再次啟動，會發生一個錯誤。
判斷當前連接是否已經啟動要用一點迂回的辦法：試著檢查當前連接是否擁有對某個表的訪問許可權。這要用到T-SQL 的 PERMISSIONS 函數。
PERMISSIONS 函數接受2個參數。第一個參數，是目標的物件標誌符。第二個參數可用可不用，它是一個欄位的名稱。如果PERMISSIONS返回0，則當前連接對目標沒有訪問許可權；如果返回的是其他值，則擁有對目標的訪問許可權。
這裏說的目標，指的是SQL Server中的某個物件，比如一個表物件、或者一個角色物件。目標的物件標誌符則是 SQL Server 為每個物件建立的一個識別碼，這個識別碼可以用 T-SQL 的 OBJECT_ID 函數來取得。
OK，現在我們知道了，檢查當前連接是否對某個表有許可權的T-SQL代碼就是：
select PERMISSIONS(OBJECT_ID(‘your_table_name’))
下面是一段 SQL Passthrough 的示例代碼：
LOCAL liHandle as Integer, liResult as Integer
** 獲得一個連接控制碼
liHandle = SQLCONNECT('Northwind')
** 檢查許可權
liResult = SQLEXEC(liHandle, ;
"select permissions(object_id('customers')) as iPermissions", "PermissionCheck")
IF liResult > 0
IF PermissionCheck.iPermissions = 0
** 需要啟動應用程式角色
liResult = SQLEXEC(liHandle, "exec sp_setapprole 'MyAppRole', 'MyAppRolePassword'")
IF liResult < 0
** 在啟動應用程式角色的時候發生了錯誤
ENDIF
ENDIF
ELSE
** 在檢查許可權的時候發生了錯誤
ENDIF
** 現在就可以正常操作了
SQLEXEC(liHandle, 'select top 10 * from customers')
BROWSE
SQLDISCONNECT(liHandle)
C、應用到 CursorAdapter 上
以下代碼為建立一個自定義的 CursorAdapter 類：
DEFINE CLASS MyCursorAdapter as CursorAdapter
FUNCTION BeforeCursorFill( ;
tlUseCursorSchema as Logical, tlNoDataOnLoad as Logical, tcSelectCmd) as Logical
** 覆蓋 BeforeCursorFill 方法來啟動應用程式角色
LOCAL llRetVal as Logical

llRetVal = DODEFAULT(tlUseCursorSchema, tlNoDataOnLoad, tcSelectCmd)
IF llRetVal
** 啟動應用程式角色
llRetVal = This.LogOnToAppRole()
ENDIF

RETURN llRetVal
ENDFUNC

PROTECTED FUNCTION LogOnToAppRole() as Logical
** 啟動應用程式角色，並返回一個邏輯值說明是否啟動成功
LOCAL liHandle as Integer, llRetVal as Logical

** 獲得連接控制碼
liHandle = This.DataSource

IF liHandle > 0
** 檢查應用程式角色是否已經設置好了
IF !This.AppRoleSet()

** 如果沒有，那麼現在設置它
IF SQLEXEC(liHandle, "exec sp_setapprole 'MyAppRole', 'MyAppRolePassword'") > 0
llRetVal = .t.
ELSE
llRetVal = .f.
ENDIF
ELSE
** 應用程式角色已經設置好了
llRetVal = .t.
ENDIF
ELSE
** 當前沒有一個有效的連接控制碼
llRetVal = .f.
ENDIF

RETURN llRetVal
ENDFUNC

PROTECTED FUNCTION AppRoleSet() as Logical
** 檢查應用程式角色是否已經設置好
LOCAL llRetVal as Logical, lcAlias as Character

** 保存當前別名
lcAlias = ALIAS()
** 檢查在表上的許可權
IF SQLEXEC(This.DataSource, ;
"select permissions(OBJECT_ID('" + This.Alias + "')) as iPermissions", ;
'approlepermission') > 0
** 如果 permissions 返回 0, 那麼就是應用程式角色沒有啟動
llRetVal = (AppRolePermission.iPermissions <> 0)
ELSE
llRetVal = .f.
ENDIF

** 清理
IF USED('AppRolePermission')
USE IN AppRolePermission
ENDIF

IF !EMPTY(lcAlias)
SELECT (lcAlias)
ENDIF
RETURN llRetVal
ENDFUNC

ENDDEFINE
使用這個類的代碼：
LOCAL loCustomers as CursorAdapter
LOCAL liHandle as Integer
** 建立一個連接
liHandle = SQLCONNECT('Northwind')
IF liHandle > 0
** 現在已經連接上了
** 建立一個對 cursor adapter 類的引用
loCustomers = NEWOBJECT('MyCursorAdapter', 'MyCursorAdapter.prg')
** 設置一些屬性，包括連接控制碼
WITH loCustomers
.DataSource = liHandle
.DataSourceType = 'ODBC'
.SelectCmd = 'Select * from customers'
.Alias = 'Customers'
ENDWITH
** 下載數據
IF loCustomers.CursorFill()
BROWSE
ELSE
MESSAGEBOX(MESSAGE())
ENDIF
ENDIF
** 斷開連接
SQLDISCONNECT(liHandle)
這確實是一個保護安全性的好辦法。相比不久之後，這種辦法就將成為我們 foxer 的標準辦法了吧！：）