文件出處: http://www.myf1.net/bbs/dispbbs.asp?boardID=1&ID=212957
“網路螞蟻”的核心技術就是“中斷點續傳”，“多線程”在 vfp 中實現起
來比較麻煩(本人還沒來得及深入研究)，暫不討論。再加之“網路螞蟻”是一
個優秀的免費軟體，我可不想真的用 vfp 寫一個“網路大象”與之較量，只是
想把實現方法介紹給大家，僅此而已。好了，言歸正傳吧 ......
首先要說的就是撥號連接。這可謂是老生常談了，撥號的方法很多，通過
測試我認爲下面兩個值得一用：
① rasapi32.dll 的 rasdial 函數
如果你需要指定電話號碼、用戶名及用戶口令進行特定撥號的話就需要使用
此函數，這多用於對內部伺服器撥號。函數原型如下：
declare integer rasdial in rasapi32.dll ;
string lprasdialextensions,; && 在win9x下無用 null
string lpszphonebook,; && 電話簿 在win9x下無用 null
string @lprasdialparams,; && 撥號參數指標
integer dwnotifiertype,; && 消息通知方式 0
integer lpvnotifier,; && 消息處理事件 0
integer @lphrasconn && 返回成功連接的連接控制碼 調用
前需先置null
調用方法：
m.lprasdialparams = ;
dectoascii(1052,4)+; && dwsize dectoascii(1052,4) 表示將1052轉換成低位元在前，高位在後的4個ascii字元
replicate(chr(0),256+1)+; && entryname(256) - 撥號連接名字或置爲空
stuffc(replicate(chr(0),128+1),1,len(m.phonenumber),m.phonenumber)+; && phonenumber(128) 電話號碼
replicate(chr(0),128+1)+; && callbacknumber (128) 回叫號碼，置空
stuffc(replicate(chr(0),256+1),1,len(m.username),m.username)+; && username(256) 用戶名
stuffc(replicate(chr(0),256+1),1,len(m.password),m.password)+; && password(256) 口令
replicate(chr(0),15+1+3) && domain (15) 功能變數名稱(自建伺服器用)
m.lphrasconn = 0 && 遠端存取連接控制碼，初值爲0
rasdial(null,null,@m.lprasdialparams,0,0,@m.lphrasconn)
值得一提的是“撥號連接名字”，要麽準確設置，要麽爲空。有趣的的是
如果“撥號連接名字”設置爲空時，撥通後在任務欄中不會顯示連接圖示(我
只測試了xp，其他系統是否如此不得而知)。
② wininet.dll 的 internetdial 函數
如果你對撥號沒有特殊指定的話，建議使用此函數撥號。函數原型如下：
declare integer internetdial in wininet.dll;
integer hwndparent,; && 父窗口(表單)控制碼或爲空
string lpszconnectoid,; && 所使用的撥號連接名字(可以爲空)
integer dwflags,; && 連接標誌
integer @lpdwconnection,; && 成功連接後的連接號(斷開連接時需要此號)
integer dwreserved && 系統保留，必須爲零
*-- dwflags - 可取如下各值
#define internet_autodial_force_online 0x0001 && 手動撥號,不在線時提示斷開
#define internet_autodial_force_unattended 0x0002 && 自動撥號
#define internet_dial_unattended 0x8000 && 自動撥號
#define internet_dial_force_prompt 0x2000 && 手動撥號
#define internet_dial_show_offline 0x4000 && 手動撥號(將“取消”按鈕替換爲“脫機工作”按鈕)
調用方法：
m.lpdwconnection = 0
internetdial(0,null,internet_autodial_force_online,@m.lpdwconnection,0)
還有一個問題就是如何斷開當前撥號連接。如果當前撥號連接是你的程式
建立的，斷開比較容易，因爲你知道連接控制碼。若運行你的程式前撥號連接
已經接通，要斷開該怎麽辦呢？其實也很簡單，用下面的方法可以斷開所有的
撥號連接，無論其是以何方式及由誰創建的！
首先，你要取得所有活動的 ras 連接，這要用 rasapi32.dll 的 rasenumconnections 函數
declare integer rasenumconnections in rasapi32.dll ;
string @ lprasconn,; && 緩衝區指標。它是一個 rasconn 結構的陣列
integer @ lpcb,; && 緩衝區大小
integer @ lpcconnections && 實際連接數
調用方法：
m.lprasconn = ;
chr(0x9c)+chr(0x01)+chr(0)+chr(0)+; && dwsize - rasconn 結構長度: 412位元組
space(4)+; && hrasconn - ras 連接控制碼
space(256+1)+; && szentryname
space(16+1)+; && szdevicetype
space(128+1+1) && szdevicename
m.lpcb = 256 * 412 && 假設有256個活動的 ras 連接。其實不會有這麽多，只是爲了保險。
m.lprasconn = replicate(m.lprasconn,256) && 分配記憶體
m.lpcconnections = 0 && 初始化連接總數
rasenumconnections(@m.lprasconn,@m.lpcb,@m.lpcconnections)
然後根據變數 m.lpcconnections (實際連接數) 值判斷是否有已連通的撥號
連接，確定後用 rasapi32.dll 的 rashangup 函數來斷開指定的撥號連接。
例如，第一個連接的控制碼爲 substr(m.lprasconn,5,4)，第二個爲substr(m.lprasconn,412+5,4)...等等，你必須將其轉換爲十進位數字(轉換方法請看
示例)後賦變數 m.hrasconn 。
declare integer rashangup in rasapi32.dll ;
integer hrasconn && 要終止的 ras 連接控制碼
*-- 象下面這樣斷開指定的連接(通常是第一個連接)
rashangup(m.hrasconn)
好了，有關撥號連接的問題已經解決了。下面該切入正題啦 - 如何實現中斷
點續傳！這部分有些難理解，但實現起來也很容易....
首先，你要和 internet 建立連接，這要用到 wininet.dll 的兩個函數 internetopen 和 internetconnect。如果要自動處理“脫機工作”狀態，還
需要用到 internetsetoption 函數。
① wininet.dll 的 internetopen 函數
該函數是取得與 internet 的會話控制碼。函數原型如下：
declare integer internetopen in wininet.dll;
string lpszagent,; && 描述
integer dwaccesstype,; && 訪問類型
string lpszproxyname,; && 代理伺服器名字
string lpszproxybypass,; && 主機名或 ip 位址
integer dwflags && 標誌字
其中 lpszagent 可以爲任意字串，甚至是null。dwaccesstype=0 表示從
註冊表取得訪問類型
調用方法：
m.hinternet = internetopen("下載測試",0,null,0,0)
得到 internet 會話控制碼後就可以連接到 internet 伺服器了。下面只討論
如何連接到 http，因爲它最常用。
② wininet.dll 的 internetconnect 函數
取得 http 的連接控制碼要用到 internetconnect 函數，原型如下：
declare integer internetconnect in wininet.dll;
integer hinternet,; && internet 會話控制碼
string lpszservername,; && 伺服器名如 www.microsoft.com (或伺服器ip如:181.231.127.233)
integer nserverport,; && 伺服器埠 0-使用 dwservice 指定的伺服器埠
string lpszusername,; && 用戶名
string lpszpassword,; && 口令
integer dwservice,; && 伺服器類型 1-ftp 伺服器 2-gopher 伺服器 3-http 伺服器
integer dwflags,; && 特殊標誌
integer dwcontext
調用方法：
m.hconnect = internetconnect(m.hinternet,' www.microsoft.com',0,null,null,3,0,0)
③ wininet.dll 的 internetsetoption 函數
如果系統正處於“脫機工作”狀態，則文件下載將會失敗。要切換到聯機工作模式就要用到 internetsetoption 函數。
declare integer internetsetoption in wininet.dll;
integer hinternet,; && internet 會話控制碼 可設置爲零，表示“全局 internet 連接”
integer dwoption,; && 設置類型 50 - 設置連機狀態
string lpbuffer,; && 需設置選項
integer dwbufferlength && lpbuffer 長度
調用方法：
m.lpbuffer = chr(1)+chr(0)+chr(0)+chr(0)+; && dwconnectedstate 0x01 - 聯機；0x10 - 脫機
replicate(chr(0),4) && dwflags 0x00 - 聯機；0x01 - 脫機
internetsetoption(0,50,m.lpbuffer,len(m.lpbuffer))
至此，我們已經連接到了 http 伺服器，接下來是判斷此伺服器是否支援“中斷點續傳”。要完成此操作需要用到三個函數：httpopenrequest、httpsendrequest 和 httpqueryinfo。
① 先用 httpopenrequest 函數獲取向 http 伺服器發送請求的控制碼，該函數原型如下：
declare integer httpopenrequest in wininet.dll;
integer hconnect,; && http 連接控制碼
string lpszverb,; && http 協定命令 若爲空則函數默認爲"get - 表示下載文件"
string lpszobjectname,; && 遠端檔案名 如:“\dir\xxx.zip”
string lpszversion,; && http 協定版本，若爲空則函數默認爲http/1.0
string lpszreferer,; && 爲 url 指定文檔地址
string lpszaccepttypes,; && 文件的打開類型
integer dwflags,; && 標誌
integer dwcontext
調用方法：
m.hrequest = httpopenrequest(m.hconnect,"get","\dir\xxx.zip","http/1.1",null,null,0x4000000,0)
② 有了向 http 伺服器發送請求的控制碼就可以發送具體請求了。假設我們上次文件已經下載了33位元組，現在我們請求伺服器從第34個位元組開始給發送，這要用 httpsendrequest 函數來實現。
declare integer httpsendrequest in wininet.dll;
integer hrequest,; && http 下載請求控制碼
string lpszheaders,; && 附加請求頭(可爲空) 從第10位元組開始下載 range:bytes=10-
integer dwheaderslength,; && 附加請求頭長度
integer lpoptional,; && 附加資料緩衝區，可爲空
integer dwoptionallength && 附加資料緩衝區長度
調用方法：
m.lpszheaders = 'range:bytes=34-' && 請求伺服器從文件的第34位元組開始發送資料
httpsendrequest(m.hrequest,m.lpszheaders,len(m.lpszheaders),0,0)
③ 接下來從 http 伺服器讀取資訊以判斷是否接受我們的請求 - “中斷點續傳”
declare integer httpqueryinfo in wininet.dll;
integer hrequest,; && http 下載請求控制碼
integer dwinfolevel,; && 讀取標誌
string @ lpvbuffer,; && 資料傳遞緩衝區
integer @ dwbufferlength,; && 緩衝區長度
integer @ lpdwindex && 返回的參數個數 ?(這個參數我還沒搞明白~-~)
調用方法：
m.bufquery = space(32)
m.dwlengthbufquery = len(m.bufquery)
m.lpdwindex = 0
httpqueryinfo(m.hrequest,http_query_status_code,@m.bufquery,@m.dwlengthbufquery,@m.lpdwindex)
如果 substr(m.bufquery,1,m.dwlengthbufquery) 的內容是 '206'，值得慶倖，支援“中斷點續傳”，接下來你可以直接調用 internetreadfile 函數從伺服器上讀取資料了！資料回傳成功後用 writefile 函數將其寫入本地文件就行啦(^_^)。
下載過程應該啓動一個“線程”來進行，這樣可以隨時中斷下載。若用迴圈控制或是申請一次下載整個文件那我們就無法對下載實施控制了，可在vfp中啓動一個“線程”又比較麻煩，因此偷懶的辦法是將此工作交給時間控制項完成，但效果不太好(將就點吧)。
在時間控制項的 timer 事件中可以放入類似下面的代碼:
this.enabled = .f. && 禁止本身，等待本事件代碼執行完畢
if 用戶請求中斷下載 .or. 已下載完
釋放控制碼 m.hrequest、m.hconnect、m.hinternet
關閉本地文件
return
endif
*-- 假定每次下載 1kb
m.dwfilesize = 1024
*-- 分配緩衝區
m.buffer = space(m.dwfilesize)
m.dwbytesread = 0
*-- 將文件讀入緩衝區
internetreadfile(m.hrequest,@m.buffer,m.dwfilesize,@m.dwbytesread)
寫入本地文件
累計已下載長度
this.enabled = .t. && 啟動本身，允許再次執行
若伺服器不支援“中斷點續傳”，那你只有將以前下載的不完整文件清空後從頭再來啦(~_~)。
另外，你還可以通過設置不同的 dwinfolevel 值來獲得其他伺服器資訊。可取值如下：
http_query_status_code 19 && 狀態代碼
http_query_status_text 20 && 狀態文本
http_query_content_type 1 && 類型
http_query_content_length 5 && 內容長度
http_query_content_range 53 && 範圍
http_query_date 9 && 日期
http_query_last_modified 11 && 最後修訂
http_query_version 18 && 協定
http_query_raw_headers 21 && 獲取 http 資訊 - 分隔符號爲 0
http_query_raw_headers_crlf 22 && 獲取 http 資訊 - 分隔符號爲“回車換行符”
http_query_server 37 && 伺服器
http_query_rest_method 45 && http協定命令
http_query_etag 54 && etag
注意：設置不同的 dwinfolevel 值一定要將字串 m.bufquery 設的足夠大。一般 m.bufquery = space(2*1024)就差不多了。
還有一點需要說明，如果伺服器不支援“中斷點續傳”，需要重新向伺服器提出請求必須先釋放前面的 http 請求控制碼，然後重新用 httpopenrequest 獲取 http 請求控制碼，然後用 httpsendrequest 發送新的操作請求，就像下面這樣：
internetclosehandle(m.hrequest)
m.hrequest = "get","\dir\xxx.zip","http/1.1",null,null,0x4000000,0)
httpsendrequest(m.hrequest,m.lpszheaders,len(m.lpszheaders),0,0)
下載完成後別忘了用 internetclosehandle 釋放前面所有的 internet 控制碼。好了，先到這裏吧，實在是懶得寫東西。我會儘快將示例整理出來，望斑竹先將此貼“固頂”幾天以便上傳示例。
下面是其他相關的 函數原型。
*-- 外部函數 - 釋放 internet 控制碼 返回值 1-成功，0-失敗，具體出錯原因可通過調用 getlasterror 得到。
declare integer internetclosehandle in wininet.dll ;
integer hinternet && 需釋放的控制碼
*-- 外部函數 - 從遠端文件中讀取資料 返回值 成功，返回1。失敗，返回 0，可調用 internetgetlastresponseinfo 獲得詳細內容
declare integer internetreadfile in wininet.dll ;
integer hfile,; && 遠端文件控制碼
string @lpbuffer,; && 接收緩衝區地址
integer dwnumberofbytestoread,; && 讀取位元組數
integer @lpdwnumberofbytesread && 實際讀取位元組數
*-- 外部函數 - 將資料寫入一個文件 返回值 非零表示成功，否則返回零
declare integer writefile in kernel32.dll ;
integer hfile,; && 文件控制碼
string @lpbuffer,; && 資料緩衝區位址
integer nnumberofbytestowrite,; && 寫入位元組數
integer @lpnumberofbyteswritten,; && 實際寫入位元組數
integer lpoverlapped && 該參數應置爲零
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
