VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

Treeview Control

http://www.universalthread.com/Magazine/June2001/Page7.asp

Ruey · 發表於: 星期三八月 13, 2003 10:47 am 文章主題:

對“兩個欄位在樹控制項中的顯示”的補充及增強
( 作者: 紅虎 )

原文是由一個發問者所得出的結論，針對資料量不是很大時，看不出什麽來，後來我處理到1000個記錄以上時就感覺明顯慢了，不過樹的處理運用在VFP裏，的確也快不了多少。先對上一問題，我採用了另一個方案，並加入核取方塊的功能：
本示例具體參照法：
1、新建一個表單
2、在表單上放一個TreeView控制項
3、在此控制項的相關事件中將以下代碼粘貼進去
在樹控制項的Init事件裏：
wait window "正在初始化，請稍候..." nowait
this.checkboxes = .T. && 顯示核取方塊
this.indentation = 20 && 設置層之間的距離
wait window "建立臨時資料表，請稍候..." nowait
*-- 建立一個臨時表：包含ROOT和CHILD兩個欄位
create cursor temp_data (root c (10),child c (11))

wait window "加入臨時資料，請稍候..." nowait
*-- 以迴圈方式在此臨時表中加入資料，共9個根目錄，每個根目錄下有9個子目錄
for r = 1 to 9 && 根目錄
cRoot = "Root "+allt(str(r))
for c = 1 to 9 && 子目錄
cChild = "Child "+allt(str(c))
insert into temp_data ( root,child ) values ( cRoot,cChild )
endfor
endfor

wait window "載入資料到樹中，請稍候..." nowait
*-- 放入最高層目錄
this.nodes.add(,,"top","Main Directory",0)

old_tree = "_" && 表示原先的一個樹的ROOT值，用於下面的對比
*-- 將原有資料表根據根目錄、子目錄排序生成一個新的臨時表
sele * from temp_data order by root,child into cursor temp_treeview
total_num = _tally && 此表最大的記錄數，用於下面的進度指示
sele temp_treeview
item_no = 1 && 每個專案在樹裏的順序號

go top
do while !eof()
new_tree = root&& 當前的新的樹的ROOT值
child_key = new_tree + "_" + allt(str(item_no)) && 當前的分支的KEY值，此值在樹裏是唯一的

if !(new_tree == old_tree) && 判斷當前分之與上一個是否相同，不同的話，要先加入根目錄
this.nodes.add("top",4,child_key,new_tree,0) && 加入一個根目錄
item_no = item_no + 1 && 順序號加1
cur_child = child_key && 同時得到當前這個根目錄的KEY值，用於下一層子目錄的引用
endif
cKey = child + "_" + allt(str(item_no)) && 當前子目錄的KEY值
this.nodes.add(cur_child,4,cKey,child,0) && 加入一個子目錄
item_no = item_no + 1 && 順序號記錄加1
wait window "資料載入中..."+allt(str(int(recn()*100/total_num),3))+"%" nowait && 顯示進度

sele temp_treeview
old_tree = root && 當前的根值賦值，以迴圈到下一個時，這個就是所謂的上一個根的值
skip
enddo

this.Nodes(1).Expanded = .T. && 將頂層分之展開
wait window "初始化...完畢" nowait

在樹控制項中的NodeCheck事件裏：
*** ActiveX 控制項事件 ***
LPARAMETERS node
llThisCheck = node.checked && 當前的checkbox的狀態
if node.key="top" && 當選擇打勾的是最頂層時
if llThisCheck
if messagebox("全部選中需要花費更多的時間，繼續嗎？",4+32,"詢問") = 7
this.nodes.item(1).checked=.f.
retu
endif
endif
*-- 對全部進行更新
for n=1 to this.nodes.count
this.nodes.item(n).checked=llThisCheck
endfor
else
*-- 如果不是頂層的分支時
if at("_",node.key) = 11 && 判斷是否點的ROOT，這個11可以根據具體情況，這裏是ROOT欄位寬度+1
nCur_Item = val(right(node.key,len(node.key)-at("_",node.key))) && 求得當前分支在樹裏的順序號
i = nCur_item + 2 && 加上頂層占一位，當前占一位元，所以在當前順序號的下2個號碼開始
do while .t.
this.nodes.item(i).checked = llThisCheck
i = i + 1
if at("_",this.nodes.item(i).key) = 11 && 判斷是否到了下一個根，如果是，退出迴圈
exit
endif
enddo
else
endif
endif

另外對樹的add方法的說明：
如此命令： this.nodes.add(Parent_key,nChild,Current_key,Topic,SelectedImage,UnSelecteImage)
Parent_key 表示當前支的上一個支的KEY值
nChild 有0-4五個選擇項，分別表示如下：
0 - 表示新的支會放在同層（或同級）的Parent_key的最上面
1 - 表示新的支會放在同層（或同級）的Parent_key的最下面
2 - 表示新的支會放在同層（或同級）的Parent_key的下面一個
3 - 表示新的支會放在同層（或同級）的Parent_key的上面一個
4 - 表示新的支會放在同層（或同級）的Parent_key的下面一層的最下面
Current_key 表示當前支的KEY值
Topic 表示顯示在樹裏的支上的內容
SelectedImage 表示當選擇了某個支後所反映出來的圖片，這個值在ImageList控制項裏的索引值，0表示沒有。
UnSelectedImage 表示沒有選擇的支所顯示的圖片，這個值在ImageList控制項裏的索引值，0表示沒有。

>>> 下載該示例 tvdemo.zip 6.6K 如有疑問，請來信！

兩個欄位的表在樹控制項中的使用
( 作者: 紅虎 )

有一個表如下：
欄位系科姓名
記
錄中文系王濤
中文系李明
數學系張三
物理系李四
物理系張民
建立該資料庫使用下列命令：
create table 表 (系科 c(10),姓名 c(10))
insert into 表 (系科,姓名) values ("中文系","王濤")
insert into 表 (系科,姓名) values ("中文系","李明")
insert into 表 (系科,姓名) values ("數學系","張三")
insert into 表 (系科,姓名) values ("物理系","李四")
insert into 表 (系科,姓名) values ("物理系","張民")
要使這個只有兩個欄位的資料表在一個TreeView的控制項上産生如下的形狀：
系科管理
　　｜
　　└→ 數學系
　　｜　　　└→ 張三
　　｜
　　└→ 物理系
　　｜　　　└→ 李四
　　｜　　　└→ 張民
　　｜
　　└→ 中文系
　　　　　　└→ 李明
　　　　　　└→ 王濤
新建一個表單，在該表單上放置一個TreeView的控制項，並指定name=OleTreeView，再創建一個按紐，在其Click事件中寫入如下代碼：
*-- 程式開始 ------------------------------------------
priv i,cn
i=1
*-- 用於物件的唯一性標記用

thisform.OleTreeView.nodes.add(,0,"top","系科管理")
*-- 先建立一個頂層的目錄

select 系科,姓名 from 表 order by 系科 group by 系科 into cursor temp_xk
*-- 查詢出該表的第一層目錄的記錄，通過group分組，可以保證結果的資料是唯一的

do while not eof()
thisform.OleTreeView.nodes.add("top",4,"xk"+allt(str(i)),allt(系科))
*-- 以迴圈的方式將這個系科的層目錄，放到頂層目錄的下面，並根據變數i得到順序的排列
i=i+1
skip
enddo
*-- 至此，第一層排列放置結束，下面進行第二層的放置

*-- 下面的思路是，按照第一層所得的結果的記錄集合，以次來放置他們各自的下一層
select temp_xk
go top
i=1
do while not eof()
cn=allt(str(recn())) && 此處的記錄號可以與第一層變數i所産生的順序號吻合
select * from 表 where 系科==temp_xk.系科 order by 姓名 into cursor temp_xm
*-- 將屬於某個第一層的下屬名單查出來，得到一個新的記錄集合

do while not eof()
thisform.OleTreeView.nodes.add("xk&cn",4,"xm"+allt(str(i)),allt(temp_xm.姓名))
*-- 再以迴圈方式對第二層的姓名，分別放置，
*-- 此處，變數i因重新賦值爲1，"xm"+allt(str(i)) 正好重新記數，
*-- 對它的理解只在於這個"xm"+allt(str(i))所反應的值在整個樹中是唯一的。
select temp_xm
i=i+1
skip
enddo

select temp_xk
skip
*-- 進入第一層的下一個迴圈
enddo

use in temp_xm
use in temp_xk
use in 表
*-- 關閉程式涉及的三個表

goto-dream · 註冊時間: 2004-05-11 文章: 909 第 3 樓

select 系科,姓名 from 表 order by 系科 group by 系科 into cursor temp_xk
改成這樣
select 系科 from 表 order by 系科 group by 系科 into cursor temp_xk

才正確....

candy7240 · 註冊時間: 2008-12-02 文章: 8 第 4 樓

此方法用二階可以使用
但我改成見三階的時候，第三層的資料就全部亂跳了

煩請各位大大解答
謝謝 Razz

syntech · 發表於: 星期五十二月 24, 2010 11:11 am 文章主題:

你得知道treeview.additem 的邏輯,然後再檢查怎麼塞資料怎麼add,

第二樓有.