VFP 愛用者社區

朱育興 · 朱育興在星期四十一月 02, 2006 1:15 pm 作了第 1 次修改

加強及補充前次發表的文件

ShellExecute() 函數說明文件(API)

FoxPro 宣告方式：(為了排版美觀，空格為全形空白，要複製程式碼測試時，請換為半形空白 2006/11/02 補)

DECLARE INTEGER ShellExecute IN shell32;
　　INTEGER hwnd,;
　　STRING　lpOperation,;
　　STRING　lpFile,;
　　STRING　lpParameters,;
　　STRING　lpDirectory,;
　　INTEGER nShowCmd

參數：
hwnd
　1.指定一個父視窗的代碼(Handle)值。
　　(一個指派給視窗的數值，供作業系統追蹤視窗屬性)
　2.該應用程式所產生的視窗若有錯誤發生時會收到一個類似錯誤報告的訊息方塊。
　3.一般都設為 0。

lpOperation
　對指定檔案執行時所做的動作，有下列幾種選擇：(依該檔案所能提供的動作而定)
　edit　　編輯
　explore 瀏覽
　find　　搜尋
　open　　開啟
　print　列印
　備註：
　　該檔案所能提供的動作可由檔案總管 --> 工具 --> 資料夾選項 --> 檔案類型
　　--> 進階 --> 執行動作可以查知。

lpFile
　指定執行所指派動作的檔案(可含完整路徑名稱)或物件名稱。

lpParameters
　若指定檔案是一個可執行檔案(executable file)，且其後可下參數時，lpParameters
　就是存放該執行檔的參數內容。若無參數，補上 "" 即可。

lpDirectory
　程式執行的工作目錄。若為 ""，表示採用預設的目錄。

nShowCmd
　指定執行該檔案時，其應用程式以何種方式顯示視窗：
　0　不顯示
　1　最大化
　2　最小化

傳回值：
　1.若執行成功，傳回大於 32 的數值。
　2.若失敗，有下列幾種回應值：
　　 2 錯誤的關聯 (例如：不合法的 URL)
　　29 關聯失敗
　　30 關聯應用程式忙碌中...
　　31 沒有關聯任何應用程式

範例：(先宣告此 API)
* ---------------------------------------------------------------------------- *
　1.與指定的電腦之時間同步
　　M_cComputerName --> 指定的電腦名稱
　　=ShellExecute(0,"Open","NET.EXE","time \\"+M_cComputerName+" /set /yes","",0)

* ---------------------------------------------------------------------------- *
　2.檔案複製
　　VFP 本身就有 COPY FILE ... 命令，但來源檔案必須是未被使用中才行，
　　否則 VFP 會出現錯誤訊息，但改用下列方式就不會了。
　　M_cSourceFile --> 來源檔案名稱
　　M_cTargFile　 --> 目的檔案名稱
　　=ShellExecute(0,"Open","CMD.EXE","/c COPY "+M_cSourceFile+" "+M_cTargFile,"",0)
　　=ShellExecute(0,"Open",GETENV("COMSPEC"),"/c COPY "+M_cSourceFile+" "+M_cTargFile,"",0)

　　備註：
　　　1.若是 Win2000 以下的 OS，請將 CMD.EXE 換成 COMMAND.COM。
　　　　不過在 VFP 中直接用 GETENV("COMSPEC") 就可以了，VFP 會自行判斷。
　　　2.事實上它就是在 DOS 模式下執行 DOS 內部指令 COPY 的動作，以 VFP 的做法如下
　　　　! COPY &M_cSourceFile. &M_cTargFile.
　　　3.將 nShowCmd 設為 0 就可令那討厭的 DOS 視窗完全不會出現；
　　　　其他的 DOS 指令也可依此模式去做。

* ---------------------------------------------------------------------------- *
　3.發送一個給指定電腦的「信差服務」訊息方塊
　　會提供這個案例，是公司有內部控管的需求。VFP 應用程式放在公司伺服器所在的電腦
　　M_cSeverComputerName --> 公司伺服器所在的電腦名稱
　　M_cUserIdR　　　　　 --> 接收訊息的使用者名稱

　　* 在那一臺電腦執行本程式
　　M_cCurComputerName = ALLTRIM(LEFT(SYS(0),AT("#",SYS(0))-1))
　　* 發送訊息的使用者名稱
　　M_cUserIdS　　　　 = ALLTRIM(SUBSTR(SYS(0),AT("#",SYS(0))+1))

　　* 在伺服器電腦上工作階段連線的電腦及其使用者
　　* ---------------------------------- *
　　* M_aSessionInfo(*,1) = C 使用者名稱
　　* M_aSessionInfo(*,2) = C 電腦名稱
　　* ---------------------------------- *
　　DIMENSION M_aSessionInfo(1,2)
　　STORE "" TO M_aSessionInfo

　　* 只有伺服器的電腦才能產生 NetSession.TXT
　　IF M_cCurComputerName == M_cSeverComputerName
　　　=STRTOFILE("NET.EXE SESSION > NetSession.TXT","Net.Bat")
　　　=ShellExecute(0,"Open","Net.Bat","","",0)
　　ENDIF

　　* 取得伺服器電腦上工作階段連線的電腦及其使用者
　　IF ADIR(W1_aAdir,"NetSession.TXT") > 0
　　　W1_mComment = FILETOSTR("NetSession.TXT")
　　　STORE "" TO M_aSessionInfo
　　　W1_nRowOfSessionInfo = 0
　　　FOR W1_SUB_A = 1 TO MEMLINES(W1_mComment)
　　　　W1_cLINE　　　　 = MLINE(W1_mComment,W1_SUB_A,0)
　　　　W1_cHandle　　　 = SUBSTR(W1_cLINE,1,2)　　　　　　&& 每列的表頭
　　　　W1_cUserName　　 = ALLTRIM(SUBSTR(W1_cLINE,24,20)) && 使用者名稱
　　　　W1_cComputerName = ALLTRIM(SUBSTR(W1_cLINE,3,20))　&& 電腦名稱
　　　　IF !W1_cHandle = "\\"
　　　　　LOOP
　　　　ENDIF
　　　　W1_nRowOfSessionInfo = W1_nRowOfSessionInfo + 1
　　　　DIMENSION M_aSessionInfo(W1_nRowOfSessionInfo,2)
　　　　M_aSessionInfo(W1_nRowOfSessionInfo,1) = W1_cUserName
　　　　M_aSessionInfo(W1_nRowOfSessionInfo,2) = W1_cComputerName
　　　ENDFOR
　　ENDIF

　　* 傳送「信差服務」
　　M_nCurRowOfSessionInfo = ASCAN(M_aSessionInfo,UPPER(ALLTRIM(M_cUserIdR)),1,-1,1,14)
　　IF M_nCurRowOfSessionInfo > 0
　　　M_mMessage = "send " + M_aSessionInfo(M_nCurRowOfSessionInfo,2) + ;
　　　　　　　　　 " " + M_cUserIdS + "發訊息給 " + ALLTRIM(M_cUserIdR) + ;
　　　　　　　　　 "：" + CHR(13) + CHR(10) + CHR(13) + CHR(10) + ;
　　　　　　　　　 "有一封信件到管理室領取"
　　　=ShellExecute(0,"Open","net.exe",M_mMessage,"",0)
　　ENDIF
　　備註：
　　　1.本 ASCAN() 函數的參數使用是 7.0 版的環境，6.0 版或以下版本，請自行改寫。
　　　2.實際上 NetSession.TXT 的產生是公司伺服器將程式放在工作排程中執行，
　　　　且每 5 分鐘更新一次(這細節不便說明)。
　　　3.傳送後，接收訊息的使用者就會在其桌面出現「信差服務」訊息方塊。
　　　4.傳送「信差服務」這一段實際上是在一個 SCAN ... ENDSCAN 中，
　　　　在這裏簡化內容。若要做個簡單測試，將電腦名稱都指定自己的電腦，
　　　　發送及接收的使用者名稱也指定自己(就是一開始進入 Windows 登錄的名稱)，
　　　　我想這樣在自己的單機上測試就可達到效果。
* ---------------------------------------------------------------------------- *

後記：
　1.這是我使用此 API 的心得，當中若有不正確或須補充的地方，煩請各位能告知我，
　　以便將此 API 的說明更加完備。
　2.以後若有實際上應用的範例會繼續提供，也希望各位若有實際應用的例子，
　　也祈盼分享出來。

奔跑的愛情 · 註冊時間: 2003-08-28 文章: 27 第 2 樓

好文，不過第一在什麼地方呢？

goto-dream · 註冊時間: 2004-05-11 文章: 909 第 3 樓

lcm · 註冊時間: 2004-12-27 文章: 45 第 4 樓

請問執行ShellExecute()是否要等所執行的程式結束後，才會繼續其後的程式碼？謝謝

朱育興 · 發表於: 星期三十一月 02, 2005 12:39 am 文章主題:

記得是不會，若需要所執行的程式的結果，就要利用延遲的效果讓該程式結束後才繼續其後的程式碼

這類範例應該不少，只是忘記用什麼關鍵詞去搜索了

garfield · Site Admin 註冊時間: 2003-01-30 文章: 2160 第 6 樓

測試用 DECLARE INTEGER ShellExecute IN shell32;
　　INTEGER mhwnd,;
　　STRING　lpOperation,;
　　STRING　lpFile,;
　　STRING　lpParameters,;
　　STRING　lpDirectory,;
　　INTEGER nShowCmd

執行? ShellExecute(0,"Open","CMD.EXE","/c COPY c:\temp\temp.dbf c:\temp\temp.txt","",0)
會出現錯誤.
但用
Declare Integer ShellExecute In shell32.Dll Integer, String, String, String, String, Integer
執行? ShellExecute(0,"Open","CMD.EXE","/c COPY c:\temp\temp.dbf c:\temp\temp.txt","",0)
確很正常 ???
不知錯在那裡?

朱育興 · 發表於: 星期四十一月 02, 2006 1:10 pm 文章主題:

那是因為直接複製我的範例時，空格是全形空白，所以宣告時就不會正確，把全形空白換為半形再執行就可以了

garfield · Site Admin 註冊時間: 2003-01-30 文章: 2160 第 8 樓

原來如此, 我才覺得看起來沒問題, 怎麼執行起來就是有問題,
眼睛是會騙人的.

syntech · 發表於: 星期五十一月 03, 2006 1:45 pm 文章主題:

一語驚醒夢中人.嚇得我屁滾尿流失了魂~~~~~ 建寧公主. ^_^

我也常常這樣做,讓POST出來的版面好看一點.
或是一些保留字改用全形等等.
以後要記得提醒別人.