VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

VFP 8: 我們總是夢想的非可視方面[轉帖]
作者 Claudio Lassala
譯者 RMH
--我的用戶不能看到該材料, 但我可以, 而且我喜歡它
正如通常發生在新版本的 Visual FoxPro 上的情況一樣, 我們得到了許多新的 "非可視" 增強. 這些增強不會被我們的最終用戶注意到, 但我們真正地喜歡它們: 新的類, 命令, 函數, 和其他可以讓我們的開發者生活更輕鬆的東西, 更高的生產力, 以及可以給我們的工作帶來一系列新的主意的東西.
在本文中, 我將向你展示在 VFP 8 Beta 中的這種類型的新功能. 當然, 不可能在一篇文章中向你展示所有的內容. 因此我選擇了那些我最喜歡, 而且我認為你也喜歡的東西. 讓我們開始 (準備好了嗎?! )!
新的 CursorAdapter 類
新的 CursorAdapter 類給我們新的時機來擴展我們的資料游標, 它幫助我們處理本地的和遠端的資料, 從本地的 VFP 資料到 ODBC, ADO 和 XML.
它的使用是相當直接了當的. 注意一下下面的示例. 我們以定義一個基於 CursorAdapter 基類的新類開始:
Define CLASS CustomersData as CursorAdapter
*-- 讓我們定義 DataSourceType 為 "本地的" (VFP 數據)
DataSourceType="Native"
*-- 讓我們定義我們將創建的別名的名字.
Alias="curCustomers"
*-- 讓我們定義將產生填充游標的資料的命令.
SelectCmd = "select * from Customer"
Procedure Init
*-- 一但物件被創建, 讓我們填充游標.
this.CursorFill()
EndProc
EndDefine
CursorFill() 方法是該新的基類的 PEMs 的一部分. 每次被調用時, 它將用 SelectCmd 屬性來獲取資料並填充游標. 我們將象下面一樣來使用上面定義的類:
oCustomersData = CreateObject("CustomersData")
Browse
記住: 一但物件被創建, 將有一個 curCustomers 游標以流覽方式打開.
你還需要多一點功能? 好吧, 讓我們看看下面的例子:
Define CLASS CustomersData as CursorAdapter
*-- 現在, 我們想定義資料源的類型為 ODBC
DataSourceType="ODBC"
Alias="curCustomers"
*-- 我們可以定義一個 "Cursor Schema"
CursorSchema = ;
"customerid c(5),companyname c(30),contactname c(30),"+;
" contacttitle c(30), address c(30), city c(30), country"+;
" c(30)"
SelectCmd = ;
"select customerid, companyname, contactname, "+;
" contacttitle, address, city, country from Customers"
*-- 還記得 CursorSetProp() 函數嗎? Smile

Tables = "Customers"
KeyFieldList = "customerid"
UpdatableFieldList = "companyname"
UpdateNameList = "companyname customers.companyname"
Procedure Init

*-- 在運行時添加一個保存連接控制碼的屬性.
This.AddProperty('Connection',;
SQLSTRINGCONNECT(;
"Driver=SQL Server;Server=(local);"+;
"Description=Northwind, Int Security;"+;
"DATABASE=Northwind;uid=sa;pwd=;"))
*-- 資料源是我們的連接控制碼
This.DataSource = This.Connection
This.CursorFill()
EndProc
EndDefine
正如我在上面的代碼中的注釋中指明, 我們有一些可以轉換游標到 "可更新游標" 的屬性, 就象我們用 CursorSetProp() 函數所做的那樣.
你可以看出這一點的漂亮之處嗎? 我們只需要創建一個類, 當我們使用它時, 它將帶給我們一個填充了資料的可更新游標. 這種 "objectified" 方法來做此事的確是酷l.
VFP ads 廣告: "你能感到 XML 嗎"? 看看下面一個:
Define CLASS WishListData as CursorAdapter
*-- 設置源類型到 "XML"!
DataSourceType="XML"
Alias="curWishList"

Procedure Init
*-- 設置 SelectCmd 屬性到將返回 XML 資料的方法.
This.SelectCmd = "this.GetXml()"
*-- 填充游標.
This.CursorFill()
EndProc
Procedure GetXml
*-- 訪問 Internet 上的我們心愛的 UT 的 Web 服務
*-- 並得到一些資料, 先生!
loUniversalThread=Createobject("mssoap.soapclient30")
loUniversalThread.mssoapinit(;
" http://www.universalthread.com/WebService/VisualFoxPro.wsdl"; Wink

lcUsername='MyUser'
lcPassword='MyPassword'
loUniversalThread.Login(lcUsername,lcPassword)
lcXML=loUniversalThread.GetWishList(DATE()-20)

RETURN lcXML
EndProc
EndDefine
只需要想想: 我們告訴 CursorAdapter that 我們將處理 "XML". 我們設置 SelectCmd 屬性到一個返回 XML 串的類方法. 在此方法上, 我們就可以從我們想要的地方得到 XML, 並且 Adapter 將小心地轉換資料到一個 VFP 游標. 是不是很酷?
你還記得希望一個較好的與 ADO 的結合嗎? 好吧, 現在我們可以了. 看看這個:
Define CLASS CustomersData as xCursor
Procedure Init
*-- 我們的游標類型現在成了 "ADO"
This.DataSourceType = "ADO"
*-- 我們將添加一個屬性來保存 ADO Connection 物件.
This.AddProperty('oConn',;
NewObject("ADODB.Connection"))

*-- 添加另一個屬性來保存 ADO RecordSet 物件.
This.AddProperty('oRS',;
NewObject("ADODB.Recordset"))

*-- 我們將為 Connection 物件設置連接器,
*-- as we磖e quite used to.
This.oConn.ConnectionString = ;
"Provider=SQLOLEDB.1;"+;
"Initial Catalog=Northwind; Data Source=lassalanotebook;uid=sa;pwd=;"
*-- ...打開連接.
This.oConn.Open()
*-- 讓我們為我們的 RecordSet 物件設置剛剛創建的連接為活動的連接
This.oRS.ActiveConnection = This.oConn
*-- ...為該 Cursor Adapter 設置 RecordSet.
This.DataSource = This.oRS
*-- 這是我們獲取資料的命令.
This.SelectCmd = ;
"select customerid, companyname, contactname, "+;
"contacttitle, address, city, country from customers"
*-- 用資料填充游標, big boy!
This.CursorFill()
EndProc
EndDefine
你能看到有多容易嗎? 僅僅這樣做我們就可以得到一個從 ADO RecordSet 填充的 VFP 游標.
好了, 我想你還想要更多的功能. 因此, 讓我們繼續談下去? 我們總是夢想一個簡單的方法來綁定 ADO RecordSets 到我們的表單, 並總是保持使用 RAD 功能而不僅僅是本地的表, 而是用本地和遠端視圖.
使用 IntelliDrop (在表單設計器中的資料環境拖到表單上) 來綁定控制項到來自 RecordSets, XML, 任何 ODBC 資料源, 或類似的東西又如何? 好, 現在我們有這個能力了.
讓我們假定我有這樣一個表單, 現在上面有一個簡單的表格, 那麼我想用 ADO 訪問一些我的 SQL Server 上的資料, 並在我的 VFP 本地表格中顯示這些資料. 好, 右擊資料環境, 我們有一個新的選項, 叫做 "添加 CursorAdapter". 注意一個這個東西的屬性, 你會看到一些非常好的屬性, 如 "KeyFieldList", "UpdatableFieldList", "SendUpdates", 和諸如此類的東西.
為了更好地利用 IntelliDrop 功能, 我們必須使用的一個酷的屬性是 CursorSchema. 在該屬性上我們必須輸入游標的 "schema" (游標的結構). 定義該 schema, IntelliDrop 將象我們從一個表拖動一個欄位到表單上一樣工作.
我將給該控制項命名為 "CursorAdapterCustomers", 並設置它的 Alias 屬性為 "Customers".
最後, 將用以下代碼填充表單的 Init 方法:

*-- 讓我們指出我們的 CursorAdapter 引用.
With Thisform.DataEnvironment.CursorAdapterCustomers
*-- 下面一行的意思你已經從前面的代碼中知道了.
.DataSourceType="ADO"
.SelectCmd = ;
"select customerid, companyname, contactname, "+;
" contacttitle, address, city, country from Customers"
.AddProperty('oConn',null)
.AddProperty('oRS',null)
.oRS = CreateObject("ADODB.RecordSet")

.oConn = CreateObject("ADODB.Connection")
.oConn.Open("Driver=SQL Server;Server=lassalanotebook;"+;
"Description=Northwind, Int Security;"+;
"DATABASE=Northwind;uid=sa;pwd=;")

.oRS.ActiveConnection = .oConn

.Datasource = .oRS
.CursorFill()
Endwith
*-- 而且現在, 我們可以定義我們的游標為我們的表格的資料源.
This.grdCustomers.RecordSource = "Customers"
當我們運行表單時, 表格中顯示了我們想要的資料.
新的 AddProperty() 和 RemoveProperty() 函數
每一個使用 SCATTER NAME 命令創建物件的人總是希望有某種方法來添加屬性到該運行時創建的物件. 作為一個處理方法, 我們使用網上可以找到的 AddProp5.fll, 或者手動地創建一個基於一個 "light" 類的物件 (如 Relation 基類) 並添加屬性到基於游標的欄位上.
現在我們不必這樣做了: 我們有了一個新的叫做 AddProperty 的屬性, 我們可以用它來在運行時為 "scattered" 物件或基於新的 Empty 類添加屬性(更多的關於該類的內容參見本文後面), 因為這些物件沒有本地地 AddProperty() 方法.
注意下面的例子:
*-- 首先, 讓我們得到一些資料...
Select Company_Name, Contact_Name From (_samples+"\tastrade\data\customer") ;
into Cursor curCustomer
*-- 然後, 讓我們創建 "scattered" 物件.
Scatter name loCustomer
*-- 最後, 讓我們添加一個叫做 MyNewProp 的新屬性到物件,
*-- 並用值 "Myvalue" 初始化它.
AddProperty(loCustomer, "MyNewProp", "Myvalue")
*-- 我們可以查詢我們的新屬性的值
? loCustomer.MyNewProp
同樣, 我們現在也可以用新的 RemoveProperty 函數在運行時移去屬性, 如下所示:
RemoveProperty(loCustomer, "Contact_Name")
新的 Empty 類
直到 VFP 7, 每次我們需要一個 "羽量級的" 類 (可以快速 initiate 和 destroy 的類) 時, 我們都使用 Relation 基類; 那是一種奇怪的, 主要用於在資料環境中的兩個表間建立關係的類. 在 VFP 8 中我們有了 Empty 類.
Empty 類是一個沒有 PEMs (屬性, 事件或方法) 的, 不能在派生也不能在 PRG 或 VCX 檔中定義的類. 該類將在我們需要在運行時創建物件並添加屬性時(象 "scattered" 物件)使用, 或當我們需要在運行時保存任何 "objectified"式樣的資料排序時使用.
例如: 不幸的是, 沒有一個本地化版本的葡萄牙語 VFP. 因此, 在我們的程式中使用一個物件來保存葡萄牙語的月份和星期串是有好處的. 讓我們看看我們可以如何用 Empty 類完成該工作:
*-- 首先定義一個 "Utils" 類,
*-- 基於 "Session" 基類, 例如...
Define Class Utils As Session
*-- 現在方法將 "帶" 給我們一些用處.
Procedure BringUtils

*-- 讓我們創建我們的 "Empty" 物件.
Local loFoo
loFoo = Createobject("Empty")
*-- 使用新的 AddProperty() 函數.
*-- 首先為需要保存的月添加屬性...
AddProperty(loFoo, "Months(12)")
*-- 而且第二個屬性保存星期.
AddProperty(loFoo, "DaysOfWeek(7)")
*-- 讓我們保存資料.
With loFoo
*-- 葡萄牙語的月(被我改為中文了)
.Months(1) = "一月"
.Months(2) = "二月"
.Months(3) = "三月"
.Months(4) = "四月"
.Months(5) = "五月"
.Months(6) = "六月"
.Months(7) = "七月"
.Months( Cool

= "八月"
.Months(9) = "九月"
.Months(10) = "十月"
.Months(11) = "十一月"
.Months(12) = "十二月"
*-- 葡萄牙語的星期
.DaysOfWeek(1) = "星期一"
.DaysOfWeek(2) = "星期二"
.DaysOfWeek(3) = "星期三"
.DaysOfWeek(4) = "星期四"
.DaysOfWeek(5) = "星期五"
.DaysOfWeek(6) = "星期六"
.DaysOfWeek(7) = "星期日"
Endwith
*-- 最後, 返回我們的有用的物件.
Return loFoo
EndProc
EndDefine
好了. 現在, 我們可以象下面一樣使用我們的 Utils 類:
*-- 初始化我們的 "Utils" 類.
oUtils = Createobject("Utils")
*-- 調用 BringUtils() 方法.
*-- 記住它將返回一個基於 "Empty" 類的物件.
oUtils = oUtils.BringUtils()
*-- 現在我們可以用中文顯示月名...
? oUtils.Months(Month(Date()))
*-- ...或者星期幾.
? oUtils.DaysOfWeek(Dow(Date()))
增強的 Scatter 命令
現在我們可以用 Scatter 命令的 Additive 關鍵字來更新一個已存在的物件, 看看它是多麼有用:
*-- 讓我們為 "Customer" 創建一個簡單的商業物件
Define Class Customer As Session
*-- 一些屬性...
Company_Name = ""
Contact_Name = ""
*-- 一個簡單的加工資料的方法.
Procedure GiveMeInfo
Return Alltrim(This.Company_Name) + " - " + This.Contact_Name
Endproc
Enddefine
現在, 看看下面:
*-- 實例化我們的 Customer 物件.
oCustomer = CreateObject("Customer")
*-- 我們得到了一些資料... 只是為了測試...
Select Company_Name, Contact_Name From (_samples+"\tastrade\data\customer") into cursor curCustomer
*-- 現在我們可以 "scatter" 資料到已經創建的 BizObject 物件.
Scatter Name oCustomer additive
*-- 調用我們的 GiveMeInfo() 方法.
MessageBox(oCustomer.GiveMeInfo())
我認為這非常有用, 不是嗎?
另一個非常好的與 "scattered" 物件相關的東西是 INSERT-SQL 語句現在可以從一個物件接受資料. 因此我們可以象下面一樣做一些事情:
*-- 讓我們創建一個簡單的測試游標.
Create Cursor Foo (Company_Name C(30), Contact_Name C(30))
*-- 現在, 假定我們有一個前面創建的物件:
Insert into Foo from name oCustomer
該新的酷功能配合使用我們熟悉的 VFP 游標和商業物件, 讓 VFP 更有力地處理資料.
為本地 VFP 物件的事件綁定
在 VFP 7 中, 我們有了 EventHandler() 函數, 可用來綁定 COM 物件事件到一個 VFP 物件. 現在我們可以使用一個新的叫做 BindEvent() 的函數做相同的, 但綁定 VFP 物件事件的事.
讓我們考慮一下...: 我們有一個包含一個資料物件的商業物件, 而且我們想用另一個物件監視該物件中的資料修改. 在此特定情節下, 讓我們首先創建商業類:
*-- 我們的 BizObj.
Define Class Customer As Session
*-- 一個屬性物件屬性.
oData = Null
Procedure Init
*-- 從一個表中綁定資料.
Select * From (_samples+"\tastrade\data\customer") into Cursor curCustomer
*-- 創建資料物件.
Scatter Name This.oData Memo
EndProc
EndDefine
現在我們將創建我們的 "事件處理器" 類.
*-- 定義一個類.
Define Class FooHandler As Session
*-- 我們定義一個處理 "Company_Name" 欄位變化事件的方法.
*-- ...當然, 在一個真實的情況下我們還有許多更感興趣的東西在此處...
Procedure CompanyNameHandling
Messagebox("你已經修改了公司的名字")
EndProc
EndDefine
最後, 讓我們使用這些類:
*-- 首先創建我們的 BizObj.
oCustomer = CreateObject("Customer")
*-- 現在是我們的事件處理物件
oFooHandler = CreateObject("FooHandler")
*-- 最後, 讓我們使用函數 Bindevent, 來實際綁定東西...
Bindevent(oCustomer.oData, "Company_Name", oFooHandler, "CompanyNameHandling")
*-- ...試試修改 "Company_name" 的值...
oCustomer.oData.Company_Name = "任何東西..."
正如你所見到, BindEvent() 函數接收的物件參數將激發事件 (在此場合是 oCustomer.oData 物件), 屬性將激發事件 (在此場合是 Company_Name 屬性), 物件將處理事件 (也就是我們的 oFooHandler 物件), 最後, 方法將處理事件 (也就是 CompanyNameHandling() 方法). 任何時候 Company_Name 被改變, 將顯示一個資訊 (這是我們在類中定義的).
你是否想看看更 "可視" 的例子? 如果是, 好吧: 讓我們說你有一個表單而且你總是希望它在螢幕大小發生變化時發生相應的變化. 我們可以象下面一樣來做此事:
*-- 讓我們創建一個簡單的表單.
Public oFooForm
oFooForm = Createobject("FooForm")
oFooForm.Visible = .T.
*-- 讓我們綁定東西...
Bindevent(_Screen, "Resize", oFooForm, "Resize")
*-- 看看我們的示例表單.
Define Class FooForm As Form
Procedure Resize
This.Top = _Screen.Top + 5
This.Left = _Screen.Left + 5
This.Width = _Screen.Width - 100
This.Height = _Screen.Height - 100
Endproc
Enddefine
在以上代碼中, 我們定義了當 _Screen 物件的 Resize 事件激發時, 我們希望 oFooForm 物件的 Resize 方法也激發. 你可能已經注意到了, _Screen 物件在此處是被動的, 因為它絕不知道有一些東西會 "跟隨它的動作".
我知道你喜歡大量的示例, 因此這裏是另外一個, 我將讓你更好地理解 BindEvent() 函數.
你還記得每次當表格中無論哪一列中的文本框被單擊時你需要運行一些代碼嗎? 到目前為止, 你只有在每一列的文本框的 Click() 中輸入代碼, 或者定義一個包含了想要運行的代碼的 textbox 類並將該類添加到表格中 (而且你更加不喜歡這種方法, 因為除在此處外你絕不會在其他地方使用該類...).好了, 使用 BindEvent() 函數, 你可以這樣做:
讓我解釋一下: 在表單的 Init() 方法中我進行了事件綁定. 它只是遍曆表格的所有的列, 並綁定各 textbox (表格中的 Control(2)) 的 RightClick() 事件到表單的 BringSomeInfo() 方法. 是不是相當酷? 跟著我: VFP Rocks!
新的 Collection 類
你再也不需要創建你自己的 Collection 類: 現在我們有一個本地的 Collection 類了! 你想實踐一下它嗎? 好嗎: 讓我們假定我的應用程式需要層迭排放所有已打開的視窗. 看看用 Collection 灰來實現它是多麼的簡單:
*-- 定義一個簡單的 "FormsManager" 類.
Define Class FormsManager As Session
*-- 定義一個保存 Collection 的屬性.
oFormsCollection = Null
Procedure Init
*-- 實例 Collection 類.
This.oFormsCollection = Createobject("Collection")
Endproc
*-- 定義一個添加視窗引用到 Collection 的方法.
Procedure AddForm(loForm)
*-- 為了添加項到 collection,我們可以使用 Collection 物件的 Add() 方法.
*-- 在該示例中, 我們檢測視窗的 Caption
*-- 作為 Collection 中的項的鍵.
This.oFormsCollection.Add(loForm, loForm.Caption)
*-- 綁定事件到窗口的 QueryUnload,
*-- 該方法引用到已被該類的 ReleaseForm 方法清除了的[視窗.
Bindevent(loForm, "QueryUnload", This, "ReleaseForm", 2)
Endproc
*-- 釋放視窗引用的方法.
Procedure ReleaseForm
This.oFormsCollection.Remove(_Screen.ActiveForm.Caption)
EndProc
*-- 一個簡單的 "cascade" 視窗的方法.
Procedure CascadeForms
Local lnTop, lnLeft
lnTop = 5
lnLeft = 5
*-- 我們可以用一個 ForEach 結構來遍曆 collection 中的所有項.
For Each loForm In This.oFormsCollection
loForm.Top = lnTop
loForm.Left = lnLeft
loForm.Visible = .T.
lnTop = lnTop + 20
lnLeft = lnLeft + 20
Next
Endproc
Enddefine
你要注意到的部分是:
我們用 Collection 類的 Add() 方法添加項到集合, 並用 Remove() 方法來移去項.
Add() 方法的第二個參數是訪問項的 "鍵".
我們可以用 For Each 結構來遍曆集合中的項.
現在,我們可以這樣使用我們的 "Form Manager" :
*-- 定義一些變數...
Public oForm1, oForm2, oForm3, oFM
*-- 實例化一些視窗, 並給它們指定 captions...
oForm1 = Createobject("Form")
oForm1.Caption = "Customers"
oForm2 = Createobject("Form")
oForm2.Caption = "Orders"
oForm3 = Createobject("Form")
oForm3.Caption = "Products"
*-- 實例化我們的 "Forms Manager"
oFM = Createobject("FormsManager")
*-- 添加視窗到我們的 "Form Manager"
oFM.AddForm(oForm1)
oFM.AddForm(oForm2)
oFM.AddForm(oForm3)
*-- 請求 "Form Manager" 來 "Cascade" 窗口.
oFM.CascadeForms()
上述代碼運行後產生的結果:
想想: 象這樣做,你有許多控制項在你的表單上, 而且有一種簡單的方法來獲得它們的引用. 而且 Collection 類為我們提供了一些其他的酷的功能, 象下面一樣:
*-- 我們可以查詢 Collection 物件的 Count 屬性,
*-- 並發現它包含了多少項.
? oFM.oFormsCollection.Count
*-- 我們可以用集合的 Index 來訪問集合中的單個的項...
*-- ...例如, 讓我信看看作為集合中的第二個項的表單引用的 Top 屬性值.
? oFM.oFormsCollection.Item(2).Top
*-- ...或按它的 "鍵"
? oFM.oFormsCollection.Item("Orders").Top
另一個酷的 Insert-SQL 增強
除前面提到的新從一個物件插入新記錄的新功能外, 現在我們可以從一個 Select-SQL 結果進行插入. 看:
*-- 讓我們創建一個簡單的游標...
Create Cursor MyCustomers (cName C(30))
*-- ...並插入從一個 Select-SQL 語句返回的行.
Insert into MyCustomers ;
Select Company_Name ;
from (_Samples+"\Tastrade\Data\Customer") ;
where country = "Brazil"
　
Textmerge 增強
我是一個總是喜歡使用 Textmerge (文本合併) 的人 . 並且我將告訴你我所喜歡這個新的增強. 回到 UTMag/RapoZine 的第六期, 在 Shortcuts column 中, 我告訴了你關於如何使用 Textemerge 來以一種清晰的方式創建 SQL 語句, 代替那些可怕的串連接. 你可以象這樣:
Local lcSQL
Text to lcSQL TextMerge NoShow
Select Field1, Field2, Field3, Field4
From Table
Inner Join AnotherTable
On Table.SomeField = AnotherTable.SomeField
Inner Join FooTable
On Table.Somefield = FooTable.SomeField
Where Field1 = << lcSomeVar >>
And Field2 = << lcAnotherVar >>
Group by Field3, Field2
Order by Field1
EndText
我們還有一小點缺點: 我們需要象下面一樣移去無內容的空格:
StrTran(lcSQL, Chr(13)+Chr(10), " ")
好了, 我們不再需要那個了. 我們可以象下面一樣修改 Text 命令:
Text to lcSQL TEXTMERGE NOSHOW PRETEXT 1+2
使用新的 PRETEXT 關鍵字我們可以移去各行尾部的空格和 tabs (flags 1+2). 這不僅僅對 SQL 語句有用, 對於 XML 文檔也是如此.
結論
好了, 就這些! 正好我在文章開始處告訴你, VFP 8 給我們帶來了許多酷的新功能, 並且在本文中我僅向你展示了一些酷的新的 "非可視" 功能. 我希望你喜歡它. 看看本期中的其他激動人心的 VFP 8 Beta 相關文章!