VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

譯文作者計飛星 /梅子網站

關於VFP資料加密的譯文

由於本人E文水平馬馬虎虎，花了一個中午時間，但也不知道大家看得順不順，將就點吧，不過此程式在vfp8下運行出錯，提示“找不到PARAMETER語句”，還請哪位大俠出手解決一下！
-------------------------------------------------------------------------------------------------------------------
VisualFoxPro的安全: 密碼使用法
作者：Daryl Moore
出處：MICROSOFT VISUAL FOXPRO ADVISOR ZONE
日期：2003年6月16日
翻譯：計星飛
VFP的安全主要關鍵在於保護資料，下面這些技術將對加密你的FoxPro資料有幫助。

在大多數的情形下，你不必擔心你編寫的程式有被破解的煩惱。如果你正在使用Visual FoxPro，那很有可能你的程式會包括運算元據，這正是你所需要保護的。

對於VisualFoxPro開發者不幸的是，微軟從未感覺到要在FoxPro中提供內建的密碼技術或安全表的迫切性。DBF檔除了提供新的資料類型和包含在DBC中外，這麼多年來並沒有什麼大改變。
如果你沒法建立受密碼保護的資料庫，那麼FoxPro開發者應如何保護資料呢？如果你想完全保護你的資料以致別人無法用記事本打開和看到文本欄位內容的話，那你應該使用另一個不同的資料庫平臺，例如Microsoft SQL Server 2000(個人版或完整版)。 SQL Server保護資料免於被偷窺，而且你能放心使用被Windows驗證的密鑰。
然而,SQL Server不可能是任何情況下的答案。你可能需要通過網路發佈你的一個小程式，而其中包含了一些你不希望用戶能輕易看到的資訊。在這種情況下，檔大小和可用性成為最大的關注, 而運行SQL Server就不是太明智了。
密碼使用法
微軟發佈的CryptoAPI 1.0和2.0版提供的基礎加密方法可能是你的答案。它支援通用型數碼簽名和資料加密技術。 WindowsXP/2000/98/NT/95系統普遍包含了這個密碼技術，它亦被包含在微軟的IE3.0和其後續版本內。
當Visual FoxPro 7.0的FFC包括_crypt.vcx的時候，微軟FoxPro開發組認真地考慮過_crypt.vcx可以通過CryptoAPI提供簡易的資料加密和解密功能。你可以在你的應用程式中使用這個類去實現加密應用。
當你使用這個加密應用時, 你需要作出一些讓步，這時你將不得不放棄VFP那迅捷的資料查詢速度。編碼加密和解密資料需要佔據大量運行時間，所以想在查詢中間運行它是錯誤的。
因此,最好的選擇是在你儲存資料之前或者在你收到資料之後進行編碼加密。但是你如何在一個FoxPro表中儲存加密的資料呢?
正確的答案是: 你是可以的。這裏有個簡單應用示例提供一個方法證明你能夠使用_crypt.vcx中的加密應用技術:
***建立資料表並加密的簡單示例
Public goApp
goApp = Createobject("myApp")
goApp.Run()
DEFINE CLASS myApp AS Session
** 你可以選擇比這更複雜的密鑰
cKey = "VFP7Rocks!"
oCrypto = .f.
PROCEDURE Init
This.oCrypto = Newobject("_cryptapi", Home(1) + ;
"ffc\_crypt.vcx")
** 不同機器中的_crypt.vcx的位置將不相同，因此你必須明確指定檔目錄。
** 這裏以windows2000為例。
this.oCrypto.cProviderName = ;
"Microsoft Base Cryptographic Provider v1.0"
Endproc
Function Run
=this.BuildTable("original")
=this.EncryptTable("original", "encrypted", this.cKey)
=this.DecryptTable("encrypted", "decrypted", this.cKey)
=this.BrowseTable("original", "encrypted", "decrypted")
Endfunc
** 建立一個資料表
Function BuildTable( tcTableName )
Create Table (tcTableName) Free (name C(20))
Insert Into (tcTableName) values ("Green Clovers")
Insert Into (tcTableName) values ("Blue Diamonds")
Insert Into (tcTableName) values ("Orange Stars")
Insert Into (tcTableName) values ("Pink Hearts")
Insert Into (tcTableName) values ("Purple Horseshoes")
Insert Into (tcTableName) values ("Yellow Moons")
Endfunc
** 加密每個記錄並填入新表
Function EncryptTable( tcDecryptedTable, tcEncryptedTable, tcKey )
Create Table (tcEncryptedTable) Free (data C(254))
Select (tcDecryptedTable)
Local lcCipher, luResult
Scan
lcCipher = ""
lcText = Trim(&tcDecryptedTable..name)
luResult = ;
this.oCrypto.encryptSessionBlockString(lcText, tcKey, @lcCipher )
Insert Into (tcEncryptedTable) values (lcCipher)
EndScan
Endfunc
** 解密每個記錄並填入新表
Function DecryptTable( tcEncryptedTable,
tcDecryptedTable,
tcKey )
Create Table (tcDecryptedTable) Free (data C(20))
Select (tcEncryptedTable)
Local lcCipher, luResult
Scan
lcText = ""
lcCipher = Trim(&tcEncryptedTable..data)
luResult = ;
this.oCrypto.decryptSessionBlockString(lcCipher, tcKey, @lcText)
Insert Into (tcDecryptedTable) values (lcText)
EndScan
EndFunc
** 流覽三個資料表並進行資料比較
Function BrowseTable( tcTable1, tcTable2, tcTable3 )
Select (tcTable1)
Browse Nowait
Select (tcTable2)
Browse Nowait
Select (tcTable3)
Browse Nowait
Endfunc
ENDDEFINE
這些代碼建立一個包含植物名稱的簡單資料表，並使用一個指定的密鑰來進行加解密。
這是一個證明你能夠通過使用欄位加密技術保護資料的簡單例子。
提醒大家注意的是，當你使用加密欄位後，系統精確查詢性能將被有所限制。另外，當你查詢的時候,你應該加密你的查詢標準和使用相同的密鑰，並使用密碼查詢:
Locate For MyTable.name == ";q?&?G9?-o?* -° "
不要嘗試使用你搜索到的解密資料進行搜索, 舉例說:
Locate for Decrypt(MyTable.Name, key) = "Orange Stars"
你將會後悔使用這種方法進行查詢，因為FoxPro將會每條記錄均提交解碼直到找到相匹配的資料為止!
密鑰管理
你的編譯密碼運算法則和你的密鑰同等重要，如果你有興趣的話，你可以使用世界上十億多個強力加密運算法則進行資料加密, 但只要你的加密資料密鑰一旦公開, 你的資料很快就會被公佈到互聯網上了。
這不是怎樣保護您的密鑰的簡單答案，有一個方法就是確信你的密鑰從來不使用象我示例代碼中使用的完整短語，而是使用詞語和字母的複雜組合, 存儲在你應用程式中的不同屬性裏:
...
lcFoobar = "WFJ@##"
lcGoof = "$@%93093"
...
luResult = encryptSessionBlockString( ;
lcText, lcFoobar + "XJ-EF" + lcGoof, @lcCipher )
通過這種方法作出來的系統，將會給那些想破解你的程式和提取使用密鑰的人增加更多的困難。