 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
Ruey
註冊時間: 2003-03-12
文章: 1698
來自: tunglo
第 1 樓
|
 發表於: 星期一 九月 01, 2003 8:21 pm 文章主題: 使用API下載HTTP文件2.0(轉貼) |
 |
|
來源:雅狐 xwy
| 代碼: | ?Url_DownFile("http://securityresponse.symantec.com/avcenter/download/us-files/20030703-016-i32.exe","C:\20030703-016-i32.exe")
RETURN
****************************************
* 使用API下載HTTP文件 *
* 2.0 2003.07.05 *
* 1.0 2003.04.23 *
* 雅狐論壇 www.yafox.com *
****************************************
*返回文件大小，＝－１為本地初始化失敗，＝－２網�}不能打�} ，＝－３指定的目標文件無效
FUNCTION Url_DownFile(Inter_Url,LocalFile)
*本地初始化
DECLARE INTEGER InternetOpen IN wininet;
STRING sAgent, INTEGER lAccessType, STRING sProxyName,;
STRING sProxyBypass, STRING lFlags
*打�}URL
DECLARE INTEGER InternetOpenUrl IN wininet;
INTEGER hInternet,;
STRING lpszUrl,;
STRING lpszHeaders,;
INTEGER dwHeadersLength,;
INTEGER dwFlags,;
INTEGER dwContext
*獲取Http信息
DECLARE INTEGER HttpQueryInfo IN wininet;
INTEGER hRequest,;
INTEGER dwInfoLevel,;
STRING @ lpvBuffer,;
INTEGER @ dwBufferLength,;
INTEGER @ lpdwIndex
*讀取遠�{文件
DECLARE INTEGER InternetReadFile IN wininet;
INTEGER hFile,;
STRING @ lpBuffer,;
INTEGER dwNumberOfBytesToRead,;
INTEGER @ lpdwNumberOfBytesRead
*本地連接終止
DECLARE INTEGER InternetCloseHandle IN wininet INTEGER hInet
Url_Open = InternetOpen("XWY", 1, CHR(0), CHR(0), 0) &&本地初始化
IF Url_Open=0
CLEAR DLLS
RETU -1 &&'本地初始化失敗'
ENDIF
Url_Session = InternetOpenUrl (Url_Open, Inter_Url, "", 2, 16, 0)
IF Url_Session=0
= InternetCloseHandle(Url_Open)
CLEAR DLLS
RETU -2 &&'網�}不能打�}'
ENDIF
Url_Fopen = FCREATE (LocalFile)
IF Url_Fopen = -1
= InternetCloseHandle(Url_Session)
= InternetCloseHandle(Url_Open)
CLEAR DLLS
RETURN -3 &&'指定的目標文件無效'
ENDIF
Url_QueryInfo = SPACE(32)
Url_QueryInfoLen = LEN(Url_QueryInfo)
IF HttpQueryInfo(Url_Session,5,@Url_QueryInfo,@Url_QueryInfoLen,0) = 1 &&取文件大小
Url_FileSize = VAL(LEFT(Url_QueryInfo,Url_QueryInfoLen))
ELSE
Url_FileSize = -1
ENDIF
Url_SizeSum = 0
Url_ReadBuffer = REPLI (CHR(0), 4096)
DO WHILE .T.
Url_ReadBye = 0
IF InternetReadFile (Url_Session, @Url_ReadBuffer, 4096, @Url_ReadBye) = 1
IF Url_ReadBye = 0
EXIT
ELSE
= FWRITE (Url_Fopen, Url_ReadBuffer, Url_ReadBye)
ENDIF
Url_SizeSum = Url_SizeSum + Url_ReadBye
IF Url_FileSize =-1
IF Url_SizeSum>1024^2
WAIT '正在接收 '+ALLT(STR(Url_SizeSum/1024^2,10,3))+'M ' WIND NOWA
ELSE
WAIT '正在接收 '+ALLT(STR(Url_SizeSum/1024 ))+'K ' WIND NOWA
ENDI
ELSE
IF Url_SizeSum>1024^2
WAIT '正在接收 '+ALLT(STR(Url_SizeSum/1024^2,10,3))+'M '+STR(Url_SizeSum/Url_FileSize*100,6,2)+'% ' WIND NOWA
ELSE
WAIT '正在接收 '+ALLT(STR(Url_SizeSum/1024 ))+'K '+STR(Url_SizeSum/Url_FileSize*100,6,2)+'% ' WIND NOWA
ENDI
ENDIF
ELSE
EXIT
ENDIF
ENDDO
WAIT CLEAR
= FCLOSE (Url_Fopen)
= InternetCloseHandle(Url_Session)
= InternetCloseHandle(Url_Open)
CLEAR DLLS
RETURN Url_SizeSum
**************************************** |
_________________
#############################
快樂媽咪系列幸福宅配,喝十全雞湯~原來幸福那麼簡單!!
學會VFP使用者社區的搜尋,Code才會更有趣~
############################# |
|
| 回頂端 |
|
 |
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
