VFP 愛用者社區

朱育興 · 註冊時間: 2003-08-25 文章: 661 來自: 台中市大里區 第 1 樓

[VFP9重點]……輕鬆連結Windows事件……

下面是 FOXTALK ０５年１月刊中的免費文章，更多內容見： http://foxer.xicp.net。訂戶通知：FOXTALK中文版０５年１月刊已發佈，請自取。。。
：

輕鬆連結 Windows 事件
作者：Doug Hennig
譯者：fbilo

VFP 所缺少的在其它開發環境中的一個功能是捕捉 Windows 事件的能力。VFP 9 擴展了 BindEvent()函數的功能，現在，當 Windows 傳遞某些特定的訊息給 VFP 視窗的時候，BindEvent()可以呼叫我們自己的程式碼。這個功能有著很廣泛的用途，Doug Hennig 在這裏為我們講述了一部分。

Windows 通過傳遞訊息來把事件傳送給應用程式。儘管 VFP 已經通過 VFP 物件中的事件為我們提供了這些訊息的一部分——比如 MouseDown 和 Click——但還是有許多訊息對 VFP 程式人員來說是不可用的。
一個常見的需求是要能夠檢測到使用者在應用程式之間切換的事件。例如，我建立了一個應用程式，該應用掛鉤在一個著名的聯繫人管理系統 GoldMine 中，以為目前聯繫人顯示更多的訊息。如果使用者切換到 GoldMine，然後選擇了另一個聯繫人，那麼，當他再次切換回我的應用程式的時候，我的應用程式就應該進行更新，以顯示新聯繫人的訊息。不幸的是，在以前版本的 VFP 中是不可能做到這一點的；我只有依靠計時器來不斷的檢查目前顯示在 GoldMine 中的是哪個聯繫人。

VFP 9 擴展了在 VFP 8 中增加的 BindEvent() 函數的功能以支援 Windows 訊息。實現這個功能的語法是：
bindevent(hWnd, nMessage, oEventHandler, cDelegate)

在這裏，hWnd 是接收事件的視窗的 Windows 控制碼，nMessage 是 Windows 訊息編號，而 oEventHandler 和 cDelegate 是當視窗接收到訊息的時候被觸發的對象和方法。與 VFP 事件不同的是，只有一個事件處理器（oEventHandler）可以被連結給一個特定的 hWnd 和 nMessage 組合。指定第二個事件處理器物件或者代理方法會導致第一個連結被替換為第二個。VFP 不會對 hWnd 或 nMessage 的值的有效性進行檢查；如果其中一個無效，就什麼都不會發生，因為指定的視窗將無法接收到指定的訊息。
對於 hWnd，你可以指定 _Screen.hWnd 或者 _VFP.hWnd 來跟蹤那些發送給應用程式的訊息，或者指定一個表單的 hWnd 來跟蹤發送給該表單的訊息。VFP 控制項沒有 Windows 控制碼，但是 ActiveX 控制項有，所以你也可以連結到它們身上。
Windows 中有著數百個 Windows 訊息。這類別的訊息有：WM_POWERBROADCAST(0x0218)，該訊息在電池電量過低、或者切換到掛起模式這樣的電來源事件發生時被發出、WM_THEMECHANGED(0x031A)，它表示 Windows XP 桌面主題已經被更換；還有 WM_ACTIVATE(0x0006)，它在切換到一個應用程式、或者從應用程式切換出來的時候被觸發（Windows 訊息通常用一個以WM_開頭的名字來引用）。

在網址：http://msdn.microsoft.com/library/en-us/winui/winui/windowsuserinterface/windowui.asp 處有著幾乎所有的 Windows 訊息的文字檔。而作為 Platform SDK 一部分的 WinUser.H 檔案中有著那些 WM_ 開頭的常數的值，你可以從 www.microsoft.com/msdownload/platformsdk/sdkupdate/ 處下載這個 Platform SDK。
事件處理器的方法必須接收4個參數：hWnd，是接收訊息的視窗的控制碼；nMessage，是 Windows 訊息的編號；還有兩個 Integer 參數，它們的值隨著 Windows 訊息的不同而不同（每個訊息的文字檔解釋了這些參數的值）。方法必須傳回一個 Integer，其中包含著一個結果的值。一種可能的傳回值是 BROADCAST_QUERY_DENY(0x424D5144，代表字串「BMQD」)，意思是事件的發生被阻止了。
如果你想讓訊息通過那種大多數事件處理器應做的常規方式來被處理，你就必須在你的事件處理器方法中呼叫 VFP 的 Windows 訊息處理器；這是種就像是在 VFP 方法程式碼中使用 DODEFAULT() 這樣的辦法。你的事件處理器方法很像是傳回 VFP 的 Windows 訊息處理器的傳回值。這裏是一個事件處理器完成這種任務的一個範例（別的它什麼都不幹）：

lparameters hWnd, ;
Msg, ;
wParam, ;
lParam
local lnOldProc, ;
lnResult
#define GWL_WNDPROC -4

declare integer GetWindowLong in Win32API ;
integer hWnd, integer nIndex

declare integer CallWindowProc in Win32API ;
integer lpPrevWndFunc, integer hWnd, integer Msg, ;
integer wParam, integer lParam

lnOldProc = GetWindowLong(_screen.hWnd, GWL_WNDPROC)
lnResult = CallWindowProc(lnOldProc, hWnd, Msg, ;
wParam, lParam)
return lnResult

當然，事件處理器不需要每次都聲明 Windows API 函數或者呼叫 GetWindowLog；你可以把這些程式碼放在類別的 Init 事件中，把 GetWindowLong 的傳回值儲存在一個自定義屬性中，然後在事件處理器要呼叫 CallWindowProc 的時候使用這個屬性。後面的範例會用這種方法來做。

為了判定連結的是哪種訊息，可以使用 AEVENTS(ArrayName,1)。它會在指定的陣列中為每個連結分配一列和四行，並用被傳遞給 BINDEVENT()的參數的值對元素們進行填充。
你可以使用 UNBINDEVENT(hWnd[,nMessage])來取消事件連結。忽略第二個參數的話，就會取消對指定視窗的所有訊息的連結。只給這個函數傳遞一個0會取消對所有視窗的所有訊息的連結。在事件處理器物件被釋放以後，再次發生訊息時事件也會自動取消連結。
一個新版本的 VFP 怎麼會沒有一些新的 SYS() 函數呢？在 VFP 9.0 中新增了三個與 Windows 事件相關的 SYS()函數：
� SYS(2325, wHandle)為一個由傳遞進來的wHandle（VFP對 hWnd 的一個內部封裝）指定的視窗傳回它的使用者端視窗的 wHandle（一個使用者端視窗是一個在一個視窗內部的視窗；例如，_Screen 是 _VFP 的一個使用者端視窗）。
� SYS(2326,hWnd)傳回用 hWnd 指定的視窗的 wHandle。
� SYS(2327,wHandle)為用 wHandle 指定的視窗傳回其 hWnd。這些函數的文字檔指出，它們是在使用了 VFP API 函式庫結構工具包的情況下用於BINDEVENT()函數的。不過，從下面的範例中可以看到，你也可以使用它們來獲得一個 VFP IDE 視窗的使用者端視窗的 hWnd。

連結到 VFP IDE 視窗事件

包含在這個月下載檔案中的 TestWinEventsForIDE.PRG 示範了怎麼將事件連結到 VFP 的 IDE 視窗。將你想要連結事件的 IDE 視窗的 Caption 設定為 lcCaption（下面的程式碼將使用命令視窗來示範），然後執行這個程式。啟動和取消啟動該視窗，移動、縮放視窗等等；你將看到對 Screen 做出反應的 Windows 事件。試驗完了的時候，在命令視窗裏輸入 RESUME 並按下歸位來進行清理。要用這段程式碼對一個 IDE 視窗中的使用者端視窗進行測試的話，需要將程式碼中被註釋掉的部分解除註釋。
你也可以通過給這段程式碼增加 BINDEVENT() 敘述來連結其它的事件；為希望連結的事件使用在WinEvents.H中的常數的值。注意，TestWinEventsForIDE.PRG只工作於非可停靠IDE視窗，所以，在你執行這個程式之前要先在你想要測試的視窗的標題欄上按一下滑鼠右鍵、確保可停靠選項已被關閉。
這裏是這個 PRG 的程式碼：

#include WinEvents.H

lcCaption = 'Command'
loEventHandler = createobject('IDEWindowsEvents')
lnhWnd = ;
loEventHandler.FindIDEWindow(lcCaption)

* 解除註釋下面的程式碼以接收使用者端視窗的事件
*lnhWnd = ;

loEventHandler.FindIDEClientWindow(lcCaption)
if lnhWnd > 0
bindevent(lnhWnd, WM_SETFOCUS, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_KILLFOCUS, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_MOVE, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_SIZE, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_MOUSEACTIVATE, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_KEYDOWN, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_KEYUP, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_CHAR, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_DEADCHAR, loEventHandler, ;
'EventHandler')
bindevent(lnhWnd, WM_KEYLAST, loEventHandler, ;
'EventHandler')
clear
suspend
unbindevents(0)
clear
else
messagebox('The ' + lcCaption + ;
' window was not found.')
endif lnhWnd > 0

define class IDEWindowsEvents as Custom
cCaption = ''
nOldProc = 0
function Init
declare integer GetWindowLong in Win32API ;
integer hWnd, integer nIndex
declare integer CallWindowProc in Win32API ;
integer lpPrevWndFunc, ;
integer hWnd, integer Msg, ;
integer wParam, integer lParam
declare integer FindWindowEx in Win32API;
integer, integer, string, string
declare integer GetWindowText in Win32API ;
integer, string @, integer
This.nOldProc = GetWindowLong(_screen.hWnd, ;
GWL_WNDPROC)
endfunc

function FindIDEWindow(tcCaption)
local lnhWnd, ;
lnhChild, ;
lcCaption
This.cCaption = tcCaption
lnhWnd = _screen.hWnd
lnhChild = 0

do while .T.
lnhChild = FindWindowEx(lnhWnd, lnhChild, 0, 0)
if lnhChild = 0
exit
endif lnhChild = 0

lcCaption = space(80)
GetWindowText(lnhChild, @lcCaption, len(lcCaption))
lcCaption = upper(left(lcCaption, ;
at(chr(0), lcCaption) - 1))
if lcCaption = upper(tcCaption)
exit
endif lcCaption = upper(tcCaption)
enddo while .T.
return lnhChild
endfunc

function FindIDEClientWindow(tcCaption)
local lnhWnd, ;
lnwHandle, ;
lnwChild
lnhWnd = This.FindIDEWindow(tcCaption)

if lnhWnd > 0
lnwHandle = sys(2326, lnhWnd)
lnwChild = sys(2325, lnwHandle)
lnhWnd = sys(2327, lnwChild)
endif lnhWnd > 0
return lnhWnd
endfunc

function EventHandler(hWnd, Msg, wParam, lParam)
? 'The ' + This.cCaption + ;
' window received event #' + transform(Msg)
return CallWindowProc(This.nOldProc, hWnd, Msg, ;
wParam, lParam)
endfunc
enddefine

這段程式碼從建立 IDEWindowsEvents 類別的實例開始。它呼叫 FindIDEWindow 方法程序來獲得對一個其 Caption 儲存在 lcCaption 變數中的視窗的控制碼。然後它使用 BindEvent()來將所需視窗的特定事件連結到這個類別的 EventHandler 方法程序。這些事件包括啟動、取消啟動、縮放、移動視窗、以及在視窗中的鍵擊。
IDEWindowsEvents 的 Init 事件聲明了這個類別要用到的 Windows API 函數。它還定義了用於呼叫 VFP 的 WIndows 訊息處理器的值，並將這個值儲存在 nOldProc 屬性中；EventHandler 方法程序使用這個值來確保常規的事件處理會正常發生。FindIDEWindow 方法程序使用一對 Windows API 函數來找到指定的 VFP IDE 視窗。它是通過遍歷 _VFP 的每個子視窗、並將各個子視窗的 Caption 和被作為參數傳遞進來的 Caption 進行對比來完成這個任務的。FindIDEClientWindow做的是類似的事情，不過使用了新的 SYS() 函數來獲得對指定視窗的使用者端視窗的控制碼。
當你執行 TestWinEventsForIDE.PRG 的時候，你會發現並非每個 IDE 或者使用者端視窗都會發生每個事件。例如，在屬性視窗中你不會看到 keypress 事件的發生。這很可能是由於 VFP 實現視窗的方式與別的 Windows 應用程式不同所導致的。
注意：通常你不會在一個典型的應用程式中使用類似於這裏的程式碼；它只是向那些想要給 VFP 的 IDE 增加自己所需行為的程式人員提供的。下一個範例中用到的技術你可能會用在一個最終使用者的應用程式中。

連結到應用程式視窗和磁碟事件

WindowsMessagesDemo.SCX （見圖1）示範了掛鉤到啟動和取消啟動以及特定的一些 Windows Shell 事件——例如插入或取出一張 CD 或者 USB 設備。下面示範了一個 Windows 事件的有趣的用途：這些程式碼將一個 Windows Shell 事件的子集當作是一個自定義 Windows 事件，並將_VFP 註冊為接收這個自定義Windows事件。

圖1、WindowsMessagesDemo.SCX 示範了你的應用程式可能會需要的幾個 Windows 事件。
這個表單的 Init 事件會處理必要的設定問題。跟 TestWinEventsForIDE.PRG 一樣，它聲明了幾個 Windows API 函數，並將用於 VFP 的 Windows 事件處理器的值儲存在 nOldProc 屬性中。使用自定義的訊息 WM_USER_SHNOTIFY 來呼叫SHChangeNotifyRegister 以讓 Windows 把 _VFP 註冊為接收磁碟事件、媒體的插入和移除事件、以及設備的增加和減少事件（在下面的程式碼中，大寫的標誌符號是定義在 WinEvents.H 或者 ShellFileEvents.H 中的常數）。
然後這段程式碼為表單將啟動事件和設備更動事件以及它剛剛為 _VFP 定義的自定義訊息連結到表單的 HandleEvents 方法程序。注意：對 SHChangeNotifyRegister 的呼叫要求 Windows XP 或更高的版本。如果你在使用一個更早版本的操作系統，請將為 This.nSHNotify 賦值的敘述註釋掉。
local lcSEntry

* 聲明要用到的 Windows API 函數
declare integer GetWindowLong in Win32API ;
integer hWnd, integer nIndex
declare integer CallWindowProc in Win32API ;
integer lpPrevWndFunc, integer hWnd, integer Msg, ;
integer wParam, integer lParam
declare integer SHGetPathFromIDList in shell32 ;
integer nItemList, string @szPath
declare integer SHChangeNotifyRegister in shell32 ;
integer hWnd, integer fSources, integer fEvents, ;
integer wMsg, integer cEntries, string @SEntry
declare integer SHChangeNotifyDeregister in shell32 ;
integer

* 為 VFP 視窗事件處理器取得一個控制碼
This.nOldProc = GetWindowLong(_screen.hWnd, ;
GWL_WNDPROC)

* 註冊 _VFP 來把特定的 shell 事件當作一個自定義 Windows 事件接收
lcSEntry = replicate(chr(0), Cool

This.nShNotify = SHChangeNotifyRegister(_vfp.hWnd, ;
SHCNE_DISKEVENTS, SHCNE_MEDIAINSERTED + ;
SHCNE_MEDIAREMOVED + SHCNE_DRIVEADD + ;
SHCNE_DRIVEREMOVED, WM_USER_SHNOTIFY, 1, @lcSEntry)

* 連結到我們感興趣的Windows事件
bindevent(This.hWnd, WM_ACTIVATE, This, 'HandleEvents')
bindevent(_vfp.hWnd, WM_DEVICECHANGE, This, 'HandleEvents')
bindevent(_vfp.hWnd, WM_USER_SHNOTIFY, This, 'HandleEvents')

* 隱藏 VFP 主視窗以便更清楚的看到接下來會發生什麼
_screen.Visible = .F.

HandleEvents 方法程序處理已註冊了的事件。它使用一個 CASE 敘述來判定發生了哪個事件，並相對應的更新在表單上的狀態標籤的 Caption。特定的事件類型有著由 wParam 參數標識的「子事件」；這是用來準確的判定發生了什麼事件用的。例如，當一個 WM_ACTIVATE 事件發生的時候，wParam 指出視窗目前是啟動了的還是沒有啟動、以及啟動的發生是否是由任務切換（例如使用者按下了 Alt+Tab）或者在視窗上按一下而導致的。
處理自定義的 Shell 事件要比其它事件複雜一些。在這個案例中，lParam 用來識別出事件，而 wParam 則包含著一個記憶體位址，該位址指向的是用於表示被插入或者移除的驅動器的路徑。然後，SYS(2600)被用來從位址中拷貝出位址所指向的記憶體中的值，自定義的 BinToInt 方法程序（程式碼這裏沒有放出來）把這個值轉換成一個整數型態，而 Windows API 函數 SHGetPathFromIDList 則從這個整數型態中提取出真正的路徑。最後，這個方法程序呼叫 HandleWindowsMessage 方法程序，後者簡單的呼叫 CallWindowsProc 來獲得常規的事件處理行為。這裏是 HandleEvents 的程式碼：

lparameters hWnd, ;
Msg, ;
wParam, ;
lParam
local lcCaption, ;
lnParm, ;
lcPath

do case
* 處理一個 activate 或者 deactivate 事件
case Msg = WM_ACTIVATE
do case
* 處理一個 deactivate 事件
case wParam = WA_INACTIVE
This.lblStatus.Caption = 'Window deactivated'
* 處理一個 activate 事件 (任務切換或者在標題欄上按一下）
case wParam = WA_ACTIVE
This.lblStatus.Caption = ;
'視窗啟動 (任務切換)'
* 處理一個 activate 事件 (在視窗的使用者端區域按一下).
case wParam = WA_CLICKACTIVE
This.lblStatus.Caption = ;
'視窗啟動 (按一下)'
endcase

* 處理一個設備更動事件
case Msg = WM_DEVICECHANGE
do case
case wParam = DBT_DEVNODES_CHANGED
This.lblStatus.Caption = 'DevNodes 已變動'
case wParam = DBT_DEVICEARRIVAL
This.lblStatus.Caption = '設備增加'
case wParam = DBT_DEVICEREMOVECOMPLETE
This.lblStatus.Caption = '設備移除 ' + ;
'完成'
endcase
* 處理一個自定義 shell 通知事件
case Msg = WM_USER_SHNOTIFY
do case
case lParam = SHCNE_DRIVEADD
lcCaption = '驅動器已增加'
case lParam = SHCNE_DRIVEREMOVED
lcCaption = '驅動器被移除'
case lParam = SHCNE_MEDIAINSERTED
lcCaption = '媒體已插入'
case lParam = SHCNE_MEDIAREMOVED
lcCaption = '媒體已移除'
endcase

lnParm = This.BinToInt(sys(2600, wParam, 4))
lcPath = space(270)
SHGetPathFromIDList(lnParm, @lcPath)
lcPath = left(lcPath, at(chr(0), lcPath) - 1)
This.lblStatus.Caption = lcCaption + ': ' + lcPath
endcase
return This.HandleWindowsMessage(hWnd, Msg, wParam, ;
lParam)

執行這個表單，然後像介紹中指出的那樣在其它視窗或者桌面上按一下再回到表單上以顯示啟動和反啟動事件。插入或者移除一個某種類型的可移動驅動器，比如一個 USB 驅動器或者一個數位相機，以瞭解事件的發生情況。
在該表單中的這類程式碼有幾個實用的用途。例如，我在本文前面提到的 GoldMin 插件現在可以在接收到一個 Activate 事件的時候更新自己了。當我把我的帶有一個 USB 延長線的數位相機連接到我的電腦上的時候，數位相機自帶的軟體就會彈出視窗提示我去下載照片。一個 VFP 房地產或者醫學圖像應用程式可以對建築或者傷口的照片做到類似的事情。

其它用途

連結 Windows 事件還有大量其它的用途。例如，你可以在特定的條件下（比如一個重要的進程尚未完成）阻止 Windows 關機。在那樣的情況下，你最好連結到 WM_POWERBROADCAST 訊息，並且在不應關機的時候傳回 BROADCAST_QUERY_DENY。
我用 Microsoft Money 來管理我的家庭財務，當我從銀行下載了一個帳單的時候，Money立刻就會知道並且顯示相對應的對話方塊，我很喜歡這種功能。這類別的行為現在在 VFP 應用程式中也能夠做到了；現在，你的應用程式不再需要不停的去檢查一個路徑以搞清是否增加（或者減少、重命名）了一個檔案，這種事情一發生，你的應用程式就會被通知，從而做出相對應的反應。
結論
支援 Windows 事件連結是VFP一個令人難以置信的增強，它讓你可以掛鉤到發生在 Windows 中的任何事情。既然 VFP 社群已經開始研究它的能力了，那麼我期待著看到它的更酷的用法。

下載檔案：501HENNIG.ZIP