 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 1 樓
|
 發表於: 星期六 五月 21, 2005 2:50 am 文章主題: 修復損壞的 DBF 與 FPT 檔之報告書 |
 |
|
長期以來常常會遇到客戶因電腦當機或斷電而造成 DBF 或 FPT 檔損毀，在 VFP7 以下(含) 時，因為只有 FPT 會損毀 (DBF 是否有損毀就不知道了)，所以就比較用偷懶的方式：「把客戶損毀的檔案傳回來，直接由 BROWSER 開啟，藉由它會問我是否要修復損毀的 FPT 檔來將 FPT 檔修復」；雖然常常該檔損毀時所在某筆記錄上的附註欄位內容，經修復後仍會遺失掉。但跟客戶解釋後由客戶自己去重補齊資料，客戶也接受這樣的狀況，所以就一直混到現在。
但到了 VFP8 以上(含)，居然 DBF 檔也會開始損毀了，VFP8 (9 也一樣) 的 BROWSER 表現的行為就不一樣了，它不修了，就直接賞您 2091 (代表 DBF 損毀，這是 VFP8 以後才有的錯誤編號) 或 0041 (代表 FPT 損毀) 的錯誤編號給您；它不像在 VFP7 以前會先自動修復好 DBF 檔後才顯示 0041 的錯誤編號 (看樣子不願承擔修好 FPT 後的資料不見的責任)，而且只是很賤的說：「若要再次開啟以前，請先自行將它修復好後才能開啟」。
這是哪門子的事啊！在 VFP8 的環境下，初期遇到損毀的事，用 VFP6 來修還是可以免強混過，到後來雖然用 VFP6 修還是修的過來，但傳給客戶卻仍賞您損毀的狀況，這意思是說修復後的檔案用 VFP6 或 7 來開啟仍是可以開啟的，但用 VFP8 或 9 就說開不起來；客戶那裏已是 VFP8 的環境了，怎麼辦呢，後來找到很笨的方法來解決這問題，就是先用 6 來修復，然後在 6 的環境下一筆一筆的將所有記錄抄到乾淨的檔案裏；所以呢，還是可以混過去。
不過想想這樣子也不是辦法 (有時剛好很忙，又來這種事，當下會有工作壓力的)，剛好最近才將客戶的一個專案 (客戶付費) 解決掉；所以就下定決心來解決這個問題，參考各論壇相關資料及 VFP 說明檔本身提供的資訊，總算是將這個問題解決了，省了每次客戶的檔案一損毀就要趕快把它修復完畢，美其名說是服務，實則 ...。
好了，現在來說說如何修復，我只將關鍵的程式碼寫出來，其他的就只是說明 (不是我偷懶，而是這種事的處理方式會因人而異)。
在什麼情況下來做修復的動作：考慮的結果，就在發生 2091 與 0041 的錯誤當下修復。
但想想也不能就這樣默默的就將它處理掉，否則客戶哪天跟您講說他某個資料的內容突然不見了。人都是健忘的，也許初期我還會記得有可能檔案曾經損毀過，但久了或是新的同事會因不清楚有這修復機制，還以為發生了靈異事件 (或是某些人動不動就說 VFP 真爛) 而呆在那裏不知如何跟客戶解釋。
觸發機制是用 ON ERROR 命令指定一個錯誤處理函數，在該函數中攔截某些特定的錯誤編號，在 2091 與 0041 錯誤的模組中，處理步驟如下：
1.告知客戶發生了檔案損毀的訊息，詢問客戶在修復前是否要備份該檔案。此用意是告知客戶有狀況發生了，免得事後才來玩靈異事件的遊戲。
2.開始修復：
A.修復 DBF 檔，程式碼如下：
L_cDBFFileName 代表損毀的 DBF 檔，由錯誤訊息中可以得到該檔案名稱 (含完整路徑)。
| 代碼: |
W1_nHandleOfDBFFile = FOPEN(L_cDBFFileName, 2) && 以讀寫方式開啟資料表格檔
IF W1_nHandleOfDBFFile = -1
* 自行處理內容
ELSE
* 檔案長度
W1_nFileSize = FSEEK(W1_nHandleOfDBFFile,0,2)
=FSEEK(W1_nHandleOfDBFFile, 0, 0)
* 截取檔頭記錄
W1_cHeaderRecords = FREAD(W1_nHandleOfDBFFile,32)
* 原始值
W1_cHead_Reccount = SUBSTR(W1_cHeaderRecords,05,04) && 檔案中的資料記錄數目
W1_cHead_1stLocation = SUBSTR(W1_cHeaderRecords,09,02) && 第一筆資料記錄的位置
W1_cHead_RecordLength = SUBSTR(W1_cHeaderRecords,11,02) && 每筆資料記錄的長度 (包括刪除記號)
* 轉換為 10 進位制數
W1_nHead_Reccount = Word2Dec(LEFT(W1_cHead_Reccount, 2)) + Word2Dec(RIGHT(W1_cHead_Reccount, 2)) * 65535
W1_nHead_1stLocation = Word2Dec(W1_cHead_1stLocation)
W1_nHead_RecordLength = Word2Dec(W1_cHead_RecordLength)
IF W1_nFileSize < W1_nHead_1stLocation OR W1_nHead_1stLocation <= 64
* 自行處理內容
ELSE
* > 計算檔案中的資料記錄數目
W1_nCorrectRecs = (W1_nFileSize - W1_nHead_1stLocation) / W1_nHead_RecordLength
* > 修正後轉換為雙位元組(WORD)二進制字串
W1_cCorrectRecs = Dec2Word(W1_nCorrectRecs-INT(W1_nCorrectRecs/65535)*65535) + Dec2Word(INT(W1_nCorrectRecs/65535))
* > 寫入正確資訊
=FSEEK(W1_nHandleOfDBFFile,4,0)
=FWRITE(W1_nHandleOfDBFFile,W1_cCorrectRecs,4)
ENDIF
=FCLOSE(W1_nHandleOfDBFFile)
ENDIF
|
B.修復 FPT 檔，程式碼如下：
L_cFPTFileName 代表損毀的 FPT 檔，由錯誤訊息中可以得到該檔案名稱 (含完整路徑)。
| 代碼: |
W1_nHandleOfFPTFile = FOPEN(L_cFPTFileName, 2) && 以讀寫方式開啟資料表格檔
IF W1_nHandleOfFPTFile = -1
* 自行處理內容
ELSE
* > 檔案大小
W1_nFileSize = FSEEK(W1_nHandleOfFPTFile,0,2)
=FSEEK(W1_nHandleOfFPTFile, 0, 0)
* > 截取檔頭記錄
W1_cHeaderRecords = FREAD(W1_nHandleOfFPTFile,8)
* > 原始值
W1_cHead_LocationOfNextFreeBlock = SUBSTR(W1_cHeaderRecords,1,4) && 下一個自由區塊的位置
W1_cHead_BlockSize = SUBSTR(W1_cHeaderRecords,7,2) && 區塊大小
* > 轉換為 10 進位制數
W1_nHead_LocationOfNextFreeBlock = UnMSBLSB(W1_cHead_LocationOfNextFreeBlock)
W1_nHead_BlockSize = UnMSBLSB(W1_cHead_BlockSize)
DO CASE
CASE W1_nHead_BlockSize = 0
W1_nHead_BlockSize = 1
CASE W1_nHead_BlockSize = 33
W1_nHead_BlockSize = 512 * W1_nHead_BlockSize
ENDCASE
W1_cFixHeaderRecords = ToMSBLSB(INT(W1_nFileSize/W1_nHead_BlockSize),4) + CHR(0) + CHR(0) + W1_cHead_BlockSize
=FSEEK(W1_nHandleOfFPTFile,0,0) && 回到檔案開始處
=FWRITE(W1_nHandleOfFPTFile,W1_cFixHeaderRecords)
=FCLOSE(W1_nHandleOfFPTFile)
ENDIF
|
3.將修復後的狀況寫入日誌檔中，供以後查閱。
因為該睡覺了，若有問題請告知。
下列為用到的自定函數：
| 代碼: |
FUNCTION Dec2Word
LPARAMETERS lnDecNum
LOCAL lcByte1, lcByte2
lcByte1 = CHR(MOD(lnDecNum,256))
lcByte2 = CHR(INT(lnDecNum/256))
RETURN lcByte1 + lcByte2
FUNCTION Word2Dec
LPARAMETERS lcBinNum
LOCAL lnNum1, lnNum2
lcBinNum = PADR(lcBinNum, 2, CHR(0))
lnNum1 = ASC(LEFT(lcBinNum,1))
lnNum2 = ASC(RIGHT(lcBinNum,1)) * 256
RETURN lnNum1 + lnNum2
FUNCTION UnMSBLSB
* ------------------------------------------------------------- *
* 說明：。
* ------------------------------------------------------------- *
* 參數名稱 型態 說明
* ------------------------------------------------------------- *
* Input:
* L_cSomeBytes C 是由 0 到 255 的 ASCII 字元所組成的字串。
* Output:
* Mo_cRetVal N 。
* ------------------------------------------------------------- *
* 範例：
* L_cSomeBytes = "戎譚" && ascii characters from 0 to 255
*
* Mo_cRetVal = ASC(SUBSTR(L_cSomeBytes,4,1)) + ;
* ASC(SUBSTR(L_cSomeBytes,3,1)) * 256 + ;
* ASC(SUBSTR(L_cSomeBytes,2,1)) * 256 * 256 + ;
* ASC(SUBSTR(L_cSomeBytes,1,1)) * 256 * 256 * 256
* ------------------------------------------------------------- *
LPARAMETERS L_cSomeBytes
LOCAL Mo_nRetVal AS Number
LOCAL W1_nSUB_A AS Integer
Mo_nRetVal = 0
FOR W1_nSUB_A = 1 TO Len(L_cSomeBytes)
Mo_nRetVal = Mo_nRetVal * 256 + ASC(SUBSTR(L_cSomeBytes,W1_nSUB_A,1))
ENDFOR
RETURN Mo_nRetVal
FUNCTION ToMSBLSB
* ------------------------------------------------------ *
* 說明：。
* ------------------------------------------------------ *
* 參數名稱 型態 說明
* ------------------------------------------------------ *
* Input:
* L_nSomeNum N 。
* (L_nCount) N 預設值 = 1。
* Output:
* Mo_cRetVal C 。
* ------------------------------------------------------ *
LPARAMETERS L_nSomeNum, L_nCount
LOCAL Mo_cRetVal AS Character
LOCAL W1_nSUB_A AS Integer
Mo_cRetVal = ""
IF Type("L_nCount") != "N"
L_nCount = 1
ELSE
L_nCount = INT(L_nCount)
ENDIF
FOR W1_nSUB_A = 1 TO L_nCount
Mo_cRetVal = CHR(MOD(L_nSomeNum,256)) + Mo_cRetVal
L_nSomeNum = INT(L_nSomeNum/256)
ENDFOR
RETURN Mo_cRetVal
|
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ
朱育興 在 星期六 五月 21, 2005 8:03 pm 作了第 1 次修改 |
|
| 回頂端 |
|
 |
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 2 樓
|
| 發表於: 星期六 五月 21, 2005 2:52 am 文章主題: |
|
|
這是用函數方式處理 DBF 的：
| 代碼: |
WAIT WIND LTRIM(STR(UFIXDBF(GETFILE())))
FUNCTION UFIXDBF
* ------------------------------------------------------------------------------------------------------------ *
* 說明：資料表格檔的表頭修復程式。
* ------------------------------------------------------------------------------------------------------------ *
* 參數名稱 型態 說明
* ------------------------------------------------------------------------------------------------------------ *
* Input:
* L_cDBFFileName C 要修復的資料表格名稱(可包含完整路徑)。
* Output:
* M_nProcessNum N -2 = 檔案找不到。
* -4 = 開啟太多的檔案，沒有足夠的檔案控制碼。
* -5 = 檔案存取失敗。
* -6 = 指定的檔案控制碼不正確。
* -8 = 記憶體不足。
* -11 = 檔案長度太小，不是資料表格檔，不能被修復。
* -12 = 不是 FoxPro/FoxBase 資料表格，不能被修復。
* -13 = 資料表格的表頭資訊被破壞或不是資料庫檔案, 不能被修復。
* -25 = 搜尋錯誤 (無法從檔案的開頭處之前開始搜尋)。
* -29 = 磁碟空間不足。
* -31 = 開啟檔案時出現錯誤。
* 0 = 資料表格的表頭資訊正確，不需要修復。
* 2 = 0x02 FoxBASE
* 3 = 0x03 FoxBASE+/dBASE III PLUS，無附註欄位。
* 48 = 0x30 Visual FoxPro。
* 49 = 0x31 Visual FoxPro，有自動增量欄位。
* 50 = 0x32 Visual FoxPro，有可變長度字元欄位、可變長度二進位欄位或二進位大型物件欄位。
* 67 = 0x43 dBASE IV SQL 資料表格檔案，無附註欄位。
* 99 = 0x63 dBASE IV SQL 系統檔案，無附註欄位。
* 131 = 0x83 FoxBASE+/dBASE III PLUS，有附註欄位。
* 139 = 0x8B dBASE IV 有附註欄位。
* 203 = 0xCB dBASE IV SQL 表檔案，有附註欄位。
* 245 = 0xF5 FoxPro 2.x (或更早版本) 有附註欄位。
* 251 = 0xFB FoxBASE。
* ------------------------------------------------------------------------------------------------------------ *
* 注意：M_nProcessNum > 0，除了表示其為何種 DBF 類型外，也代表該 DBF 被修復成功。
* ------------------------------------------------------------------------------------------------------------ *
LPARAMETERS L_cDBFFileName AS String
LOCAL M_nProcessNum AS Number
LOCAL W1_nFileSize AS Number,W1_nHandleOfDBFFile AS Number
LOCAL W1_cHead_Filetype AS Character,W1_cHead_Reccount AS Character,W1_cHead_1stLocation AS Character,W1_cHead_RecordLength AS Character
LOCAL W1_nHead_Filetype AS Number ,W1_nHead_Reccount AS Number ,W1_nHead_1stLocation AS Number ,W1_nHead_RecordLength AS Number
LOCAL W1_nCorrectRecs AS Number ,W1_cCorrectRecs AS Character
M_nProcessNum = 0
W1_nFileSize = 0
W1_nHandleOfDBFFile = FOPEN(L_cDBFFileName, 2) && 以讀寫方式開啟資料表格檔
* 1.檔案是否能開啟
IF W1_nHandleOfDBFFile = -1
M_nProcessNum = FERROR() * -1
ENDIF
* 2.檔案長度是否太小
IF M_nProcessNum = 0
W1_nFileSize = FSEEK(W1_nHandleOfDBFFile,0,2)
=FSEEK(W1_nHandleOfDBFFile, 0, 0)
IF W1_nFileSize <= 64
=FCLOSE(W1_nHandleOfDBFFile)
M_nProcessNum = -11
ENDIF
ENDIF
* 3.判斷是否為 FoxPro/FoxBase 資料表格
IF M_nProcessNum = 0
* > 截取檔頭記錄
W1_cHeaderRecords = FREAD(W1_nHandleOfDBFFile,32)
* > 原始值
W1_cHead_Filetype = SUBSTR(W1_cHeaderRecords,01,01) && 檔案類型
W1_cHead_Reccount = SUBSTR(W1_cHeaderRecords,05,04) && 檔案中的資料記錄數目
W1_cHead_1stLocation = SUBSTR(W1_cHeaderRecords,09,02) && 第一筆資料記錄的位置
W1_cHead_RecordLength = SUBSTR(W1_cHeaderRecords,11,02) && 每筆資料記錄的長度 (包括刪除記號)
W1_cHead_Tableflags = SUBSTR(W1_cHeaderRecords,29,01) && 資料表格旗標
* > 轉換為 10 進位制數
W1_nHead_Filetype = Word2Dec(W1_cHead_Filetype)
W1_nHead_Reccount = Word2Dec(LEFT(W1_cHead_Reccount, 2)) + Word2Dec(RIGHT(W1_cHead_Reccount, 2)) * 65535
W1_nHead_1stLocation = Word2Dec(W1_cHead_1stLocation)
W1_nHead_RecordLength = Word2Dec(W1_cHead_RecordLength)
W1_nHead_Tableflags = Word2Dec(W1_cHead_Tableflags)
* > 判斷
IF INLIST(RIGHT(TRANSFORM(W1_nHead_Filetype,"@0"),2),"02","03","30","31","32","43","63","83","8B","CB","F5","FB")
M_nProcessNum = W1_nHead_Filetype
ELSE
=FCLOSE(W1_nHandleOfDBFFile)
M_nProcessNum = -12
ENDIF
ENDIF
* 4.資料表格是否被破壞
IF M_nProcessNum > 0
IF W1_nFileSize < W1_nHead_1stLocation OR W1_nHead_1stLocation <= 64
=FCLOSE(W1_nHandleOfDBFFile)
M_nProcessNum = -13
ENDIF
ENDIF
* 5.判斷是否需要修復
IF M_nProcessNum > 0
IF W1_nHead_Reccount = INT((W1_nFileSize-W1_nHead_1stLocation)/W1_nHead_RecordLength)
=FCLOSE(W1_nHandleOfDBFFile)
M_nProcessNum = 0
ENDIF
ENDIF
* 6.將受損的 DBF 修復
IF M_nProcessNum > 0
* > 計算檔案中的資料記錄數目
W1_nCorrectRecs = (W1_nFileSize - W1_nHead_1stLocation) / W1_nHead_RecordLength
* > 修正後轉換為雙位元組(WORD)二進制字串
W1_cCorrectRecs = Dec2Word(W1_nCorrectRecs-INT(W1_nCorrectRecs/65535)*65535) + Dec2Word(INT(W1_nCorrectRecs/65535))
* > 寫入正確資訊
=FSEEK(W1_nHandleOfDBFFile,4,0)
=FWRITE(W1_nHandleOfDBFFile,W1_cCorrectRecs,4)
=FCLOSE(W1_nHandleOfDBFFile)
ENDIF
RETURN M_nProcessNum
FUNCTION Dec2Word
* 這是別人提供的，是誰就不知了
******************************************************************************
* 名稱 : Dec2Word.PRG
* 用途 : 轉換 10 進制數到雙位元組(WORD)二進制字串
* 編寫 :
* 日期 : 1997.08.26
* 版本 : 1.0.0
******************************************************************************
* 用法 :
* cRetuVal = Dec2Word(<十進制數>)
******************************************************************************
* 參數:
*
* lnDecNum : 十進制數
*
******************************************************************************
* 傳回值:
*
* 傳回字元型雙位元組(WORD)二進制字串
*
******************************************************************************
* 參見:
* Word2Dec.PRG : 轉換雙位元組(WORD)二進制字串到 10 進制數
*
******************************************************************************
LPARAMETERS lnDecNum
LOCAL lcByte1, lcByte2
lcByte1 = CHR(MOD(lnDecNum,256))
lcByte2 = CHR(INT(lnDecNum/256))
RETURN lcByte1 + lcByte2
FUNCTION Word2Dec
* 這是別人提供的，是誰就不知了
******************************************************************************
* 名稱 : Word2Dec.PRG
* 用途 : 轉換雙位元組(WORD)二進制字串到 10 進制數
* 編寫 :
* 日期 : 1997.08.26
* 版本 : 1.0.0
******************************************************************************
* 用法 :
* cRetuVal = Word2Dec(<二進制字串>)
******************************************************************************
* 參數:
*
* lcBinNum : 二進制字串
*
******************************************************************************
* 傳回值:
*
* 傳回十進制數
*
******************************************************************************
* 參見:
* Dec2Word.PRG : 轉換 10 進制數到雙位元組(WORD)二進制字串
*
******************************************************************************
LPARAMETERS lcBinNum
LOCAL lnNum1, lnNum2
lcBinNum = PADR(lcBinNum, 2, CHR(0))
lnNum1 = ASC(LEFT(lcBinNum,1))
lnNum2 = ASC(RIGHT(lcBinNum,1)) * 256
RETURN lnNum1 + lnNum2
|
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 3 樓
|
| 發表於: 星期六 五月 21, 2005 2:53 am 文章主題: |
|
|
這是用函數方式處理 FPT 的：
| 代碼: |
WAIT WIND LTRIM(STR(UFIXFPT(GETFILE())))
FUNCTION UFIXFPT
* ------------------------------------------------------------------------------------------------------------ *
* 說明：附註檔的表頭修復程式。
* ------------------------------------------------------------------------------------------------------------ *
* 參數名稱 型態 說明
* ------------------------------------------------------------------------------------------------------------ *
* Input:
* L_cDBFFileName C 要修復的附註檔案名稱(可包含完整路徑)。
* Output:
* M_nProcessNum N -2 = 檔案找不到。
* -4 = 開啟太多的檔案，沒有足夠的檔案控制碼。
* -5 = 檔案存取失敗。
* -6 = 指定的檔案控制碼不正確。
* -8 = 記憶體不足。
* -25 = 搜尋錯誤 (無法從檔案的開頭處之前開始搜尋)。
* -29 = 磁碟空間不足。
* -31 = 開啟檔案時出現錯誤。
* 0 = 附註檔的表頭資訊正確，不需要修復。
* ------------------------------------------------------------------------------------------------------------ *
LPARAMETERS L_cFPTFileName AS String
LOCAL M_nProcessNum AS Number
LOCAL W1_nFileSize AS Number,W1_nHandleOfFPTFile AS Number
M_nProcessNum = 0
W1_nFileSize = 0
W1_nHandleOfFPTFile = FOPEN(L_cFPTFileName, 2) && 以讀寫方式開啟資料表格檔
* 1.檔案是否能開啟
IF W1_nHandleOfFPTFile = -1
M_nProcessNum = FERROR() * -1
ENDIF
* 2.檔案長度是否太小
IF M_nProcessNum = 0
* > 檔案大小
W1_nFileSize = FSEEK(W1_nHandleOfFPTFile,0,2)
=FSEEK(W1_nHandleOfFPTFile, 0, 0)
* > 截取檔頭記錄
W1_cHeaderRecords = FREAD(W1_nHandleOfFPTFile,8)
* > 原始值
W1_cHead_LocationOfNextFreeBlock = SUBSTR(W1_cHeaderRecords,1,4) && 下一個自由區塊的位置
W1_cHead_BlockSize = SUBSTR(W1_cHeaderRecords,7,2) && 區塊大小
* > 轉換為 10 進位制數
W1_nHead_LocationOfNextFreeBlock = UnMSBLSB(W1_cHead_LocationOfNextFreeBlock)
W1_nHead_BlockSize = UnMSBLSB(W1_cHead_BlockSize)
DO CASE
CASE W1_nHead_BlockSize = 0
W1_nHead_BlockSize = 1
CASE W1_nHead_BlockSize = 33
W1_nHead_BlockSize = 512 * W1_nHead_BlockSize
ENDCASE
W1_cFixHeaderRecords = ToMSBLSB(INT(W1_nFileSize/W1_nHead_BlockSize),4) + ;
CHR(0) + CHR(0) + W1_cHead_BlockSize
=FSEEK(W1_nHandleOfFPTFile,0,0) && 回到檔案開始處
=FWRITE(W1_nHandleOfFPTFile,W1_cFixHeaderRecords)
=FCLOSE(W1_nHandleOfFPTFile)
ENDIF
RETURN M_nProcessNum
FUNCTION UnMSBLSB
* 這是別人提供的，是誰就不知了
* ------------------------------------------------------------- *
* 說明：。
* ------------------------------------------------------------- *
* 參數名稱 型態 說明
* ------------------------------------------------------------- *
* Input:
* L_cSomeBytes C 是由 0 到 255 的 ASCII 字元所組成的字串。
* Output:
* Mo_cRetVal N 。
* ------------------------------------------------------------- *
* 範例：
* L_cSomeBytes = "戎譚" && ascii characters from 0 to 255
*
* Mo_cRetVal = ASC(SUBSTR(L_cSomeBytes,4,1)) + ;
* ASC(SUBSTR(L_cSomeBytes,3,1)) * 256 + ;
* ASC(SUBSTR(L_cSomeBytes,2,1)) * 256 * 256 + ;
* ASC(SUBSTR(L_cSomeBytes,1,1)) * 256 * 256 * 256
* ------------------------------------------------------------- *
LPARAMETERS L_cSomeBytes
LOCAL Mo_nRetVal AS Number
LOCAL W1_nSUB_A AS Integer
Mo_nRetVal = 0
FOR W1_nSUB_A = 1 TO Len(L_cSomeBytes)
Mo_nRetVal = Mo_nRetVal * 256 + ASC(SUBSTR(L_cSomeBytes,W1_nSUB_A,1))
ENDFOR
RETURN Mo_nRetVal
FUNCTION ToMSBLSB
* 這是別人提供的，是誰就不知了
* ------------------------------------------------------ *
* 說明：。
* ------------------------------------------------------ *
* 參數名稱 型態 說明
* ------------------------------------------------------ *
* Input:
* L_nSomeNum N 。
* (L_nCount) N 預設值 = 1。
* Output:
* Mo_cRetVal C 。
* ------------------------------------------------------ *
LPARAMETERS L_nSomeNum, L_nCount
LOCAL Mo_cRetVal AS Character
LOCAL W1_nSUB_A AS Integer
Mo_cRetVal = ""
IF Type("L_nCount") != "N"
L_nCount = 1
ELSE
L_nCount = INT(L_nCount)
ENDIF
FOR W1_nSUB_A = 1 TO L_nCount
Mo_cRetVal = CHR(MOD(L_nSomeNum,256)) + Mo_cRetVal
L_nSomeNum = INT(L_nSomeNum/256)
ENDFOR
RETURN Mo_cRetVal
|
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
marvin
註冊時間: 2004-06-01
文章: 321
第 4 樓
|
| 發表於: 星期一 五月 23, 2005 11:57 am 文章主題: |
|
|
| 先謝謝你的程式碼, 請問是適用在那個 VFP version ? |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 5 樓
|
|
| 回頂端 |
|
|
effielee
註冊時間: 2005-09-22
文章: 7
第 6 樓
|
| 發表於: 星期三 七月 19, 2006 11:32 am 文章主題: |
|
|
想請教一下,
不知道是否能在程式中加入某種機制,
能盡量避免發生DBF和FPT檔損毀的情形 @@? |
|
| 回頂端 |
|
|
impotence
註冊時間: 2005-02-21
文章: 135
來自: Hong Kong
第 7 樓
|
| 發表於: 星期三 七月 19, 2006 12:31 pm 文章主題: |
|
|
我也想知道 ...
_________________
一個常常忘記 Command 的人 ! |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 8 樓
|
|
| 回頂端 |
|
|
syntech
註冊時間: 2003-05-16
文章: 4252
來自: Taipei,Taiwan
第 9 樓
|
| 發表於: 星期三 七月 19, 2006 2:49 pm 文章主題: |
|
|
當毀損沒發生時,VFP不知道有沒有發生毀損,
當毀損發生時,那只剩能修復多少的問題.
_________________
如果公司有下列困擾:
1. 找不到便宜,快速,簡易的 生產排程軟體
2. 不知道如何快速排定 採購計劃
3. 成本抓不準,自己算比軟體算有用
4. 想學習系統規劃,想找系統架構的顧問
請聯絡我們,也許我們幫得上忙 |
|
| 回頂端 |
|
|
小賴
註冊時間: 2004-12-27
文章: 477
第 10 樓
|
| 發表於: 星期三 七月 19, 2006 4:39 pm 文章主題: |
|
|
| effielee 寫到: | 想請教一下,
不知道是否能在程式中加入某種機制,
能盡量避免發生DBF和FPT檔損毀的情形 @@? |
如果加上這條指令應可避免一些
ON 斷電 供電 WITH UPS
如果再加上
ON 不正常關機 CLOSE ALL
就更理想了 |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
