VFP 愛用者社區

[pnyjq]

*************************************************************
* 模块名称：tohtml.prg
* 模块功能：生成html表格
* 使用环境：VFP9.0 ,由于使用了cast()函数，故不能用于8.0以下版本
* 调用方法：1、保存到一个网页文件
* strtofile(tohtml(),"d:\vfp.htm")
*
* 2、在com中调用

* Select * from Mytable
* local lcResult as string
* lcResult = ''
* lcResult = lcResult + web_top() && 网页顶部
* lcResult = lcResult + tohtml() && 表格内容
* lcResult = lcResult + web_root() && 网页底部

* CLOSE DATABASES ALL

* RETURN lcResult
*
* 最后修改：2004-8-31
* 编写：PNYJQ
*************************************************************
#DEFINE lcEnter CHR(13) + CHR(10)
#DEFINE lcRecorBegin [ <tr>] + lcEnter
#DEFINE lcRecorEnd [ </tr>] + lcEnter
#DEFINE lcFielBegin [ <td>]
#DEFINE lcFielEnd [</td>] + lcEnter
#DEFINE lcNodata [抱歉！找不到您查询的数据]

IF EMPTY(ALIAS())
RETURN lcNodata
ENDIF

IF RECCOUNT() = 0
RETURN lcNodata
ENDIF

LOCAL lcHtml as String
#DEFINE lnFcount FCOUNT()

TEXT TO lcHtml TEXTMERGE NOSHOW
<table border="1" width="100%" cellspacing="0" cellpadding="0">

ENDTEXT


lcHtml = lcHtml + ganHear() &&表头

SCAN
lcHtml = lcHtml + ganTable() &&记录
ENDSCAN

lcHtml = lcHtml + lcEnter + '</table>'
RETURN lcHtml

*-----------------------------------------------------
* 记录生成模块
*-----------------------------------------------------
FUNCTION ganTable
LOCAL lcRecor as String
lcRecor = lcRecorBegin
FOR i = 1 TO lnFcount
lcRecor = lcRecor + lcFielBegin + ALLT(CAST(EVALUATE(fiel(i)) as char(80))) + lcFielEnd
ENDFOR
lcRecor = lcRecor + lcRecorEnd
RETURN lcRecor

*-----------------------------------------------------
* 表头生成模块
*-----------------------------------------------------
FUNCTION ganHear
LOCAL lcRecor as String
lcRecor = lcRecorBegin
FOR i = 1 TO lnFcount
lcRecor = lcRecor + [<td align="center">] + allt(fiel(i)) + lcFielEnd
ENDFOR
lcRecor = lcRecor + lcRecorEnd
RETURN lcRecor

[liangszpt]

有没有在6.0底下都可以实现的方法啊？

[pnyjq]

把这一句ALLT(CAST(EVALUATE(fiel(i)) as char(80))) 写成自定义函数，将所有类型的变量转换成字符型，应该不难．

[syntech]

其實 VFP 6.0 本來就提供一個

[syntech]

CAST(EVALUATE(fiel(i)) as char(80))
這一句是 " 把 fiel(i)的值,不論什麼資料型態, 通通轉成 最大SIZE 為 80字的字串".

所以,要針對不同的型態,以 DO CASE 的方式改寫,
就像另一篇相關討論的一樣.
http://vfp.sunyear.com.tw/viewtopic.php?t=336

[pnyjq]

有时间的话写一个allToString函数,把所有的字段都转换成char,这样就更完美了.