 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 1 樓
|
 發表於: 星期日 四月 13, 2003 3:16 pm 文章主題: 阿拉伯數字轉成中文大寫金額 |
 |
|
********************************************
FUNC Num2Chinese &&數字轉換成'大寫'
&& num的整數部分最多有16位,小數部分5位
para num &&I.g.: 234,124.33 貳拾 萬肆仟壹佰貳拾肆點
LOCAL i,tmp,tmpchr,never_met0,lcTmp,lnPos
tmp=''
never_met0=.t.
num=allt(padc(num,22))
if len(num)>16
=MessageBox('調用numToChinese時出錯, 參數長過16位')
return ''
endif
int_len=iif(at('.',num)=0,len(num),at('.',num)-1) &&整數部分長度
for i=1 to len(num)
tmpchr=substr(num,i,1)
do case
case i>int_len+1 &&小數部分
tmp=tmp+ gcU2Ch(tmpchr)
case tmpchr='.' &&小數點
tmp=tmp+'點'
case tmpchr='0' && 遇到零
do case
case int_len=1 &&只有個位數
tmp=gcU2Ch(tmpchr)
case i=int_len and int_len#1 &&多位數的個位, 不要
otherwise &&多位數
do case
case never_met0 &&未遇到過'0',保留一個
never_met0=.f.
if gcPos2Chinese(int_len-i+1)$'億萬'
tmp=tmp+gcPos2Chinese(int_len-i+1)
never_met0=.f.
else
tmp=tmp+gcU2Ch(tmpchr)
endif
case gcPos2Chinese(int_len-i+1)$'億萬'
&& 但若它的TITLE是'萬'或'億,'萬'或'億'留下
tmp=tmp+gcPos2Chinese(int_len-i+1)
never_met0=.t.
endcase
endcase
case i=int_len &&遇到個位數
tmp=tmp+gcU2Ch(tmpchr)
otherwise &&整數部分
never_met0=.t.
tmp=tmp+gcU2Ch(tmpchr)+gcPos2Chinese(int_len-i+1)
endcase
endfor
&&&!!!萬和億的前面有'零',去掉!
lnPos=at('萬',Tmp)
IF lnPos>0 and subst(Tmp,lnPos-2,2)='零'
Tmp=Subst(Tmp,1,lnPos-4+1)+Subst(Tmp,lnPos)
ENDIF
lnPos=at('億',Tmp)
IF lnPos>0 and subst(Tmp,lnPos-2,2)='零'
Tmp=Subst(Tmp,1,lnPos-4+1)+Subst(Tmp,lnPos)
ENDIF
return tmp |
|
| 回頂端 |
|
 |
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 2 樓
|
| 發表於: 星期三 二月 11, 2004 5:17 pm 文章主題: |
|
|
YSC5096寫了更簡潔的函數,我把他轉貼過來.
來源:紅狐論壇 YSC5096
http://fox.hanyu.com.tw/View.aspx?fbId=1&Id=11198
| 代碼: | * 為求排版美?#91;，空白為全形，若要測試，請轉為半形後再測試
FUNCTION F_StrConv
* -------------------------------------------------------------------------- *
* 變數名稱 型態 說明
* -------------------------------------------------------------------------- *
* Input : L_ncNumber N or C 1.代表「阿拉伯數字型式」的金額。
* 2.小數位數只處理到第二位，負號會被忽略不處理。
* 3.若為 C 型態：接受
* 9999999999999999999.99 或
* 9,999,999,999,999,999,999.99 格式
* Output: Lo_cNumber C 代表「口語金額敘述型式」的字串金額
* -------------------------------------------------------------------------- *
* 說明: 將「阿拉伯數字型式」金額轉換成「口語金額敘述型式」字串金額
* -------------------------------------------------------------------------- *
* 範例: 10205104.32 --> 壹仟零貳拾萬伍仟壹佰零肆元參角貳分整
* ? F_StrConv(10205104.32)
* ? F_StrConv("10205104.32")
* ? F_StrConv("10,205,104.32")
* -------------------------------------------------------------------------- *
LPARAMETERS L_ncNumber
LOCAL W1_cNumber,W1_cStr1,W1_cStr2,W1_cStr3
LOCAL W1_nSUB_A,W1_n1Num,W1_cTranStr
IF TYPE("L_ncNumber") = "C"
L_ncNumber = VAL(CHRTRAN(L_ncNumber,",",""))
ENDIF
W1_cNumber = LTRIM(TRANSFORM(ABS(L_ncNumber),"9999999999999999999.99"))
STORE "零壹貳參肆伍陸柒捌玖" TO W1_cStr1
STORE "分角 元拾佰仟萬拾佰仟億拾佰仟兆拾佰仟" TO W1_cStr2
STORE " 元 萬 億 兆 " TO W1_cStr3
STORE SPACE(0) TO Lo_cNumber
FOR W1_nSUB_A = LEN(W1_cNumber) TO 1 STEP -1
W1_n1Num = VAL(SUBSTR(W1_cNumber,W1_nSUB_A,1)) && 要處理的位數之值
W1_cTranStr = IIF(W1_n1Num=0,W1_cStr3,W1_cStr2) && 要換算的對應單位字串
Lo_cNumber = SUBSTR(W1_cStr1,W1_n1Num*2+1,2) + ; && 例：4 --> 肆
ALLTRIM(SUBSTR(W1_cTranStr,(LEN(W1_cNumber)-W1_nSUB_A+1)*2-1,2)) + ;
Lo_cNumber
ENDFOR
Lo_cNumber = Lo_cNumber + "整"
DO WHILE !EMPTY(AT("零零",Lo_cNumber))
Lo_cNumber = STRTRAN(Lo_cNumber,"零零","零")
ENDDO
Lo_cNumber = STRTRAN(Lo_cNumber,"零萬","萬")
Lo_cNumber = STRTRAN(Lo_cNumber,"零億","億")
Lo_cNumber = STRTRAN(Lo_cNumber,"零兆","兆")
Lo_cNumber = STRTRAN(Lo_cNumber,"零元","元")
Lo_cNumber = STRTRAN(Lo_cNumber,"元零","元")
Lo_cNumber = STRTRAN(Lo_cNumber,"零整","整")
RETURN Lo_cNumber |
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!
學會VFP使用者社區的搜尋,Code才會更有趣~
############################# |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 3 樓
|
| 發表於: 星期三 二月 11, 2004 10:14 pm 文章主題: |
|
|
TO Ruey:
你少貼了下面一段話
| 引言回覆: |
[整理]將「阿拉伯數字型式」金額轉換成「口語金額敘述型式」字串金額
* 這是 cchvfp 提供的「人事系統程式碼免費公開」中的某一自訂函數，
* 我覺得它還蠻實用，就把它提出來分享。
* 不過我有稍微更動過內容，原始的程式碼比較簡潔，我只是為了加說明而更動一些。 |
我只是將它整理出來並加入說明而已
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 4 樓
|
| 發表於: 星期三 二月 11, 2004 10:42 pm 文章主題: |
|
|
多謝指正
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!
學會VFP使用者社區的搜尋,Code才會更有趣~
############################# |
|
| 回頂端 |
|
|
jasonyummy
註冊時間: 2004-05-06
文章: 15
第 5 樓
|
| 發表於: 星期五 六月 04, 2004 10:26 am 文章主題: |
|
|
我是新手，在這裡獲取很多很多，所以每有新意時就很想貼出，但是怕多此一舉而礙到你們的眼睛，所以就.........
這個比較簡單，所以就獻醜了
| 代碼: |
**********************************************
�{式碼：
parameter xnTc_V
lcChar_M="0零1壹2貳3參4肆5伍6陸7柒8捌9玖"
lcTc_V=strtran(transform(xnTc_V,"9兆9仟9佰9拾9億9仟9佰9拾9萬9仟9佰9拾9元.9角9分"),".","") &&轉成文字型態
lcRet_T=''
for lnI=1 to lenc(lcTc_V) step 2
lcChar_N=substrc(lcTc_V,lnI,2) &&取碼
if inlist(left(lcChar_N,1),"1","2","3","4","5","6","7","8","9","0") &&取阿拉伯數字
lcChar_B= substr(lcChar_M,at(left(lcChar_N,1),lcChar_M)+1,2) &&轉換阿拉伯數字成為中文大寫數字
lcRet_T= lcRet_T+lcChar_B+right(lcChar_N,2)
endif
endfor
lcRet_T=alltrim(lcRet_T)+"整"
lcRet_T=strtran(lcRet_T,"零拾","零")
lcRet_T=strtran(lcRet_T,"零佰","零")
lcRet_T=strtran(lcRet_T,"零仟","零")
lcRet_T=strtran(lcRet_T,"零角","零")
lcRet_T=strtran(lcRet_T,"零分","零")
lcRet_T=strtran(lcRet_T,"零零","零")
lcRet_T=strtran(lcRet_T,"零零","零")
lcRet_T= STRTRAN(lcRet_T,"零萬","萬")
lcRet_T= STRTRAN(lcRet_T,"零億","億")
lcRet_T= STRTRAN(lcRet_T,"零兆","兆")
lcRet_T= STRTRAN(lcRet_T,"零元","元")
lcRet_T= STRTRAN(lcRet_T,"零整","整")
return(lcRet_T)
********************************************** |
為了美觀, 我有加入大寫空白, 要用的話請自行刪除
我取 Ruey 所發表的 YSC5096 文章片段, 做成我所喜歡的格式
希望此舉沒有觸犯何事, 或另人不悅的事
若有的話, 此刪除此篇, 謝謝版主 |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
