VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

**************************************************
*-- Class Library: d:\t1\grid1.vcx
**************************************************

**************************************************
*-- Class: grid1 (d:\t1\grid1.vcx)
*-- ParentClass: grid
*-- BaseClass: grid
*-- Time Stamp: 08/30/02 03:40:11 PM
*
DEFINE CLASS grid1 AS grid

Height = 200
Width = 320
Name = "grid1"

PROCEDURE MouseDown
LPARAMETERS nButton, nShift, nXCoord, nYCoord
local nWhere_Out, nRelRow_Out, nRelCol_Out, nView_Out
THIS.GRIDHITTEST(nxcoord,nycoord,@nWhere_Out,@nRelRow_Out,@nRelCol_Out,@nView_Out)
if nView_Out=0.or.nWhere_Out=5
node
endif
ENDPROC

PROCEDURE Scrolled
LPARAMETERS nDirection
IF nDirection>=4 &&表示是水平方向卷
IF This.RelativeColumn#This.ActiveColumn
local 鎖定列數,ii,jj,kk,總列數
左列固定寬=this.左列固定寬
鎖定列數=this.鎖定列數
if m.鎖定列數=1
This.Partition=THIS.COLUMNS(1).WIDTH+m.左列固定寬
else
總列數=this.columncount
jj=0
kk=0
for ii=1 to m.總列數
if this.columns(m.ii).columnorder<=m.鎖定列數
jj=m.jj+this.columns(m.ii).width
kk=m.kk+1
if m.kk>m.鎖定列數
exit
endif
endif
next
This.Partition=m.jj+1+m.左列固定寬+2
endif
else
this.partition=m.左列固定寬
endif
endif
ENDPROC

PROCEDURE AfterRowColChange
LPARAMETERS nColIndex
if inli(last(),3,18,24,5)
retu
endif
local 總列數,ii,鎖定列數,鎖定寬度,jj,kk,左列固定寬
左列固定寬=this.左列固定寬
鎖定列數=this.鎖定列數
總列數=this.columncount
if this.panel#1
for ii=1 to m.總列數
if this.columns(m.ii).columnorder=1
this.panel=0
this.Columns(m.ii).setfocus()
this.panel=1
This.Partition=m.左列固定寬
keyb "{tab}" plai clear
exit
endif
next
retu
endif
if this.leftcolumn>1
if m.鎖定列數=1
if This.Partition<=m.左列固定寬
for ii=1 to m.總列數
if this.columns(m.ii).columnorder=1
This.Partition=min(this.columns(m.ii).width+1,this.width-50)+m.左列固定寬
exit
endif
next
endif
else
local jj,kk
jj=0
kk=0
for ii=1 to m.總列數
if this.columns(m.ii).columnorder<=m.鎖定列數
jj=m.jj+this.columns(m.ii).width
kk=m.kk+1
if m.kk>m.鎖定列數
exit
endif
endif
next
鎖定寬度=m.jj+1+m.左列固定寬+2
if this.Partition#m.鎖定寬度
This.Partition=m.鎖定寬度
endif
endif
else
if This.Partition>m.左列固定寬
This.Partition=m.左列固定寬
endif
endif
ENDPROC

PROCEDURE Init
with this
.addproperty("差數h",thisform.height-.height)
.addproperty("差數w",thisform.width-.width)
if !vart(.鎖定列數)=="N".or.!betw(.鎖定列數,0,10)
.addproperty("鎖定列數",1)
endif
.addproperty("左列固定寬",iif(.recordmark,10,0))
.deletemark=.f.
if .splitbar
.panelLink=.f.
.panel=0
.scrollbars=1
.panel=1
.recordmark=.f.
.panelLink=.t.
.partition=.左列固定寬
endif
endw
ENDPROC

ENDDEFINE
*
*-- EndDefine: grid1
********************************************

Ruey · 發表於: 星期日七月 13, 2003 7:54 pm 文章主題:

借花敬佛：
固定GRID的任意幾列
*以固定左邊三列為例：
*在GRID的AfterRowChange事件中：
LPARAMETERS nColIndex
FOR I=1 TO 3
this.Columns(I).ColumnOrder = this.LeftColumn+I-1
ENDF
*在GRID的ScrolledD事件中：
LPARAMETERS nDirection
if nDirection>3
this.AfterRowColChange()
endif
-------------------------------------------
在 grid 中固定某一列的最簡單方法

--------------------------------------------------------------------------------
zck 於 2002-2-1 21:47:59 發表：

我以前和很多人一樣，也以為grid不能固定某一列，而這個問題在輸入工資表之類的場合卻又最需要的，把姓名那一列固定了，這樣就是不斷的往右移，姓名那一列也還能看得到。

現在方法如下：
1、給grid加個屬性：LockColumn，數值型，內容就是你要固定那一列

2、在Grid.AfterRowColChange事件裏寫上：
this.columns(this.lockcolumn).columnorder=this.leftcolumn

這就行了

方法的局限性在於：
被固定那一列，它就只能放在表格的最左邊了。即使人工用滑鼠把它拖到中間的列位置，一旦觸發AfterRowColChange事件，它又會到回第一列的位置上了

順便把我做的grid類的幾個方法寫出來，供大家參考

〖init事件〗
this.SetAll(′backcolor′,RGB(192,192,192),′header′)
this.SetAll(′forecolor′,RGB(0,0,0),′header′)
this.SetAll(′alignment′,2,′header′)
this.SetAll(′fontsize′,14,′header′)
this.SetAll(′fontsize′,14,′column′)
this.HeaderHeight = 27
this.RowHeight=27

〖BeforRowColChange事件〗
LPARAMETERS nColIndex
PRIVATE i
WITH this
FOR i=1 TO .ColumnCount
IF .columns(i).columnorder=ncolindex
.Columns(i).header1.backcolor=12632256
.Columns(i).header1.forecolor=0
.Columns(i).header1.fontbold=.f.
ENDIF
ENDFOR
ENDWITH

〖AfterRowColChange事件〗
LPARAMETERS nColIndex
PRIVATE i,j
WITH this
.columns(.lockcolumn).columnorder=.leftcolumn
FOR i=1 TO .ColumnCount
IF .columns(i).columnorder=nColINdex
.Columns(i).header1.backcolor=8421440
.Columns(i).header1.forecolor=65535
.Columns(i).header1.fontbold=.t.
j=i
ENDIF
ENDFOR
.refresh()
ENDWITH

其結果就是，游標所在的那一列，它的列標題的顏色是和其他的列不同的，從而起到標識的作用。可惜行那裏做不到這樣的效果，不然就和 OfficeXP 裏面的 Excel 一樣效果了帖號主　　　　題作者日　　期
338594 在grid中固定某一列的最簡單方法： zck 2002-2-1 21:47:59
帖號主　　　　題作者日　　期
--------------------------------------------------------

Ruey · 發表於: 星期日七月 13, 2003 7:56 pm 文章主題:

如果你有VFP8的話
固定Grid已經有個屬性LockColumn
可控制欄位了,不用擔心會有問題的
趕快換工具吧