VFP 愛用者社區 首頁 VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
 
 常見問題常見問題   搜尋搜尋   會員列表會員列表   會員群組會員群組   會員註冊會員註冊 
 個人資料個人資料   登入檢查您的私人訊息登入檢查您的私人訊息   登入登入

動態建立視圖

 
發表新主題   回覆主題    VFP 愛用者社區 首頁 -> VFP 討論區
上一篇主題 :: 下一篇主題  
發表人 內容
Ruey



註冊時間: 2003-03-12
文章: 1698
來自: tunglo

第 1 樓
發表發表於: 星期三 八月 13, 2003 11:02 am    文章主題: 動態建立視圖 引言回覆
*------ 例子
loView = CreateObject([View])
loView.CreateView([DataBase] ,[cTable] ,[cView] ,[cConnection] ,.F. ,cWhere,[cOrder],.T.,.T.)
*------ 動態建立視圖
*------ View維護用於維護視圖的完整性
*-----------------------------------------------------------
*------ 這個類有待完善
DEFINE CLASS View AS Custom

*---- 當前資料庫
PROTECTED lcDataBase
lcDataBase = []

*---- 這些屬性暫時用不上
*---- 連接控制碼
PROTECTED nConnHandle
nConnHandle = 0
*---- 連接名稱
PROTECTED cConnection
cConnection = []
*---- 連接對應的資料庫
PROTECTED cDataBase
cDataBase = []
*---- 伺服器表名
PROTECTED cTable
cTable = []
*----- dbc視圖名稱
PROTECTED cView
cView = []
*----- 是否設置預設值
PROTECTED lSetDefault
*----- 是否用預設值檢查現存資料
PROTECTED lCheckDataByDefault

*----- 檢查伺服器是否存在此表
*----- 並且返回大小寫的表名
*----- 第一個參數tcTable檢查的表名，不區分大小寫
*----- 第二個參數是後臺伺服器連接（代表某一個資料庫)
PROCEDURE CheckTable
LPARAMETERS tnConnHandle ,tcTable

lcAlias = Alias()
*---- 避免結果名稱和系統其他工作去表名重複
lcTableDictionary = SYS(2015)
IF SQLTABLES(tnConnHandle ,[TABLE] ,lcTableDictionary) < 0
*---- 失敗，返回

RETURN .F.
ENDIF

SELECT (lcTableDictionary)

LOCATE FOR LOWER(ALLTRIM(table_name)) == LOWER(ALLTRIM(tcTable))
IF !FOUND()
USE
*---- 如果資料庫中沒有此表
RETURN []
ENDIF
*----- 如果作為引用，這句話有用
tcTable = ALLTRIM(table_name)
IF NOT EMPTY(lcAlias)
SELECT lcAlias
ENDIF
USE IN (lcTableDictionary)
RETURN tcTable
ENDPROC
*----- 檢查欄位是否存在
*----- 如果存在則返回區分大小寫的欄位名稱
*----- 第二個參數必須是陣列
PROCEDURE CheckField
LPARAMETERS tnConnHandle ,tcTable ,tacField ,tnColIndex
*---- tacField是一個欄位陣列
*---- 陣列可能是多維
lcTableStru = SYS(2015)
IF SQLCOLUMN(tnConnHandle ,tcTable ,[NATIVE] ,lcTableStru) <= 0
RETURN .F.
ENDIF
SELECT (lcTableStru)


lnRow = ALEN(tacField ,1)
m.i = 1

*---- 加入調試命令
lcAssert = SET([Asserts])
SET ASSERTS ON



FOR i = 1 TO lnRow
IF EMPTY(tnColIndex)
lcField = tacField[m.i]
LOCATE FOR LOWER(ALLTRIM(column_name)) == LOWER(ALLTRIM(tacField[m.i]))
IF FOUND()
tacField[m.i] = ALLTRIM(column_name)
ELSE
ASSERT FOUND() MESSAGE [欄位] + tacField[m.i] + [在伺服器表中找不到了]
ENDIF
ELSE
lcField = tacField[m.i,tnColIndex]
LOCATE FOR LOWER(ALLTRIM(column_name)) == LOWER(ALLTRIM(tacField[m.i,tnColIndex]))
IF FOUND()

tacField[m.i,tnColIndex] = ALLTRIM(column_name)

ELSE
ASSERT FOUND() MESSAGE [欄位] + tacField[m.i,tnColIndex] + [在伺服器表中找不到了]
ENDIF
ENDIF

ENDFOR

USE IN (lcTableStru)
SET ASSERTS &lcAssert


RETURN tacField
ENDPROC

*----- 創建連接
*----- 第一個參數是資料庫
*----- 第二個參數連接名稱
PROCEDURE CreateConnection
LPARAMETERS tcDataBase ,tcConnection
*---- 保存當前資料庫的名稱
*---- 這樣子可以對多個資料庫進行操作
This.lcDataBase = SET([Database])

IF NOT EMPTY(tcDataBase) AND (LOWER(tcDataBase) # LOWER(This.lcDataBase) OR EMPTY(This.lcDataBase))
IF NOT DBUSED(tcDataBase)
OPEN DATABASE (tcDataBase) SHARED
ENDIF
SET DATABASE TO (tcDataBase)
ENDIF

IF EMPTY(SET([Database]))
MESSAGEBOX([請打開資料庫] ,16 ,[錯誤])
RETURN 0
ENDIF

*----- 檢查連接的合法性。如果合法，進行連接
*----- 建議連接為空的是否系統自動彈出連接對話方塊
*----- 讓用戶選擇，暫時不加入此功能
IF EMPTY(tcConnection) OR VARTYPE(tcConnection) # [C]
RETURN 0
ELSE

DIMENSION acConnection[1]
IF ADBOBJECTS(acConnection ,[CONNECTION]) > 0
IF ASCAN(acConnection ,UPPER(tcConnection)) <= 0
MESSAGEBOX([連接名稱] + tcConnection + [不存在資料庫中] ,16 ,[錯誤])
RETURN 0
ENDIF
ENDIF
lnConnHandle = SQLCONNECT(tcConnection)
*---- 如果連接不通
IF lnConnHandle <= 0
MESSAGEBOX([不能連接] ,16 ,[錯誤])
RETURN 0
ENDIF
ENDIF

RETURN lnConnHandle
ENDPROC

PROCEDURE CloseConnection
LPARAMETERS tnConnHandle

*---- 如果執行視圖前資料已經打開了資料的話
IF NOT EMPTY(This.lcDataBase)
SET DATABASE TO (This.lcDataBase)
This.lcDataBase = []
ENDIF
RETURN SQLDISCONNECT(tnConnHandle)

ENDPROC
*----- 創建視圖
*---- CreateView的參數解釋
*---- 第一個參數是資料庫的，如果此參數為空那麼，CreateView使用當前資料庫 ,如果當前資料庫沒有打開則提示錯誤返回
*---- 第二個參數是伺服器的表名，不區分大小寫（避免程式師記錯大小寫）
*---- 第三個參數遠端視圖的名稱
*---- 第四個是遠端連接的參數{現存連接（數值型） , 連接名稱（字元型)},系統自動識別
*---- 第五個參數是設置預設值的是否需要檢查現存的資料
PROCEDURE CreateView
LPARAMETERS tcDataBase ,tcTable ,tcView ,tvConnection ,tlValidData ,tcWhere ,tcOrderBy ,tlFieldSetting ,tlUpdatable

lCloseHandle = .T.
*---- tvConnection 是已經存在的連接
IF VARTYPE(tvConnection) = [N]
lnConnHandle = tvConnection
tvConnection = [SQLSVR_UTGL]
lCloseHandle = .F.
ELSE
lnConnHandle = This.CreateConnection(tcDataBase ,tvConnection)
ENDIF
*This.CheckTable(lnConnHandle ,@tcTable)
*----- 創建遠程視圖

lcCreateViewSql = [CREATE SQL VIEW ] + tcView + [ REMOTE CONNECT ] + tvConnection + [ AS SELECT * FROM ] + tcTable

*---- 建議在前面匹配大小寫
*---- 視圖參數
IF NOT EMPTY(tcWhere)
tcWhere = tcTable + SUBSTR(tcWhere ,AT([.] ,tcWhere ))
lcCreateViewSql = lcCreateViewSql + [ WHERE ] + tcWhere
ENDIF
*---- 排序欄位
IF NOT EMPTY(tcOrderBy)
lcOrderBy = tcTable + SUBSTR(tcOrderBy ,AT([.] ,tcOrderBy))
lcCreateViewSql = lcCreateViewSql + [ ORDER BY ] + tcOrderBy
ENDIF

*---- 產生視圖
&lcCreateViewSql

IF tlFieldSetting
This.FieldSetting(lnConnHandle ,tcTable ,tcView ,tlUpdatable ,tlValidData)
ENDIF

*---- lCloseHandle 在方法開頭定義
IF lCloseHandle
IF This.CloseConnection(lnConnHandle) # 1
MESSAGEBOX([不能斷開連接] )
ENDIF
ENDIF

ENDPROC

*---- 是指視圖欄位的屬性
*---- 第一個參數是連接
*---- 第二個參數是伺服器表（區分大小寫的），如果不清楚請使用CheckTable獲取
*---- 第三個參數dbc中的視圖名稱（不區分大小寫）
*---- 第四個參數表示把表設置為不可更新的
*---- 第五個參數驗證資料的預設值
PROCEDURE FieldSetting
LPARAMETERS tnConnHandle ,tcTable ,tcView ,tlUpdatable ,tlValidData

DBSetProp(tcView, [View] ,[UpdateType] , 1)
DBSetProp(tcView, [View] ,[WhereType] , 1)
DBSetProp(tcView, [View] ,[SendUpdates] , tlUpdatable)
DBSetProp(tcView, [View] ,[FetchMemo] , .T.)


*---- 這裏加入了NODATA
*---- 如果需要驗證資料的預設值
IF NOT USED(tcView)
IF tlValidData
USE (tcView) IN 0
ELSE
USE (tcView) NODATA IN 0
ENDIF
ENDIF

SELECT (tcView)
GO BOTTOM

*---- 加入調試命令
lcAssert = SET([Asserts])
SET ASSERTS ON

*---- 獲取欄位的配置資訊
lcTableStructure_F = SYS(2015)
ln = SQLCOLUMN(tnConnHandle ,tcTable ,[NATIVE] ,lcTableStructure_F)
*---- 這裏一般出現連接級別的錯誤
IF ln<=0
MESSAGEBOX(STR(ln))
ENDIF

IF NOT USED(lcTableStructure_F)
ASSERT USED(lcTableStructure_F) MESSAGE [找不到表] + tcTable + [的後臺配置]
ENDIF
SET ASSERTS &lcAssert

SELECT (lcTableStructure_F)
GO TOP

DO WHILE .NOT. EOF()
*---- lcField是區分大小寫的欄位名稱
lcField = TRIM(column_name)
lcDefault = ALLTRIM(column_def)

lcDefault = STRTRAN(lcDefault ,[)] ,[])
lcDefault = STRTRAN(lcDefault ,[(] ,[])
*---- 在default值中產生的預設值包含asc碼為0的字元
lcDefault = STRTRAN(lcDefault ,CHR(0) ,[])

lcViewField = FORCEEXT(tcView ,lcField)
lcUpdateField = FORCEEXT(tcTable ,lcField)

SELECT (tcView)
*---- 設置關鍵字和更新欄位
lcSqlRemoteKeyField = DBGETProp(lcUpdateField ,[Field] ,[KeyField])
DBSetProp(lcViewField ,[Field] ,[KeyField] ,lcSqlRemoteKeyField)
*---- 設置是否可以更新
DBSetProp(lcViewField ,[Field] ,[Updatable] ,tlUpdatable)
DBSetProp(lcViewField ,[Field] ,[UpdateName] ,lcUpdateField)
*---- lcSqlType 的返回值格式，如：N(4,2)
lcSqlType =DBGETPROP(lcViewField,'Field',[DataType])
lcSqlCutType = SUBS(lcSqlType ,1 ,1)
DO CASE
CASE lcSqlCutType = [C]
*---- 如果SQLSERVER的後臺沒有此欄位的預設值
IF EMPTY(lcDefault)

SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default '' For ] + lcField) &&修改SQL中的預設值
lcDefault = ['']
ENDIF
*---- 對關鍵字進行設置
IF lcField = [sqllno]
DBSetProp(lcViewField ,[Field] ,[Defaultvalue] , [Keyvalue()])
REPLACE ALL &lcField WITH SYS(2015) + [系統] FOR EMPTY(&lcField) OR ISNULL(&lcField)
ELSE

DBSetProp(lcViewField, 'Field', 'Defaultvalue', "&lcDefault")
REPLACE ALL &lcField WITH &lcDefault FOR ISNULL(&lcField)
ENDIF
*---- 記錄創建者
IF lcField="sys_creater"
DBSetProp(lcViewField ,[Field] ,[Defaultvalue] ,[UserName])
ENDIF
CASE lcSqlCutType = [N]
IF EMPTY(lcDefault)
*---- 修改SQL中的預設值
SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default 0 For ] + lcField)
lcDefault = [0]
endif
lnLen = VAL(SUBSTR(lcSqlType ,3))
lcOldType = STRTRAN(lcSqlType ,[N(] + ALLTRIM(STR(lnLen)) ,[])
lcNewType = [N(] + ALLTRIM(STR(lnLen-2)) + lcOldType
DBSETPROP(lcViewField ,[Field] ,[DataType] ,lcNewType)
CASE lcSqlCutType = [M]
IF EMPTY(lcDefault)
*---- 修改SQL中的預設值
SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default '' For ] + lcField)
lcDefault = ['']
ENDIF
CASE lcSqlCutType = [L]
IF EMPTY(lcDefault)
*---- 修改SQL中的預設值
SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default 0 For ] + lcField)
lcDefault = [.F.]
ELSE
lcDefault = IIF(lcDefault = [0] ,[.F.] ,[.T.])
ENDIF
CASE lcSqlCutType =
IF EMPTY(lcDefault)
*---- 修改SQL中的預設值
SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default 0 For ] + lcField)
lcDefault = [0]
ENDIF
*----- 設置最長的長度
DBSETPROP(lcViewField ,[Field] ,[DataType] ,[N(13,4)])
CASE lcSqlCutType =
IF EMPTY(lcDefault)
*---- 修改SQL中的預設值
SQLEXEC(tnConnHandle ,[Alter Table ] + tcTable + [ Add Default 0 For ] + lcField)
lcDefault = [0]
ENDIF
DBSETPROP(lcViewField ,[Field] ,[DataType] ,[N(Cool])
CASE lcSqlCutType = [T]
DBSETPROP(lcViewField ,[Field] ,[DataType] ,[D])
REPLACE ALL &lcField WITH null FOR year(&lcField)<1911
ENDCASE
*---- 針對數值型欄位，一次性處理
IF lcSqlCutType $ [NMLBI]
DBSetProp(lcViewField ,[Field] ,[Defaultvalue] ,[(&lcDefault)])
REPLACE ALL &lcField WITH &lcDefault FOR ISNULL(&lcField)
ENDIF
SELECT (lcTableStructure_F)
SKIP
ENDDO
USE IN (lcTableStructure_F)
USE IN (tcView)
ENDPROC
ENDDEFINE
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!

學會VFP使用者社區的搜尋,Code才會更有趣~
#############################
回頂端
檢視會員個人資料 發送私人訊息
從之前的文章開始顯示:   
發表新主題   回覆主題    VFP 愛用者社區 首頁 -> VFP 討論區 所有的時間均為 台北時間 (GMT + 8 小時)
第1頁(共1頁)

 
前往:  
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案


Powered by phpBB © 2001, 2005 phpBB Group
正體中文語系由 phpbb-tw 維護製作