VFP 愛用者社區

joson · 註冊時間: 2003-06-16 文章: 4 第 1 樓

一個使用說明，關於cursoradapter類的
翻譯：四維

vfp8最激動人心的變化是 CursorAdapter 類，它爲不同的資料源提供通用的資料介面。
下面介紹怎樣用 CursorAdapter 改變在 VFP 8 中連接資料的方式,包括，native tables, ODBC, OLE DB, XML. 。

CursorAdapter 類是 VFP 8 開發組的最給人印象深刻的成就之一。它將會改變許多開發者連接各種不同的資料來源的方式。開發小組在 VFP 存取資料的方式方面作了重要改變,將本地和遠端資料連接方式進行了統一。另外，創建 CursorAdapter 類對那些已經熟練使用視圖和SPT人來說並不費力。對使用ADO RecordSets 或XML可擴展標示語言文件的人也不費力。

CursorAdapter 類的獨特之處在於，它是第一個提供本地游標、ODBC、ADO、XML資料源連接的基類，在一個類裏面實現了所有連接功能。換句話說，要將ODBC資料源，ADO RecordSet 或XML可擴展標示語言文件翻譯成一個 VFP 游標，CursorAdapter 類完全可以勝任。

你或許會說 CursorAdapter 是較早版本中本地視圖和遠端視圖技術的替代 (注意: VFP 8中仍然保留這些功能). 但是在一些情形中，它也代替了SPT, 以及減少了使用ADO和XML時的代碼量，可以直接使用ADO和XML。
CursorAdapter 的最大好處是，需要在同一個程式內連接到多個資料源的時候，它爲你提供方便。舉例說，如果你的程式大部分數據來自 SQL server，但是同時需要與XML可擴展標示語言連接,CursorAdapter 可以整合這兩種情況，使程式取回的資料作爲VFP的游標。

另外的一個例子是資料現在被儲存在 VFP 表中 , 但是計劃要移到一個資料庫伺服器 , 比如 SQL server或Oracle。你需要先建立一組 VFP CursorAdapter 類，必要的時候以 SQL server以外的資料庫代替這些類。

但是,就象我們能跑之前必須學會走一樣,先概覽一下 CursorAdapter 類和它的特性。然後，使用 CursorAdapter 類來設計資料類是比較容易的。

建立第一個 CursorAdapter 類，象其他類一樣，學習怎樣使用它的最好辦法是瞭解建立過程。第一次建立這些類的時候複雜程度低一些,我們開始用 CursorAdapter 類存取 VFP 本地的資料。這很象使用本地視圖取回 VFP 本地表的資料。稍後在這一篇文章中，我們將會使用另一個 CursorAdapter 類連接到 SQL server資料庫，ODBC和XML。
首先，你有二個方法建立 CursorAdapter 。你能使用資料環境建立，也可以手動通過程式或類設計器來創建一個經過一個CursorAdapter類。這一個例子將會使用資料環境建立；較遲的例子將會手動建立.

如果你不熟悉 VFP 8 變化後的資料環境, 你可能認爲在設計環境下創建的 CursorAdapter 只能在表單中使用,不能用於類。然而， VFP 8 中已經改善了設計環境，因此不需要在表單中就可以創建。

用creat class命令創建一個新的資料環境類。

此主題相關圖片如下：

確定從下拉清單中選擇based on資料環境類(dataenvironment) 。類名爲Tests,所屬類庫名爲tests.vcx.

此主題相關圖片如下：

創建的類在類設計器中出現後，右鍵單擊Data Environment ，選擇builder,起動資料環境建立向導。

此主題相關圖片如下：

在資料源類型項下，注意可選的選項。因爲第一個例子將會連接到本地的 VFP 表,選擇native。選擇完以後, 使用‘省略號’按鈕選擇 Northwind 資料庫（我這裏是gzdata資料庫）。 (默認位置是 c:\ program files\microsoft visual foxpro 8\ sample\northwind\ northwind.dbc)

此主題相關圖片如下：

下一步,點cursors 頁, 它初始值是空的。在列表框中,選擇new按鈕用 CursorAdapter 設計器創建一個新的 CursorAdapter 類。

此主題相關圖片如下：

首先，你應該看看Properties頁，這裏提供選項來選擇類的名字和由類産生的游標的別名。
確定提供一個不同於表名字的別名，避免産生混亂。在這裏,使用 caCustomer 做類名， cCustomer 作爲別名。如果想讓這個類用和資料環境一樣的資料源，應該選擇 "Use DataEnvironment data source" 。注意你可以爲 CursorAdapter 設置不同的資料源, 允許你在不同的類之間整合資料源.( 例如一個類使用ODBC資料源，另一個類使用XML資料源)

此主題相關圖片如下：
要定義CursorAdapter 如何返回來自資料源的資料,使用設計器中的Data Access 頁。按build按鈕啟動一個對話方塊，可以選擇游標包含的欄位。

此主題相關圖片如下：

在這個例子中,選擇Customers表, 然後選擇Customers.*。點擊向右的箭頭移動選擇項, 然後點ok。

此主題相關圖片如下：

這爲你建立下列SQL語句:
select CUSTOMERS.* from CUSTOMERS
如果你想添加篩檢程式,連接, 或其他條件到查詢,你可以在列表框中直接鍵入。如果你想建立帶參數的查詢,有一些選項,在本文後面介紹。現在, 讓我們添加WHERE子句:
select CUSTOMERS.* from CUSTOMERS where
companyname like 'C%'
這裏可以看出源表和游標的不同，因爲只有少數記錄符合WHERE子句。
在第二個編輯框(schema)中已經爲爲你創建了欄位列表。通常在繼續以前花幾分鐘看看欄位順序是否符合你的習慣是有好處的
在這一頁的下半部分有資料包設置對話方塊（data fetching），用來設置怎樣處理遠端資料包，當用vfp作爲資料源的時候，這裏的設置不發揮作用。（如上圖）這裏我們保留默認設置，稍後再講述具體細節。在本頁的底部附近是緩衝模式設定, 允許你設置任何被關聯的表單的緩衝模式。有兩個選項：開放式行緩衝和開放式表緩衝。

此主題相關圖片如下：

通常，你使用開放的表緩衝模式，除非你有特殊要求使用行緩衝模式。在這個例子中設置爲開放式的表緩衝。最後，“break on error”控制CursorAdapter類怎樣來處理錯誤。默認設置是類（class）自行捕獲錯誤，並且允許你用aerror()函數捕獲這些錯誤。選定這個設置，CursorAdapter類內部不管發生什麽錯誤，vfp都會出現錯誤資訊。也就是說，你需要使用ON ERROR命令或者‘類’的ERROR事件來排除不需要報錯的情況。通常情況下不選這項設置，以便程式能處理任何發生的例外情況。
最後一頁 (auto update) 配置如何更新源表。在通常情況下，選擇“自動更新（auto-update)”和“更新所有欄位(update all fields)”。

此主題相關圖片如下：
這將使cursoradaper類對游標（cursor）中資料的任何改變自動建立適當的更新、插入、刪除機制。然而，你必須選擇游標中的主關鍵欄位，以便這些機制（更新、刪除、插入）唯一的識別源表中的記錄。在本例中，CustomerID是關鍵欄位。因此，需要在其前面大上‘對號’。其他的設置暫時保留預設值。具體設置辦法在本文後面講述。設置完cursoradaper後，點擊“ok”按鈕，回到資料環境設置。此時，你應該在左邊列表框中能看到caCustomer類, 在右邊看到細節。如果你想更改這個類，你可以隨時用資料環境‘builder’更改，選擇需要更改的CursorAdapter 類，然後點擊builder按鈕。
存取 VFP 資料
此時，你可以測試資料環境，看看是否能取回在 CursorAdapter 的指令中篩選的資料。使用命令窗戶,例示 DE 類而且喚起 OpenTables 方法:
lo = NewObject("deTest","Tests.vcx")
? lo.OpenTables()
BROWSE

一個特殊情況是，CursorAdapter的游標連接到其他物件，如果你毀壞了指向CursorAdapter類的物件，會丟失游標和其中的記錄。這就是說，你必須確保CursorAdapter物件參數在你打算存取的關聯游標的範圍內
編輯 VFP 資料
現在, 讓我們看看是否能夠更新游標，並且把更新準確地發送到源表。在命令窗口測試以下命令:
REPLACE contactname WITH 'My Name Here'
?TABLEUPDATE()
SELECT customers
BROWSE
瀏覽customers別名,你會發現修改過的記錄已經更新到源表中。如果你在發送replace命令之前沒有移動記錄指標,客戶ID中 'CACTU' 所在的記錄被修改。不管你修改哪條記錄, 這證明 CursorAdapter 是能夠被更新，而且更新能夠準確地被發送到源表。

讓我們打開你剛剛測試的資料環境類，這不只是一個練習—它是一個很棒的方法學習當你決定在資料環境以外建立自己的類的時候，該如何正確地配置一個 CursorAdapter 類。

雖然資料環境有一些屬性改變和一個方法, 我們實際上對那些改變不感興趣。看一下下拉清單框中的屬性列表，選擇 caCustomer 類，看看建立 CursorAdapter 類的時候需要進行的設置。表 1 概述被builder和每個 PEM 所做改變。
所有的屬性包含在 "see Init" ,通過INIT方法中的代碼來設置這些屬性。那一段代碼顯示在list 1中。
在builder設置完以後，看看一些屬性是怎樣設置的，這是最好的學習方法。你可以在這裏或者通過builder改變設置值。然而，如果在這裏改變設置值，你需要冒破壞一些功能的風險，因爲你在這裏改變的屬性有可能在builder裏不會發生改變。
不管怎樣,你能在 Init() 代碼中看到 SelectCmd 屬性是如何敍述的, 同樣在 KeyFieldList ， UpdatableFieldList 和 UpdateNameList中也可以看到。特別注意 UpdateNameList 屬性—這個屬性列出游標的每一個欄位以及源表中對應的欄位(帶表名稱)。
當從頭創建你自己的 CursorAdapter 類的時候，你可能想在這個列表中省略表名字。然而，如果不使用精確的格式，你的更新將會失敗, 但是沒有錯誤提示。在後面講不通過builder建立一個類的時候我將再說這一點。
前面我說過 CursorAdapter使用本地的資料源的時候 , 本質上是一個替代了本地視圖。如果你曾經用過本地視圖，你可以發現類似的地方: 生成一個SQL select語句，定義哪些欄位將被更新，設置關鍵欄位，剩下的事情讓 VFP 來做。一旦游標中取回資料，可以使用 TableUpdate() 發送更新到源表，而且 VFP 自動地建立必要的update,insert,delete語句。
還是以上面的例子, 取消cCustomer 別名中contact欄位被替換的資料。通過TableUpdate ， VFP 自動地産生 (並提交)下列更新命令嘗試更新:

UPDATE customers
SET CONTACTNAME=ccustomer.contactname
WHERE
CUSTOMERID=OLDVAL('customerid','ccustomer');
AND
CONTACTNAME=OLDVAL('contactname','ccustomer')
VFP 能夠根據CursorAdapter的KeyFieldList屬性和部分UpdateNameList屬性中的值産生where子句。它通過子句記錄那些已經被改變或添加的記錄，保證你不會更新那些別人已經更新過的記錄。注意，這是因爲我們在它的WhereType 屬性中保留預設值 "key fields and any modified fields."

在本文中出現table1,list1等，可惜我當時沒下載，現在已經找不到了，不過不會對理解本文有什麽影響，下次發“cursoradapter類的錯誤處理"

錯誤處理
明顯的，當用 CursorAdapter 更新資料時候 ,並不能完全如你所願。你知道,多種原因可以導致TableUpdate 更新失敗, 例如更新衝突或記錄加鎖失敗。你必須對 CursorAdapter 類做特別處理來發現這些問題嗎? 答案是,"視情況而定 ."
我們來建立一個簡單的更新問題：給CursorAdapter嘗試更新的一條記錄加鎖。如果類設計器仍然是開著的,關掉它。然後, 像前面做過的一樣，用 NewObject 函數啓動detest類,而且啓動 OpenTables 方法。瀏覽游標以便你能看到資料,但是先不要改變任何東西。
現在打開 VFP 8 的第二個實例，這樣就能夠加鎖記錄。在命令視窗中運行下列語句加鎖你將嘗試更新的記錄:
OPEN DATABASE (HOME(2)+"Northwind\northwind.dbc")
USE customers
LOCATE FOR customerid = 'CACTU'
?RLOCK()
你應該能返回.T.，表明記錄確實被 VFP 的這一個實例加鎖。
回到 VFP 的第一個實例，在命令視窗中運行下面的代碼:
REPLACE contactname WITH 'updated'
SET REPROCESS TO 2 SECONDS
?TABLEUPDATE()
在這種情況, TableUpdate 返回.F.,表現記錄鎖阻止更新成功。如果你用 AERROR() 捕獲錯誤而且顯示錯誤結果, 你會看到錯誤資訊 "記錄沒加鎖"。這意味著如果你對設置緩衝的表直接操作而不是一個游標，你能用同樣的辦法處理錯誤。
不幸地，不是所有的預期錯誤都會這樣表現出來。需要特別注意的是更新衝突,比如一個使用者企圖覆蓋其他人所作的修改。想看看這種行爲的結果,在當前的 VFP 實例中(CursorAdapter 正在使用)運行下面的代碼：
?TABLEREVERT(.T.)
REPLACE contactname WITH 'client 1'
現在轉變在到第二個例證並且發行下列指令:
CLOSE DATABASES all
OPEN DATABASE (HOME(2) + "Northwind\northwind.dbc")
USE customers
LOCATE FOR customerid = 'CACTU'
REPLACE contactname WITH 'client 2'
BROWSE
返回第一個實例, 嘗試用 TableUpdate 發送更新:
?TABLEUPDATE()
在這種情況， TableUpdate 錯誤地返回.T.,使你相信更新成功了! 然而, 事實上並沒有成功，而且這可以被CursorAdapter的CursorRefresh() 方法證明, 用下列代碼:
?TABLEREVERT(.T.)
?lo.caCustomer.CursorRefresh()
CursorRefresh 方法告訴 CursorAdapter 再運行 SelectCmd 裏的語句，並且取回來自源表的最新資料。對ContactName 欄位的測試說明 CursorAdapter 根本沒更新欄位值!
解決這一個問題的最簡單的方法要利用 CursorAdapter 的 AfterUpdate 方法。這一個方法在 TableUpdate 發送保存每條記錄的請求後被執行。注意這個‘方法’只對當前記錄有效。如果記錄是新的，或者記錄已經被刪除,會啟動AfterInsert 或 AfterDelete 方法。
AfterUpdate 方法捕獲一些參數, 包括最初的欄位狀態,是否被強制更改, 和作爲更新的命令。最後一個參數 , lResult,是我們這部分主題最重要的,因爲它告訴我們更新過程是否成功。
使用的另一個重要角色解決更新衝突問題的是系統變數 _tally, 它告訴我們最後一次操作影響了多少記錄。因此，如果 lResult 放回成功的, 但是 _tally是零,那麽說明沒有記錄被更新，那麽你可以判定這種情況是一個更新衝突。
簡單說，解決這一個問題的簡單方法是把下列代碼加入 CursorAdapter 類的 AfterUpdate 方法:
LPARAMETERS cFldState, lForce, nUpdateType, cUpdateInsertCmd, cDeleteCmd, lResult
IF lResult AND _TALLY = 0 THEN
ERROR 1585 && update conflict
ENDIF
有趣的是你在螢幕上看不到錯誤資訊;錯誤資訊被 TableUpdate “限制住了”,這就迫使你使用 AError 函數分析更新失敗的原因。出現這樣的現像是因爲 BreakonError 屬性保留了預設值 ,也就是錯誤不引起程式中斷。如果你把這個屬性設爲“ture",那麽"更新衝突" 錯誤資訊就會出現,如果作了定義,你的ON ERROR控制碼會被運行。
這一個更新衝突問題是爲 CursorAdapter設計的，因爲 VFP 8 沒有自動發現這個問題方法。因此，當不用本地資料源的時候，這個代碼( 或相似的代碼)會用在你的CursorAdapter類設計中。

CursorAdapter with ODBC
現在你已經有了一定的基礎, 讓我們繼續看看當後臺資料庫用 SQL server的時候怎樣進行設置。我們將從使用 VFP 通過ODBC連接 SQL server上的 Northwind 資料庫開始。同樣, 讓我們從頭建立 CursorAdapter 以便可以看見類需要設置的各個方面。
首先,用下列指令在類設計器中建立一個新類:
CREATE CLASS caODBC OF tests as CursorAdapter
這裏需要設置的最重要的屬性是 DataSourceType 屬性。因爲我們想通過ODBC連接 SQL server,將這一屬性設置爲ODBC。當使用這種連接方式的時候 , DataSource 屬性需要有一個確切的連接控制碼,可以用 SQLConnect 或 SQLConnectString 函數建立。在任一情況，這些功能應該在 CursorAdapter 類的 Init 方法中使用下列代碼:

LOCAL lcConnStr, lnConn
** string assumes trusted connection (integrated security)
lcConnStr = "Driver=SQL Server;Server=(local);DATABASE=Northwind"
lnConn = SQLSTRINGCONNECT(lcConnStr)
IF lnConn > 0 THEN
THIS.DATASOURCE = lnConn
ELSE
** unable to connect
ENDIF
連接字串假定你使用可信賴的關聯到 SQL server；如果你使用安全的連接到 SQL server,把 "uid"= 和 "pwd"= 串加入連接控制碼指定使用者名稱和密碼。任何一種情況下，返回的是連接柄 , 或錯誤發生時的否定值。這一個連接柄被指定爲 DataSource 屬性以便 CursorAdapter 知道該到哪里聲明。
下一個步驟是建立 SelectCmd 以便 CursorAdapter 知道需要從資料源取回什麽資料。還有一個最好的放置地方是 Init 方法, 因爲屬性表限制字串的長度。把下列代碼加入 Init 方法中,設定 DataSource 屬性代碼之後, 取回公司名字中以 "C" 開頭的客戶列表:

This.SelectCmd = "SELECT " +
"CustomerID, CompanyName, ContactName, " +
"Address, City, Region, Country " +
"FROM Customers WHERE CompanyName LIKE 'C%'"
然後，你應該告訴 CursorAdapter 通過調用CursorFill 方法填充被關聯的游標。你可以省略這一個調用，並且手動從類之外調用, 或放在 Init 方法中，以便它能夠自動填充游標。在Init 方法中設置 SelectCmd 之後，可以用 This.CursorFill()調用。

最後，你應該在類的Destroy方法中加上一些代碼，以便在物件從記憶體中釋放以後減少到伺服器的連接。沒有這些代碼的話，每一個新的實例將會産生一個到伺服器的新連接, 並且不會釋放它:

IF this.DataSource > 0 THEN
SQLDISCONNECT(this.DataSource)
ENDIF
藉由這些變化，你擁有一個實用的 CursorAdapter 類，它能夠生成一個唯讀的游標。在允許更新之前，測試一下類，確保可用，並能準確取回資料。用下列代碼測試:
lo = NEWOBJECT("caODBC","tests")
BROWSE
注意，你不需要像資料環境那樣調用 OpenTables 方法。這是因爲你把 CursorFill 方法直接加入了 Init 方法,使類在實例化之後自動地填充游標。

Updating ODBC Data（更新ODBC資料）
爲了使這個類可更新,你必須正確地給Tables, KeyFieldList ， UpdatableFieldList 和 UpdateNameList 屬性賦值。並且設定 AllowInsert ， AllowUpdate 和 AllowDelete 屬性爲true, 確定自動更新特徵被啟動。再一次強調，最好的辦法是在Init 方法中用代碼設置這些屬性。 Init 方法一些代碼在list2 中。
在關閉類設計器之前,你可能想將 BufferModeOverride 屬性換成 "5",“開放的表緩衝”以便移動記錄指標的時候 , 自動更新不發生。

測試 CursorAdapter 的更新能力,把它作爲一個實例,瀏覽游標,作一個更改, 然後提交 TableUpdate。確定所作的更改被回應,調用 CursorAdapter 的 CursorRefresh 方法，再瀏覽一次。
處理ODBC錯誤（Handling ODBC Errors）象使用本地 CursorAdapter一樣，大多數的錯誤處理是按照 "傳統的"方法—測試 TableUpdate 返回的值，如果失敗，使用 AError 來判斷原因。不幸的是，更新衝突的檢測也是ODBC連接類型 CursorAdapter 的一個問題。

本地 CursorAdapter 錯誤的解決辦法是在 AfterUpdate 方法中設置錯誤處理代碼, 但這種方法對ODBC型 CursorAdapter 是無效的，因爲更新失敗的時候，我們不是要處理VFP錯誤,而是ODBC錯誤。因此，最好答案是使用一個存儲過程，或在更新控制碼中增加一些代碼發送到伺服器。

回想一下，爲本地的 CursorAdapter 更新錯誤的解決辦法是檢查 _TALLY，看看是否有記錄被更新。爲ODBC連接的解決辦法與本地CursorAdapter是相似的，但是我們不能使用 _TALLY，因爲在遠端資料檢測上它是不可靠的。我們可以使用SQL server的@@Rowcount 系統函數來判定記錄是否被更新。

如果你要寫一個 T- SQL 批量更新語句來更新一筆記錄,你應該象下面這樣寫:
--@custID and @oldContact set by earlier code or parameters
UPDATE customers
SET ContactName = @newContact
WHERE CustomerID = @custID
AND ContactName = @oldContact
IF @@ROWCOUNT = 0
RAISERROR('Update failed.',16,1)
RaisError T- SQL 函數使 VFP 接收一個ODBC錯誤 (1526 號), 在第一個參數裏寫錯誤資訊.(另外二個參數指出嚴重和錯誤的狀態) 在這種情況下，當@@Rowcount=0的時候RaisError 被調用, 表明早先的 T- SQL 語句沒影響任何的記錄。

所有討論的這一些表明你可以使用 CursorAdapter 的 BeforeUpdate 方法來描述發送到伺服器用來更新的語句。 BeforeUpdate 方法接受五個參數, 有趣的是最後的二個 (cUpdateInsertCmd 和 cDeleteCmd) 建立了關聯（注：原文the last two (cUpdateInsertCmd and cDeleteCmd) are interesting in that they are passed by reference. ）。在它們被送去資料源之前 , 這允許你修改指令。

在我們的例子中，我們使用這一個方法增加一個對@@Rowcount的測試然後調用 RaisError 。把下列代碼寫入 BeforeUpdate :
LPARAMETERS cFldState, lForce, nUpdateType,
cUpdateInsertCmd, cDeleteCmd
IF nUpdateType = 1 THEN
cUpdateInsertCmd = cUpdateInsertCmd +
" if @@ROWCOUNT = 0 "+
"RAISERROR('Update Failed due to update " +
"conflict.',16,1)"
ENDIF
現在，爲發送到後臺資料庫的每一行記錄，用這段代碼測試行是否被更新。如果沒更新， VFP 將會接收到錯誤,TableUpdate 將會失敗，而且 AError 將會顯示1526號錯誤，並顯示預設的錯誤資訊。

存在二個的問題。首先，這是特別爲 SQL server設置的；對其他的ODBC資料源 ( 比如ORACLE) ，這一段代碼無效。其次，這個錯誤資訊是指一類錯誤，總是産生相同的 VFP 錯誤號, 而且在 VFP 中建立正確的錯誤處理控制碼有一點困難。這一個問題可以通過在SQL SERVER伺服器上建立通用的錯誤資訊，每條資訊對應著自己的唯一錯誤號碼。

另外一個更好的解決方法是使用存儲過程來執行更新，代替用VFP建立一個查詢。當然，採用存儲過程的不利因素是不能使用VFP 的自動更新控制碼來更新資料。

參數化設置 Parameterization
通過學習，你已經知道如何爲 CursorAdapter 類的方法、屬性添加命令。基本上，在類中使用的每個事件（event)都有一組before和after方法, 比如 BeforeUpdate 和 AfterUpdate 。然而,沒有 BeforeSelect 或 AfterSelect－替代它們叫做 BeforeCursorFill 和 AfterCursorFill,因爲游標是用 SelectCmd 的結果來填充的。
BeforeCursorFill 方法接受三個參數, 而且返回 Boolean 值。第一個參數 , lUseCursorSchema, 敍述 CursorSchema 屬性是否控制游標的結構。第二個參數 , lNoDataOnLoad,與視圖的 NODATA 子句類似,只取回表結構，但是沒有從資料源取回資料。

對於現在的討論 , 第三參數 , cSelectCmd,是最有意思的。我們已經提到過它 (象 BeforeUpdate 的 cUpdateInsertCmd 參數) ，先使用 SelectCmd 的當前設置。然而，如果你改變這一個參數的值,它不改變 SelectCmd 屬性的值；取而代之的是，它的值改爲被傳給資料源的語句。

舉例來說, 假如你已經把 CursorAdapter 物件的 SelectCmd 設定爲下列代碼:

SELECT CustomerID, CompanyName, ContactName, City,
Region, Country FROM Customers
在呼叫 CursorAdapter 的 CursorFill 方法之前， BeforeCursorFill 方法的 cSelectCmd 參數會包含這個語句。假如你在這一個方法中用下列代碼:
cSelectCmd = cSelectCmd +
" WHERE CompanyName LIKE '" +
this.cCompanyName + "%'"
這就導致實際的select命令總是包含如上面代碼描述的where子句和 this.cCompanyName（自定義屬性）的當前值.因爲它不改變 SelectCmd 的初始值, 你不必用任何特別的代碼來確定在select命令中是否包含兩個where子句。

參數設置第二部分
如果你以前用過視圖，或 SQL pass through,那麽你可能熟悉在參數前使用 "?" 字元。這一個用法也適用於 CursorAdapter 。下面的代碼例子告訴你如何在 CursorAdapter 的 SelectCmd 屬性中使用參數:

This.SelectCmd = "SELECT * FROM Customers " +
" WHERE CompanyName like ?lcMyVar "
lcMyVar = 'C%'
This.CursorFill()
最要緊的是確定變數 "lcMyVar" 在 CursorFill 方法被請求之前被定義。否則的話，VFP會提示找不到值,使用者會無所適從。

你可以使用 CursorAdapter 的屬性作爲參數,用來替代本地的變數。這樣做有這樣的優點：只要物件存在，屬性也會存在，而且你可以通過使用access/assign方法來確定分配的值符合規則。

使用存儲過程
在上面說過, 使用儲存過程是一個突破錯誤處理限制的好辦法。讓我們逐步探究在ODBC CursorAdapter中使用存儲過程的方法。這樣我們就能感覺出手動處理 CursorAdapter 類的更新錯誤是多麽複雜。
這一段是關於通過調用資料源的存儲過程來代替自動執行的update、insert和delete命令。這意味著你必須處理 UpdateCmd ， InsertCmd 和 DeleteCmd 屬性, 而且假設 SQL server上的 Northwind 資料庫已經建立存儲過程來提供這些功能。

例子, 讓我們看一看一個簡單存儲過程的完整代碼，你可以用它更新 Northwind 資料庫的customer表的 ContactName 欄位:

--T-SQL code, not VFP
CREATE PROCEDURE UpdateCustomerContact (
@CustomerID nchar (5),
@ContactName nvarchar (30),
@oldContact nvarchar (30)
)
AS
IF @CustomeriD IS NULL
RAISERROR('CustomerID is a required parameter',16,1)
ELSE
UPDATE Customers
SET ContactName = @contactName
WHERE CustomerID = @customerID
AND ContactName = @oldContact
爲了節約空間,這一個存儲過程沒有包含全部的錯誤處理代碼。不管這個,已經有足夠的代碼來說明怎樣在 CursorAdapter 類中執行更新。

幸運地, 建立 UpdateCustomerContact 存儲過程作爲更新命令，可以取代 BeforeUpdate 方法，用下面的代碼:
LPARAMETERS cFldState, lForce, nUpdateType,
cUpdateInsertCmd, cDeleteCmd
cUpdateInsertCmd =
"EXECUTE UpdateCustomerContact '" +
EVALUATE(this.Alias+".CustomerID") + "','" +;
ALLTRIM(EVALUATE(this.Alias+'.ContactName'))+
"','" +
OLDVAL('contactname',this.Alias)+"'"
這裏,代碼放在 cUpdateInsertCmd 參數裏,覆蓋了默認的update命令。我使用了evaluate函數，是爲了cursor的名字是動態的，說明cursor的名字可以很容易被改變，但是代碼不變。還有，我使用了OLDVAL 函數取回 ContactName 欄位被修改前的值。如果在存儲過程的where子句裏需要舊的資料，那麽這個函數是必需的。這有點像自動産生update的情況。
記住，在記錄被實際更新之前 ,通過TableUpdate自動呼叫 BeforeUpdate 方法。因此, 無論UpdateCmd當前的值是什麽，這個方法程式（指UpdateCmd）被禁用，而且總是使用存儲過程。

注意，你也可以使用已經討論過的參數設置方法，使用 BeforeUpdate 方法。這就要求你爲 CursorAdapter 提供 UpdateCmd設置,但是, 不要在參數裏用固定的代碼，要用變數或者屬性，並在它們前面加上“？”。

在這裏需要注意的重要的一點是 cUpdateInsertCmd( 或物件的 UpdateCmd屬性) 不能返回任何值。進一步說，如果你從存儲過程返回一個值，它就沒有地方 "去" ，那麽這個值就會永遠丟失。因此,在存儲過程中添加一個RaisError呼叫，以便在更新過程中發生任何錯誤( 例如不正確的參數或一個更新衝突) 的時候，你的代碼能夠作出反應，這樣做是非常重要的。你可以通過測試 TableUpdate 返回值來捕獲錯誤 ,或者用 AError 方法, 然後分析錯誤。

相似的代碼也應該寫進 BeforeInsert 和 BeforeDelete 方法,以便它們也調用存儲過程，而不是調用設置好的“查詢”。爲了節約空間，我將留下代碼當做 "讀者的練習."

CursorAdapter with OLE DB
我們的下一個任務是看看如何通過 CursorAdapter 類使用OLE DB（物件連接與嵌入）, 並且把它同我們用過的native和ODBC作一比較。OLE DB技術比ODBC有更多的處理能力, 而且能夠連接的資料源類型比ODBC多。 CursorAdapter 通過嵌入ADO物件使用OLE DB，這是OLE DB技術標準的 COM 封裝。 VFP 會自動地把ADO記錄集轉換成一個 VFP 游標, 以及處理更新, 正如在早先的例子中講到的一樣。

第一件要做的事,當然還是建立一個新的 CursorAdapter 類，我們用代碼建立一個。

開始建立一個新的程式，取名字 caADO.prg, 把下列代碼添加進去:

PUBLIC goCAADO as CursorAdapter
goCAADO = CREATEOBJECT('caADO')
BROWSE
DEFINE CLASS caADO AS CursorAdapter
oConn = NULL
oRS = NULL
Alias = "cCustADO"
DataSourceType = "ADO"
SelectCmd = "SELECT " +
"CustomerID, CompanyName, ContactName, "+;
"ContactTitle, Address, City, Country "+;
"FROM Customers WHERE Customerid LIKE 'C%'"
FUNCTION Init()
This.DataSource = this.oRS
This.oRS.ActiveConnection = this.oConn
This.CursorFill()
ENDFUNC
ENDDEFINE
在這段代碼中，我們將 DataSourceType 設爲ADO而且把我們對Customers的查詢加入 SelectCmd 。當 DataSourceType 是ADO的時候, DataSource 屬性必須包含有效的 RecordSet 或命令物件, 這依賴於你如何使用 CursorAdapter。如果你不使用參數化查詢 (就象前面例子中講到的用 "?")那麽你可以用記錄集( RecordSet )；否則，你必須使用命令物件,因爲ADO已經代替了參數選擇。你的查詢中的任何參數在命令物件中自動地被處理。

在這種情況下，我們使用 RecordSet 物件 , 但是應該注意我們必須提供一個“連接”物件。在這兩種情形中，我使用Access方法建立了關於這些物件的參考。 list3 中是Access方法的代碼。

兩個Access方法首先檢查物件是否已經被建立。如果沒有，那麽就繼續創建物件。在使用 RecordSet 的情形，你只需要建立物件,剩下的由 CursorAdapter 來做。用“連接”物件的情況下，你必須提供連接字串（連接控制碼）並且打開連接，因爲CursorAdapter 不爲你打開連接。這是因爲“連接”不是 CursorAdapter 的一個屬性, 而是 RecordSet 物件的一個屬性。
下一次發：用OLE DB更新

用OLE DB更新
如果不另外設定幾個屬性，這麽簡單的 CursorAdapter 是沒有更新能力的。把下面的代碼放在定義類(define)的代碼中，在init方法之前運行，將會允許自動更新:

KeyFieldList = "CustomerID"
UpdatableFieldList =
"CompanyName, ContactName, ContactTitle, "+
"Address, City, Country"
UpdateNameList =
"CustomerID Customers.CustomerID, " +
"CompanyName Customers.CompanyName, " +
"ContactName Customers.ContactName, "+;
"ContactTitle Customers.ContactTitle, " +
"Address Customers.Address, "+;
"City Customers.City, Country Customers.Country"
Tables = "Customers"
然而， RecordSet 會建立它的默認的 CursorLocation 和 CursorType 屬性。如果不改變這些屬性設置， RecordSet 最初是唯讀的,因此，你需要按以下方法修正 oRS_Access 方法:
FUNCTION oRS_Access() as ADODB.RecordSet
LOCAL loRS as ADODB.RecordSet
IF VARTYPE(this.oRS)<>"O" THEN
this.oRS = NULL
loRS = NEWOBJECT("ADODB.Recordset")
IF VARTYPE(loRS)="O" THEN
loRS.CursorType= 3 && adOpenStatic
loRS.CursorLocation = 3 && adUseClient
loRS.LockType= 3 && adLockOptimistic
this.oRS = loRS
ENDIF
ENDIF
RETURN this.oRS
ENDFUNC
爲 RecordSet 加上這些代碼以後， CursorAdapter 就能處理自動更新了。
下一次發cursoradapter with XML

CursorAdapter with XML
最後, 讓我們建立使用XML作爲資料源的 CursorAdapter。這一節很有趣,因爲XML文本不像通常的資料源。同樣，當資料源設置爲XML的時候， CursorAdapter 不會自動建立 SQL 更新, 插入或刪除命令。因此，這種類型的 CursorAdapter 需要大量的代碼接收和更新資料。

在這一個例子中，我將使用 SQL server 2000 的 SQLXML 提供XML文本。同時，因爲SQLXML支援通過XML更新，我們將花一點時間寫必要的代碼來執行更新。假設你已經配置了SQLXML，允許HTTP資料存取Northwind 資料庫,而且允許用 UpdateGrams 對資料庫進行更新。

在這裏，我在 IIS 上面設置使用一個被稱爲 "nwind" 的虛擬目錄存放 HTTP 資料。因此，我的全部例子將會包含這個網址：
http://localhost/nwind，經由 IIS 存取 SQLXML。
讓我們開始建立一個新的程式，程式名字爲caXML.prg，用下列代碼（創建一個類）:
PUBLIC oCAXML as CursorAdapter
SET MULTILOCKS ON && need for table buffering
oCAXML = CREATEOBJECT('xcXML')
BROWSE NOWAIT
DEFINE CLASS xcXML AS CursorAdapter
DataSourceType = "XML"
Alias = "xmlCursor"
UpdateCmdDataSourceType = "XML"
InsertCmdDataSourceType = "XML"
DeleteCmdDataSourceType = "XML"
BufferModeOverride = 5
*custom properties
oXMLHTTP = NULL
oXMLDOM = NULL
cServer = "localhost"
cVDir = "nwind"
ENDDEFINE
不同於通常的 DataSourceType 和Alias（別名）屬性設置，這是我們第一次看見 xxxCmdDataSourceType 屬性。因爲這是一個XML類型的 CursorAdapter,如果你想讓它用來更新源資料，這些屬性就必須進行設置。推薦在這個類中使用 oXMLHTTP 和 oXMLDOM 屬性，將會在下面做詳細說明。

接收XML資料
在考慮 CursorAdapter 的更新能力之前,我們先研究怎樣從SQLXML 伺服器接收文本。首先,一個簡單的select命令不能工作,我們必須建立通用的 SelectCmd 。這在 Init 方法中很容易做到,同時，在INIT中調用 CursorFill 方法,如以下代碼:
FUNCTION INIT() as Boolean
LOCAL llRetVal, lcMsg, laErr[1]
this.SelectCmd = "this.GetXml()"
llRetVal = THIS.CursorFill()
IF NOT llRetVal THEN
AERROR(laErr)
lcMsg = "Cursor was not filled!"
IF NOT EMPTY(laErr[2]) THEN
lcMsg = lcMsg + CHR(13) + laErr[2]
ENDIF
MESSAGEBOX(lcMsg,16,"XMLCursorAdapter Test")
ENDIF
RETURN llRetVal
ENDFUNC
這一段代碼建立 SelectCmd 作爲本地用的方法,代替 SQL 命令。以前的例子中沒有這樣做過,對任何 CursorAdapter 類,不管什麽類型,都是合法的。然而，當你使用一個本地的方法作爲 SelectCmd 的時候,你必須也提供代碼用來更新,插入和刪除, 因爲如果不是一條SQL語句的話， VFP 是不會自動處理的。
當我們在 Init() 中使用 CursorFill 的時候,GetXML 方法被調用。資料源設定爲XML的時候,GetXML 方法必須返回只包含一個表的最終文本。如果它包含多個表,你會得到料想不到的結果。 GetXML 方法在list4 中列示。

GetXML開始於提交一個 MSXML2.XMLHTTP COM 物件。這個物件處理所有 HTTP 通信,包括發送請求到伺服器並且返回結果。你可以看到,oXMLHTTP 實例物件是被設計好的Access方法控制的，這樣設計是爲了防止連續地創建和破壞 COM 伺服器。
然後，你可以看到我們的典型的SELECT描述, 除了LIKE子句有點稍稍不同以外。 HTTP 需要我們當十六位元百分比字元顯示到達25％的時候退出顯示（指進度顯示），在 SQL server接收查詢之前 , 這個值將會變成單一的百分比符號。

然後，代碼用具體的查詢要求來設置URL，並且通過HTTP發送URL到SQL SERVER伺服器。SQL SERVER接收到這個查詢，並且處理它，以XML方式返回值。這是因爲我們已經在“查詢”中包含了FOR XML子句。在這個例子中，XML的根元素叫做 "results" 。你從查詢字串中可以看出。這是按照你的習慣配置的。

此時， lcRetXML 包含一個來自 SQL server的XML資料流程。既然 GetXML 方法被 VFP 作爲 SelectCmd 調用，你可以從 GetXML 方法中返回這個變數的內容，而且 VFP 將會把資料流程轉換成一個 VFP 游標。你可以通過執行 caXML 程式測試。會出現一個包含返回的XML文本內容的瀏覽窗戶。使用調試工具一步一步查看 GetXML 方法，可以看到在被轉換到一個 VFP 游標並釋放之前 , lcRetXML 變數的值是XML文本。

更新XML資料
下一個步驟是決定該如何使這個游標可更新，以便所作的更改能被發送回 SQLXML 伺服器。 SQLXML 能使用一個特別的XML文本,即 UpdateGram, 利用它直接把更新發送到資料庫。在 VFP7 中，可以用 XMLUpdateGram 函數建立這個文本。用VFP 8 的 CursorAdapter ， UpdateGram 屬性會自動建立。

第一個步驟是設置 updatable 屬性並且建立一個更新指令。在類定義的開始設置這些屬性，並在CursorAdapter的init事件中增加一行代碼，提供調用更新命令的方法。
KeyFieldList = 'customerid'
Tables = 'customers'
UpdatableFieldList =
"companyname, contactname, contacttitle, "+;
"address, city, country "
UpdateNameList=
"customerid customers.customerid, " +
"companyname customers.companyname, " +
"contactname customers.contactname, " +
"contacttitle customers.contacttitle, " +
"address customers.address, " +
"city customers.city, country customers.country"
FUNCTION INIT() as Boolean
LOCAL llRetVal, lcMsg, laErr[1]
this.UpdateCmd = "this.UpdateXML()"
this.SelectCmd = "this.GetXML()"
** balance of code skipped...
注意，我們已經在init方法中替換了屬性表中的 UpdateCmd 和 SelectCmd 設置，實際上最終結果是一樣的。不管怎樣, 這一段代碼的第一部份現在看起來很熟悉，在這裏我們設置了 KeyFieldList ，table， UpdatableFieldList 和 UpdateNameList 屬性。沒有這些屬性設置，就不可能創建 UpdateGram 。

然後，我們建立 UpdateXML 方法作爲 CursorAdapter 的 UpdateCmd 。沒有參數傳遞給 UpdateXML 方法,所以，所有決定更新的工作必須這個方法裏處理。還有，因爲XML 類型的 CursorAdapter 沒有默認的更新機制, 你必須寫代碼把更新傳遞給XML資料源。

在這一段代碼中，使用 XMLHTTP 物件傳遞更新到伺服器。通過LoadXML方法載入 UpdateGram 屬性的內容到 XMLDOM( 在ACCESS方法中) 之內,打開到伺服器的連接,設定請求的內容爲XML, 然後發送 XMLDOM。所有的結果通過 XMLHTTP 物件的 ResponseText 屬性返回,接著裝載到 XMLDOM 中，並且分析錯誤資訊。

如果沒有提示錯誤,更新已經成功，而且過程結束。然而，如果有錯誤, 就會産生符合語法的錯誤資訊文本，並且包含在一個自定義的ERROR函數中，這樣 TableUpdate 函數就能找到更新失敗的原因。如果沒有這些代碼，即使有問題的時候，TableUpdate 總是返回成功資訊。

測試一下這段代碼,運行 caXML 程式,在游標中更改一個欄位, 然後在命令視窗中發出 TableUpdate。如果 TableUpdate 成功, 你應該能在伺服器上看到更新結果。如果 TableUpdate 失敗,你需要用 AError 函數接收 SQL server産生的錯誤資訊。
如果你對 UpdateGram 的內容感到好奇, 你可以一步步查看類的 UpdateXML 方法，並且查看 UpdateGram 屬性的內容。然而，如果你不到有關資料變化的方法中 (如 UpdateCmd ， InsertCmd 或 DeleteCmd 屬性內容) ,你也不能完全弄明白 UpdateGram 屬性的內容。

list6顯示當ContactName欄位的客戶ID被更改爲‘CACTU' 後UpdateGram的內容。

正如你看到的，SQLXML 能夠讀取這個文本並且能夠很容易地建立一個Update-SQL 語句, 然後發送到 SQL server。 updg:sync（同步更新）元素使更新立即發生；因此，如果你有多個表需要更新,你可以把它們關聯起來放到一個 UpdateGram中, 確定把他們封裝進這個元素，執行一次就可以全部更新。
結束語
在這一篇文章中，我們涉及了許多方面，講了新的 CursorAdapter 類的四種表現形式。你已經學到了如何通過 DataEnvironment 、 CursorAdapter buileder、類設計器、和PRG建立 CursorAdapter 。你也已經瞭解了建立本地、ODBC、OLE DB或XML型 CursorAdapter 類的基本方法, 並且怎樣使這些類可更新。

下一個步驟是考慮如何把這些類應用到你的程式中。對我來說，覺得 CursorAdapter 應用到任何程式的 UI 層中效果很好,同時應用於需要大量過程代碼的許多商業開發。CursorAdapter並不是一個最好的選擇物件用於層來傳遞資料。因爲它把所有的來自資料源的資料轉化成一個不便於攜帶的游標。

然而，在一個使用 CursorAdapter 類進行商業開發的方案中，它能接收來自資料源的資料, 然後用標準的 VFP 命令和函數處理資料,這是因爲它産生的是一個 VFP 游標。資料可以被轉換爲更一個較適當的類型,例如XML。

CursorAdapter 的另一個有利條件是通用的 OOP 介面,不管需要存取的資料是什麽類型。甚至用XML,需要大量代碼來使類可更新,我們仍然可以用使用 CursorFill取回資料，用 TableUpdate 更新資料, 而且用 AError 返回錯誤, 像使用其他類型的 CursorAdapter一樣。

基於一個事先的考慮或者計劃，你想建立一個可以重復使用的CursorAdapter類。這些類可以在程式之間重復使用或者在同一程式內部混合使用，來形成一種你的程式處理資料的標準方法。

==========================================

有網友問使用cursoradapter是否還需要tableupdate(),下面索性再發一篇文章：
如何通過 CursorAdapter 物件使用 TableUpdate 函數更新資料
這一篇文章適用於:vfp 8.0
摘要:
這一篇文章討論下列各項主題:
1、TableUpdate 交互地使用 CursorAdapter 類更新後端資料。
2、使用vfp 8.0 的新 CursorAdapter 類通過TableUpdate 函數更新資料的時候如何處理更新衝突。
較多的資訊：
可以通過vfp 8.0 的 CursorAdapter 類取回來自本地的或遠端的資料源的資料。默認情況下，CursorAdapter 産生的游標不更新後端資料。爲了要更新後端資料,必須設定 CursorAdapter 的下列各項屬性值:
InsertCmd
UpdateCmd
DeleteCmd
如果你不設定這些屬性值,你能通過設定下列各項 CursorAdapter 屬性值自動地産生後端 SQL 更新指令:
tables
KeyFieldList
UpdatableFieldList
UpdateNameList
SendUpdates
處理更新衝突
當你使用 CursorAdapter更新後端資料的時候, TableUpdate 函數返回 CursorAdapter 游標的更新結果。如果一個更新衝突發生,後端資料的更新不可能成功。然而, TableUpdate 可能仍然返回更新成功,因爲在 CursorAdapter 游標中的資料被更新。

更新衝突是指，使用者試圖編輯一條取回後已經發生改變的記錄。下列各項是更新衝突能發生的情況:
1. User1 打開由客戶表建立的一個游標（cursor)。
2. User2 更新第一條記錄而且提交更新。
3. User1 更新第一條記錄(使用 TableUpdate() 函數).

此時， User1 有一個更新衝突: User1 正在嘗試更新的後端記錄在被取回之後已經發生改變。
DataSourceType 代碼示例：
下列示例代碼使用vfp 8.0 的native DataSourceType 更新 SQL server Northwind 資料庫的一筆記錄。查證是否記錄被更新,在更新命令中附加下列代碼:
CRLF+[EXECSCRIPT+(" if _tally=0"+CHR(10)"+error ('update conflit')"+CHR(10)+"ENDIF")]
在這種情況下,Tableupdate() 返回 (.F。 ) 而且允許你處理更新失敗。
#DEFINE CRLF CHR(13)+CHR(10)
Local loCursor,ovfp
CLEAR

ON ERROR

Set Exclusive Off
Close Databases All
Set Multilocks On
loCursor = Createobject('CA')
* Load loCursor with the data specified in SelectCmd and display error message if error occurs.
loCursor.CursorFill()
GO top
* Display the value of the company name before update.
? "Before:",companyname
?
ovfp=Createobject("visualfoxpro.application.8")
ovfp.DoCmd("set exclusive off")
ovfp.DoCmd("update (_samples+'\northwind\customers') set companyname='Alfreds Futterkisted' where customerid='ALFKI'")
GO top
* Update the data in the cursor.
replace companyname WITH 'Alfreds Futterkiste'
* Update the back end.
retval=TABLEUPDATE(0,.F.,locursor.alias)
Messagebox("Tableupdate="+Transform(retval))

* If update conflict occurs, display the error.
if(retval=.F.)
LOCAL ARRAY errors(1)
AERROR(errors)
* Displays the errors.

IF "Update conflict"$errors[2]
MESSAGEBOX("Update Conflict-reverting changes")
=TABLEREVERT(.T.,locursor.alias)
ENDIF
endif
* Refresh the Cursor to get the updated data.
loCursor.CursorRefresh() && Get the data again to be sure
GO top
* Display the value of the company name after update.
?
? "After:",companyname

Define Class CA As CursorAdapter
Alias = 'test1'
DataSourceType = 'NATIVE'
SelectCmd = 'select * from (_samples+"\northwind\customers")'
Tables = 'Customers'
KeyFieldList = "customerid"
UpdatableFieldList = "companyname"
UpdateNameList = "customerid customers.customerid,companyname customers.companyname"
WhereType= 3
* This is a custom property, that is added to handle update conflicts. It does not do
* anything by itself. It is added below to the automatically-generated UpdateInsertCmd to
* test whether anything was actually updated.
ConflictCheckCmd =CRLF+[EXECSCRIPT("IF _tally=0" + CHR(10) + "ERROR('Update conflict')" + CHR(10) + "ENDIF")]

Procedure AfterUpdate
Lparameters cFldState, lForce, nUpdateType, UpdateInsertCmd, DeleteCmd, lResult
* To see why it will fail on the back end, look at the UpdateInsertCmd that is used
? "Update Command sent="+UpdateInsertCmd
* Swap the actual values in the command to see what occurred.
UpdateInsertCmd=Strtran(UpdateInsertCmd,[OLDVAL('customerid','test1')],Oldval('customerid','test1'))
UpdateInsertCmd=Strtran(UpdateInsertCmd,[OLDVAL('companyname','test1')],Oldval('companyname','test1'))
UpdateInsertCmd=Strtran(UpdateInsertCmd,[test1.companyname],test1.companyname)
? "With the OLDVAL() and test1.companyname evaluated the update statement is :"+UpdateInsertCmd
* Check tally.
? "Tally="+Transform(_Tally)

Procedure BeforeUpdate
Lparameters cFldState, lForce, nUpdateType, cUpdateInsertCmd, cDeleteCmd
cUpdateInsertCmd=cUpdateInsertCmd+this.ConflictCheckCmd

ENDDEFINE
使用SQL server DataSourceType的示例代碼：
下列代碼使用 SQL server DataSourceType 更新 SQL server Northwind 示例資料庫的一筆記錄。查證記錄是否被更新,把下列代碼加入更新指令:
IF @@ROWCOUNT=0 RAISERROR (' Update
conflict.', 16, 1)
在這種情況下，Tableupdate() 返回 (.F。 ) 而且允許你處理更新失敗。
LOCAL loCursor,ovfp,nhnd,lsuccess

CLEAR
SET EXCLUSIVE OFF
CLOSE DATABASES ALL
SET MULTILOCKS ON

loCursor = CREATEOBJECT('CA')

* Load loCursor with the data specified in SelectCmd and display error message if error occurs.
IF !loCursor.CursorFill()
=AERROR(lar)
MESSAGEBOX(lar[2])
ENDIF

* Display the value of the company name before update.
? "Company Name Before Update:",companyname
?
* Create a connection handle for SQL Server so you can set up the update conflict.
nhnd=SQLSTRINGCONNECT([Driver=SQL Server; SERVER=<SQL SERVER NAME>; DATABASE=NORTHWIND])
=SQLEXEC(nhnd,[update customers set companyname='Alfreds Futterkiste' where customerid='ALFKI'])
=SQLDISCONNECT(nhnd)

* Now make a change to the local data, and then try to update it.
GO TOP
REPLACE companyname WITH 'Alfreds Futterkisted'

lsuccess=TABLEUPDATE(0,.F.,locursor.alias)
Messagebox("Tableupdate="+Transform(lsuccess))
* Error handling function. Displaying the error message if update conflict occurs.
IF !lsuccess
=AERROR(lar)
IF "Update conflict"$lar[2]
MESSAGEBOX("Update conflict!-Reverting changes")
=TABLEREVERT(.f.,locursor.alias)
ENDIF
ENDIF

* Get the current data from the CursorAdapter.
loCursor.CursorRefresh()
GO TOP

* Displaying the value of the company name after update.
?
?"Company Name After Update:", companyname

DEFINE CLASS CA AS CursorAdapter
Alias = 'test1'
SelectCmd = 'select * from customers'
Tables = 'Customers'
KeyFieldList = "Customerid"
UpdatableFieldList = "companyname"
UpdateNameList = "customerid customers.customerid,companyname customers.companyname"
WhereType= 3 && Key and modified

* This is a custom property that is added to handle update conflicts. It does not do
* anything by itself. It is added below to the automatically-generated UpdateInsertCmd to
* test whether anything was actually updated.
ConflictCheckCmd =";IF @@ROWCOUNT=0 RAISERROR (' Update conflict.', 16, 1)"

* Initializing the connectivity to Data source (SQL Server) by using ODBC driver.
PROCEDURE init
WITH THIS
.DataSourceType = 'ODBC'
.DataSource=SQLSTRINGCONNECT([Driver=SQL Server; SERVER=<SQL SERVER NAME>; DATABASE=NORTHWIND])
ENDWITH
ENDPROC

PROCEDURE BeforeUpdate
LPARAMETERS cFldState, lForce, nUpdateType, cUpdateInsertCmd, cDeleteCmd

? "Entering BeforeUpdate()"

cUpdateInsertCmd=cUpdateInsertCmd + THIS.ConflictCheckCmd
ENDPROC

PROCEDURE AfterUpdate

LPARAMETERS cFldState, lForce, nUpdateType, UpdateInsertCmd, DeleteCmd, lResult

* To see why it will fail on the back-end, look at the UpdateInsertCmd that is used.
? "Update Command sent="+UpdateInsertCmd

* Swap the actual values in the command to see what occurred.
lcActualCmd =Strtran(UpdateInsertCmd,[OLDVAL('customerid','test1')],Oldval('customerid','test1'))
lcActualCmd =Strtran(UpdateInsertCmd,[OLDVAL('companyname','test1')],Oldval('companyname','test1'))
lcActualCmd =Strtran(UpdateInsertCmd,[test1.companyname],test1.companyname)

? "With the OLDVAL() and test1.companyname evaluated the update statement is :"+UpdateInsertCmd
?
? "Leaving AfterUpdate()"
ENDPROC

* Destroying the connection.
PROCEDURE destroy
=SQLDISCONNECT(THIS.DataSource)
ENDDEFINE

注意：這種更新方式(如這一段代碼所示的)不支援批量更新。 (例如,cursoradapter.batchupdatcount>1) 。使用批量更新的時候,下列各項事件不動作:
BeforeInsert
AfterInsert
BeforeUpdate
AfterUpdate
BeforeDelete
AfterDelete
三考
更多的資訊,vfp8幫助中的下列各項主題。
“CursorAdapter Object Properties, Methods, and Events"
"Data Access Management Using CursorAdapters"
"Detecting and Resolving Conflicts"
"Locking Data"
"Management of Updates with Views"
"Programming for Shared Access"

=============================
vfp8自帶的cursoradapter幫助：
用 Visual FoxPro,可以用cursor adapters接收支援以下資料源類型的本地或遠端資料:
• 本地的
• 開放式資料源連接(ODBC)
• ActiveX 資料物件 (ADO)
• 擴展標記語言 (XML)
Cursoradapter 類爲不同的資料源類型作爲本地臨時表使用提供支援. Cursoradapter 物件具有以下功能:
• 靈活地使用不同的資料源.
• 使用 Cursoradapter物件資料源或者資料環境 .
• 在資料源限制範圍內分享資料.
• 隨意定義Cursoradapter 物件生成的臨時表的表結構.
• 控制 Cursoradapter 物件生成的臨時表的資料裝載.
• 從不同資料源生成基於資料源類型的Visual FoxPro 臨時表.
• 用 Cursoradapter 屬性和方法控制怎樣添加、更新、刪除資料.
• 除數據環境以外，添加 Cursoradapter 物件到表單、表單集和其他容器.
• 用 Cursoradapter 類作爲單獨的、無數據環境的類.
對 Cursoradapter 物件來說,資料源只是一個翻譯層，它從資料源獲取資料生成 Visual FoxPro 臨時表.
注意： Visual FoxPro 不支援Cursoradapter 物件建立連接關係. 但是, 可以在生成的臨時表之間建立連接關係.
想瞭解更多 Cursoradapter, 資料環境, 和游標類的資訊,請看： Cursoradapter Class, DataEnvironment Object, 和 Cursor Object.
用TABLEUPDATE()和TABLEREVERT()函數實現資料互動
TABLEUPDATE( ) 函數能夠識別並且用 Cursoradapter 物件工作. TABLEUPDATE( ) delegates its operations to the cursor adapter associated with the cursor. TABLEREVERT( ) operates on Cursoradapter objects in the same way as other buffered cursors.
想瞭解更多的 Cursoradapter 物件怎樣影響TABLEUPDATE( ) 和 TABLEREVERT( ) 函數的行爲, 請查看 TABLEUPDATE( ) Function 和
TABLEREVERT( ) Function.
Automatic Updating and Cursoradapters
Visual FoxPro在本地和遠端視圖中自動産生 SQL INSERT, UPDATE, 和 DELETE 命令. 用 Cursoradapter 物件,可以指定、控制Visual FoxPro 怎樣操作SQL INSERT, UPDATE, 和 DELETE 命令.
當 Cursoradapter InsertCmd, UpdateCmd, 和 DeleteCmd 屬性爲空的時候， Visual FoxPro 自動産生標準的SQL命令. 你必須確定那些自動産生的命令是否適合使用的資料源.要自動産生SQL INSERT, UPDATE, 和 DELETE 命令,你必須設定下面的 Cursoradapter特定屬性:
• Tables
• KeyFieldList
• UpdatableFieldList
• UpdateNameList
Tables 和 UpdateNameList 屬性要符合以下規則:
• Tables
如果允許自動更新,必須按順序列出希望在 SQL INSERT, UPDATE, 和 DELETE 命令中顯示的表的名稱.
• UpdateNameList
• 必須指定一個包含成對出現的、本地和完整的遠端資料欄位的列表，用分號分隔。沒一對欄位名中，本地的在前，遠端的在後。完整的遠端欄位名應該這樣寫：<遠端表名>, <遠端欄位名>, <遠端表名> 必須和Tables 屬性中的名字一致.
如果你設置以下Cursoradapter 的屬性爲 True (.T.)，必須指定關鍵欄位:
• AllowInsert
• AllowUpdate
• AllowDelete
你想瞭解更多關於SQL 的自動更新命令,請看 INSERT - SQL Command, UPDATE - SQL Command, 和 DELETE - SQL Command.
批量更新（Batch Updates）
如果 Cursoradapter BatchUpdateCount 屬性的值大於1, Cursoradapter 物件使用批量更新。同時必須具備以下條件:
• Cursoradapter 物件設置爲所有允許的操作使用相同的ODBC連接，包括AllowInsert, AllowUpdate, 和 AllowDelete屬性中設置的INSERT，UPDATE,和DELETE操作。.
• Cursoradapter 物件設置爲所有允許的操作使用相同的ADODB 命令物件。
• Cursoradapter 物件所有被允許的操作使用 "XML" 作爲資料源。
如果使用批量更新, 下列 Cursoradapter 事件不發生：
• BeforeInsert
• AfterInsert
• BeforeUpdate
• AfterUpdate
• BeforeDelete
• AfterDelete
如果批量更新失敗, Visual FoxPro 嘗試在該批資料中的每一行發送一個分散的更新，然而，列舉的事件不會發生。
更多的相關資訊, 參見 BatchUpdateCount Property.
自動更新（Automatic Updating）和 ActiveX Data Objects (ADO)
用 ADO工作的時候, 可以用兩種辦法發送更新:
• 使用 Cursoradapter 物件，通過在Cursoradapter CursorFill 方法中使用 ADO 記錄集物件發送更新
• 當使用 ADO記錄集執行自動更新的時候, 設置ursorAdapter InsertCmdDataSource, UpdateCmdDataSource, 和 DeleteCmdDataSource 屬性的時候，必須遵循下列規則:
• ADO記錄集必須是可讀寫的並且標記爲可用。
• 當使用用戶端記錄集物件的時候，書簽必須總是可用。
• Bookmarks might be available when using Keyset or Static server-side cursors when supported by the OLE DB Provider.
• 按照一個欄位一個欄位的規則進行更新.更新完一條記錄以後， Cursoradapter 物件在ADO記錄集中尋找原始記錄t, 用來改變可更新欄位的值, 並且調用ADO記錄集的update方法。 Cursoradapter 物件不調用ado記錄集的updatebatch方法，因此, 你的程式需要在恰當的時候明確地調用 UpdateBatch方法。
當使用這個方法程式的時候, 需要按以下方法設置 Cursoradapter 物件:
THIS.DataSourceType="ADO"
THIS.UpdateCmdDataSourceType=""
可以用資料環境（DataEnvironment）和 Cursoradapter builders 來建立一個可更新的表單，或者使用資料環境 DataEnvironment 和 Cursoradapter 類庫，或者在Cursoradapter Builder中使用 AutoUpdate tab 制定一個主關鍵欄位,更新欄位,或者其他要求的資訊。
• 通過一個自定義的或者自動産生的命令，通過 Cursoradapter 物件向資料庫直接發送一個更新。
• 當執行自動直接更新, Cursoradapter 物件需要一個 ADO物件，其 ActiveConnection 屬性設置成開放的ADO連接模型。
• 用這種方法的時候, 需要用以下方法設置Cursoradapter物件 :
THIS.UpdateCmdDataSourceType="ADO"
THIS.UpdateCmdDataSource=NewADODBCommandObject
在這個方法裏不推薦使用 THIS.DataSourceType="ADO" 。
自動更新和 XML
Cursoradapter 物件使用XML資料源時，不自動産生SQL INSERT, UPDATE, 和 DELETE命令，因爲已經存在好多産生XML的手段。然而,可以使用Cursoradapter 物件産生一個 XML UpdateGram ，放在 Cursoradapter UpdateGram 屬性.
儘管Cursoradapter 物件能産生XML UpdateGram, 你必須使用恰當的協定來實現最終更新。例如，SQL XML（HTTP）, SQL XML OLE DB, 或者 XML Web service to .NET.
使用 XML 資料源和産生 XML UpdateGrams的時候必須遵循以下規則:
• 必須在 Cursoradapter InsertCmd, UpdateCmd, and DeleteCmd 屬性中指定具體的命令，Visual FoxPro能夠據以進行正確的插入、更新、和刪除操作。如果使用批量更新, Cursoradapter BatchUpdateCount 屬性值必須大於1, UpdateCmd 在批量中只執行一次。
• 下列 Cursoradapter 屬性必須設置爲 "XML":
• InsertCmdDataSourceType
• UpdateCmdDataSourceType
• DeleteCmdDataSourceType
如果這些屬性不設置爲"XML", Visual FoxPro 執行 UpdateCmd, InsertCmd, DeleteCmd 屬性中的命令而且不産生XML UpdateGram.
• 要想正確的建立XML 更新（UpdateGram）, Cursoradapter 需要 Tables, UpdatableFieldList, UpdateNameList 屬性中包含確定的值。 Cursoradapter 可以通過在Tables, UpdatableFieldList,和 UpdateNameList 屬性中指定恰當的名稱來産生一個多表更新。因此, 可以更新用XMLUPDATEGRAM( )函數産生的連接多個表的游標。更多的資訊,請看 XMLUPDATEGRAM( ) Function.
• Cursoradapter 使用 WhereType 屬性産生XML UpdateGram 的 before 事件。因此, 當你執行一個更新或刪除的操作時， KeyFieldList 和 UpdatableFieldList 屬性必須包含一個主關鍵欄位.更多的資訊,參見 WhereType Property.
• 如果設置了行緩衝, 或者 BatchUpdateCount 的值是1, Visual FoxPro 爲每個update, insert, delete 操作建立一個XML UpdateGram 更新。
如果設置爲表緩衝, 並且使用批量更新, 即atchUpdateCount 的值大於1, Visual FoxPro 爲全部的批量創建一個 XML更新。此種方式下, 必須使用TABLEUPDATE( ) 函數執行XML更新。

akwang · 註冊時間: 2004-11-06 文章: 24 來自: ccf 第 2 樓

这篇文章写的太好了
呵呵，不知道这种用法过时了吗？

impotence · 發表於: 星期二二月 07, 2006 12:02 pm 文章主題:

謝謝分享 ~~~