 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
Mark123
註冊時間: 2012-06-28
文章: 6
第 1 樓
|
 發表於: 星期三 十一月 14, 2012 3:23 pm 文章主題: 如何取得FTP伺服器上面檔案的日期時間? |
 |
|
請問各位先進,我寫了一支備份程式,每天排程下載FTP檔案,
*** 取得目錄中的第一個檔案名稱
Declare Integer FtpFindFirstFile In wininet;
Integer hftpsession, String lpszsearchfile,;
string @lpfindfiledata, Integer dwflags, Integer dwcontent
*** 找下一個檔案名稱
Declare Integer InternetFindNextFile In wininet;
Integer hfind, String @lpvfinddata
我用了以上方法取得檔案名稱.
請問我要用什麼方法取得檔案的日期? 謝謝! 這樣我才能知道檔案是不是最新的. |
|
| 回頂端 |
|
 |
ckp6250
註冊時間: 2004-07-30
文章: 1645
第 2 樓
|
| 發表於: 星期四 十一月 15, 2012 3:58 pm 文章主題: |
|
|
wininet 應該有 ftpcommad 可用吧
下 ls 指令 , 應該能傳回檔案清單 |
|
| 回頂端 |
|
|
Mark123
註冊時間: 2012-06-28
文章: 6
第 3 樓
|
| 發表於: 星期五 十一月 16, 2012 10:11 am 文章主題: |
|
|
不好意思,我碼程式碼貼出來才比較清楚!!!
| 代碼: |
Set Dele On && 已經刪除的資料不顯示
Set Safe Off && 檔案IO時不詢問,直接動作
Set Date ymd && 日期格式: yyyy-mm-dd
Set Hours To 24 && 時間為24小時制
Set Century On && 日期格式中,年份�]定為四碼
Set Mark To '-' && 日期分隔符號,例如 2010-11-01
Set enginebehavior 70 && 向下相容foxpro早期版本�{式語法
On Error * && 當有任何錯誤的時候不做任何事, *星號是註解,註解就代表什麼都不做
Close Databases All && 關閉所有�}啟的資料庫
*=MESSAGEBOX(SYS(5)+SYS(2003))
m_date=Date()-1 && 前一天
m_user=Upper(Alltrim(Right(Sys(0),Len(Sys(0))-At('#',Sys(0)))))
m_pcname=Upper(Alltrim(Left(Sys(0),At('#',Sys(0))-1)))
m_prgname='每日FTP下載informix資料庫備份'
sss=Seconds() && 記錄�}始執行的時間
Create Cursor temp01 (功能 c(10),分類 c(4),資料夾 c(100)) && 備份資料夾記錄檔, 用來儲存 backup_init.txt 內容
*APPEND FROM Backup_init.txt DELIMITED WITH _ WITH CHARACTER ,
Append From backup_init.txt Delimited With Character , && 讀取 backup_init.txt 檔案,裡面記錄備份要用的資料夾
*****backup_init.txt 是用來隨時改變備份位置的,請將backup_init.txt2檔案與此�{式放在同一資料夾
*****backup_init.txt 內容如下三列(不含前面5個星號)
*****informix,FTP,/u1/EXPORT/smz.exp/
*****informix,暫存,D:\Backup\informix資料庫\smz.exp
*****informix,目的,E:\Backup\informix資料庫
*=================================================================================================
***** 準備 FTP 連線
***** 宣告 wininet.dll
*** �}啟 internet 連結
Declare Integer InternetOpen In wininet;
string sAgent,;
integer lAccessType,;
string sProxyName,;
string sProxyBypass,;
string lFlags
*** 關閉 internet 連結
Declare Integer InternetCloseHandle In wininet ;
integer hInet
*** 連結 ftp or http
Declare Integer InternetConnect In wininet;
integer hInternetSession,;
string sServerName,;
integer nServerPort,;
string sUsername,;
string sPassword,;
integer lService,;
integer lFlags,;
integer lContext
*** 下載 ftp 檔案
Declare Integer FtpGetFile In wininet;
integer hFtpSession, ;
string lpszRemoteFile,;
string lpszNewFile,;
integer fFailIfExists,;
integer dwFlagsAndAttributes,;
integer dwFlags,;
integer dwContext
*** 取得 ftp 目錄資料
Declare Integer FtpGetCurrentDirectory In wininet;
Integer hftpsession, String @lpszdir, Integer @lpdwcurdir
*** 取得目錄中的第一個檔案名稱
Declare Integer FtpFindFirstFile In wininet;
Integer hftpsession, String lpszsearchfile,;
string @lpfindfiledata, Integer dwflags, Integer dwcontent
*** 找下一個檔案名稱
Declare Integer InternetFindNextFile In wininet;
Integer hfind, String @lpvfinddata
*** 建立本機資料夾
Select temp01
Locate For 功能='informix' And 分類='暫存' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
m_path=Alltrim(資料夾) && 如果找到, 則使用該資料夾備份未壓縮的檔案
Else
m_path='D:\Backup\informix資料庫\smz.exp' && 找不到, 就用預�]的資料夾 (例如: d:\Backup\informix資料庫\smz.exp)
Endif
If !Directory(m_path) && 檢查資料夾是否存在,不存在就建立
Md &m_path && 建立資料夾
Else
m_comm='run del '+m_path+' /q' && 刪除資料夾內的檔案
&m_comm
Endif
Select temp01
Locate For 功能='informix' And 分類='目的'
If Found()
m_path1=Alltrim(資料夾)
Else
m_path1='E:\Backup\informix資料庫' && 備份檔案路徑 (例如: E:\Backup\informix資料庫\)
Endif
If !Directory(m_path1) && 檢查資料夾是否存在,不存在就建立
Md &m_path1 && 建立資料夾
Endif
***** �}始連線
sagent = "vfp7" && 自訂一個名稱(隨便)
sproxyname = 0 && 不使用Proxy server -->vb 不是 chr(0) 是用 null
sproxybypass = 0 && 不回復訊息
lflags = 0 && 預�]值
* �}啟連結 (建立 internet session)
hopen = internetopen (sagent, 1, sproxyname, sproxybypass, lflags)
* �]定登入的使用者名稱
strhost = '10.0.1.99' && 要登入的ftp位�}或名稱
port=21 && ftp 的通訊埠
struser = 'test' && 使用者名稱
strpwd = 'test' && 密碼
************** 連線至 ftp
*!* hFtpSession = InternetConnect (hOpen, strHost, port, strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
hftpsession = internetconnect (hopen, strhost, port, struser, strpwd, 1, 0, 0)
If hftpsession = 0
Return
Endif
*** 下載 ftp 檔案
If hopen>0 And hftpsession>0
lpfindfiledata = Repli (Chr(0), 320) && lpfindfiledata = 320個chr(0)
Select temp01
Locate For 功能='informix' And 分類='FTP' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
ftpdir=Alltrim(資料夾) && FTP Server 的檔案路徑
Else
ftpdir='/u1/EXPORT/smz.exp/' && FTP Server 的檔案路徑
Endif
lcmask=Alltrim(ftpdir)+'*.*'
hfind = ftpfindfirstfile(hftpsession,lcmask,@lpfindfiledata,16,0) && 取得第一個檔案
If hfind>0 && 判斷是否找到第一個檔案
Select 0 && 切換至空的工作區
Create Cursor temp00 (filename c(20),filesize i,filetime T,fileattrib c(100),dl c(4)) && 建立Cursor
m_filename=Alltrim(Substr(lpfindfiledata, 45,250))
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
Insert Into temp00 (filename) Values (m_filename) && 將檔案名稱寫入Cursor
lnfound =1 && 找到的檔案總數累�[, 從一�}始 ,�]為ftpfindfirstfile已經找到第一個檔案
Do While .T. && �}始找尋下一個檔案
If internetfindnextfile (hfind, @lpfindfiledata) <> 1 && 判斷是否找到下一個檔案
Exit && 找不到, 跳出迴圈
Else
lnfound = lnfound + 1 && 找到的檔案總數累�[
m_filename= Alltrim(Substr(lpfindfiledata, 45,250))
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
Insert Into temp00 (filename) Values (m_filename) && 將檔案名稱寫入Cursor
Endif
Enddo
Select temp00 && 切換到Cursor
Scan &&將temp00資料表逐筆�]過一次
lpszremotefile=ftpdir+Alltrim(Lower(temp00.filename)) && 來源檔
*Wait Windows notes+'/'+lpszremotefile Nowait && 將檔案名稱顯示在畫面,這是要監看用的,讓你知道正在下載那一個檔案
lpsznewfile=m_path+'\'+Alltrim(Lower(temp00.filename)) && 目的檔
lnresult=ftpgetfile (hftpsession, lpszremotefile, lpsznewfile, 0, 128, 2, 0) && �}始下載
If lnresult>0 && 判斷是否成功, >0成功 ,寫入temp01
Replace dl With '成功' In temp00 && 寫入dl欄位, 供以後判斷成功與否
Else
Replace dl With '失敗' In temp00
Endif
Endscan
Copy To m_path+'\log00' && 記錄檔存放下載記錄 ,D:\Backup\informix資料庫\smz.exp\log00.dbf
Endif
Endif
= internetclosehandle (hopen) && 關閉FTP連線
*=================================================================================================
*** 呼叫WinRAR 壓縮檔案
*If Os()='Windows 6.01' && 取得作業系統是不是 Windows2008R2 64位元版?
Do Case
Case File("C:\Program Files (x86)\winrar\winrar.exe") && 64位元作業系統WinRAR放在此資料夾,公司伺服器Windows2008R2是64位元,所以會有此問題
Set Default To "C:\Program Files (x86)\winrar" && 切換�{式路徑至 C:\Program Files (x86)\winrar
Case File("C:\Program Files\winrar\winrar.exe")
Set Default To "C:\Program Files\winrar" && 切換�{式路徑至C:\Program Files\winrar
Endcase
aaa='run winrar a -m5 '+m_path1+'\smz_'+Dtos(m_date)+'.rar '+m_path && 將命令�]成字串,命令內容是執行DOS模式 ,前面的RUN代表呼叫DOS模式,後面接著winrar命令
&aaa && 巨集替代,執行字串的內�[ (�]就是把字串變成命令執行)
Select filename,dl From temp00 Order By dl,filename Into cursor temp88 && 依照下載成功與否排序
***** 寫入SQL
=SQLSetprop(0,"DispLogin",3)
conn9=Sqlstringconnect('DRIVER=SQL Server;SERVER=192.168.1.1;uid=test;PWD=test;DATABASE=test')
If conn9>0
lc_sss=Alltrim(Str(Seconds()-sss,10,3)) && 計算執行秒數
*** 拼湊HTML
aaa="這是自動信件,請勿直接回覆,謝謝!<br>"
aaa=aaa+'<font color="#cc33ff" size="7">本�{式請勿在凌晨01:00~02:00執行,此時informix正在匯出資料庫</font>'
aaa=aaa+"<br>�{式名稱: "+m_prgname
aaa=aaa+"<br>�{式功能: 自動化FTP下載1:00產生的informix資料庫備份檔案,並呼叫WinRAR壓縮"
aaa=aaa+'<br>執行的電腦:'+m_pcname
aaa=aaa+"<br>目前時間: "+Ttoc(Datetime())
aaa=aaa+"<br>執行秒數: "+lc_sss
aaa=aaa+'<table bordercolor="black" border="1">'
aaa=aaa+'<td>序號</td><td>檔案名稱</td><td>是否完成</td>'
*** 拼湊HTML的列(Row;Record)
Select temp88 && 切換工作區(切換至記憶體中的資料表)
Scan && 針對此資料表做一筆一筆的掃描一遍
If dl='失敗'
aaa=aaa+'<tr BGCOLOR=red>'
Else
aaa=aaa+'<tr>'
Endif
aaa=aaa+'<td>'+Alltrim(Str(Recno()))+'</td>'
aaa=aaa+'<td>'+Alltrim(filename)+'</td>'
aaa=aaa+'<td>'+Alltrim(dl)+'</td>'
aaa=aaa+'</tr>' && 用<tr></tr>區隔一列資料
Endscan
aaa=aaa+'</table><br><br>'
*** 寫入發信機制,排�{發信
=SQLExec(conn9,"insert into 送信整合信件內容 (電腦名稱,比對電腦名稱,�{式名稱,主旨,內容,信件格式) values (?m_pcname,0,?m_prgname,'"+m_prgname+'_'+Dtoc(m_date)+"',?aaa,'html')") && 對SQL執行SQL命令
=SQLDisconnect(conn9)
Endif
|
請問,我要如何把Cursor temp00.filetime 欄位的值填正確? |
|
| 回頂端 |
|
|
Mark123
註冊時間: 2012-06-28
文章: 6
第 4 樓
|
| 發表於: 星期五 十一月 16, 2012 10:30 am 文章主題: |
|
|
應該這樣說,
以下是程式執行後發出的信件內容(是另一支程式負責發信).
目前內容缺少了檔案最後寫入時間,無法判斷前一天informix備份是否有做?
每天備份290個檔案,要清楚的辨識下載成功與否? 檔案日期是不是最新的?
***信件內容
這是自動信件,請勿直接回覆,謝謝!
程式名稱: 每日FTP下載informix資料庫備份
程式功能: 自動化FTP下載1:00產生的informix資料庫備份檔案,並呼叫WinRAR壓縮
執行的電腦:SEAL-SRV
目前時間: 2012-11-16 05:00:00
執行秒數: 509.027序號 檔案名稱 是否完成
1 xxx00378.unl 成功
2 xxx00367.unl 成功
3 xxx00363.unl 成功
4 xxx00317.unl 成功
5 ... |
|
| 回頂端 |
|
|
elleryq
註冊時間: 2007-06-21
文章: 768
第 5 樓
|
|
| 回頂端 |
|
|
Mark123
註冊時間: 2012-06-28
文章: 6
第 6 樓
|
| 發表於: 星期五 十一月 16, 2012 10:48 pm 文章主題: |
|
|
謝謝elleryq回覆,
以下是我改完成的程式碼.
| 代碼: |
Set Dele On && 已經刪除的資料不顯示
Set Safe Off && 檔案IO時不詢問,直接動作
Set Date ymd && 日期格式: yyyy-mm-dd
Set Hours To 24 && 時間為24小時制
Set Century On && 日期格式中,年份�]定為四碼
Set Mark To '-' && 日期分隔符號,例如 2010-11-01
Set enginebehavior 70 && 向下相容foxpro早期版本�{式語法
On Error * && 當有任何錯誤的時候不做任何事, *星號是註解,註解就代表什麼都不做
Close Databases All && 關閉所有�}啟的資料庫
*=MESSAGEBOX(SYS(5)+SYS(2003))
m_date=Date()-1 && 前一天
m_user=Upper(Alltrim(Right(Sys(0),Len(Sys(0))-At('#',Sys(0)))))
m_pcname=Upper(Alltrim(Left(Sys(0),At('#',Sys(0))-1)))
m_prgname='每日FTP下載informix資料庫備份'
sss=Seconds() && 記錄�}始執行的時間
Create Cursor temp01 (功能 c(10),分類 c(4),資料夾 c(100)) && 備份資料夾記錄檔, 用來儲存 backup_init.txt 內容
*APPEND FROM Backup_init.txt DELIMITED WITH _ WITH CHARACTER ,
Append From backup_init.txt Delimited With Character , && 讀取 backup_init.txt 檔案,裡面記錄備份要用的資料夾
*****backup_init.txt 是用來隨時改變備份位置的,請將backup_init.txt2檔案與此�{式放在同一資料夾
*****backup_init.txt 內容如下三列(不含前面5個星號)
*****informix,FTP,/u1/EXPORT/smz.exp/
*****informix,暫存,D:\Backup\informix資料庫\smz.exp
*****informix,目的,E:\Backup\informix資料庫
*=================================================================================================
***** 準備 FTP 連線
***** 宣告 wininet.dll
*** �}啟 internet 連結
Declare Integer InternetOpen In wininet;
string sAgent,;
integer lAccessType,;
string sProxyName,;
string sProxyBypass,;
string lFlags
*** 關閉 internet 連結
Declare Integer InternetCloseHandle In wininet ;
integer hInet
*** 連結 ftp or http
Declare Integer InternetConnect In wininet;
integer hInternetSession,;
string sServerName,;
integer nServerPort,;
string sUsername,;
string sPassword,;
integer lService,;
integer lFlags,;
integer lContext
*** 下載 ftp 檔案
Declare Integer FtpGetFile In wininet;
integer hFtpSession, ;
string lpszRemoteFile,;
string lpszNewFile,;
integer fFailIfExists,;
integer dwFlagsAndAttributes,;
integer dwFlags,;
integer dwContext
*** 取得 ftp 目錄資料
Declare Integer FtpGetCurrentDirectory In wininet;
Integer hftpsession, String @lpszdir, Integer @lpdwcurdir
*** 取得目錄中的第一個檔案名稱
Declare Integer FtpFindFirstFile In wininet;
Integer hftpsession, String lpszsearchfile,;
string @lpfindfiledata, Integer dwflags, Integer dwcontent
*** 找下一個檔案名稱
Declare Integer InternetFindNextFile In wininet;
Integer hfind, String @lpvfinddata
*** 取得檔案日期資訊
Declare Integer FileTimeToSystemTime In kernel32.Dll;
STRING @lpFileTime, String @lpSystemTime
*** 建立本機資料夾
Select temp01
Locate For 功能='informix' And 分類='暫存' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
m_path=Alltrim(資料夾) && 如果找到, 則使用該資料夾備份未壓縮的檔案
Else
m_path='D:\Backup\informix資料庫\smz.exp' && 找不到, 就用預�]的資料夾 (例如: d:\Backup\informix資料庫\smz.exp)
Endif
If !Directory(m_path) && 檢查資料夾是否存在,不存在就建立
Md &m_path && 建立資料夾
Else
m_comm='run del '+m_path+' /q' && 刪除資料夾內的檔案
&m_comm
Endif
Select temp01
Locate For 功能='informix' And 分類='目的'
If Found()
m_path1=Alltrim(資料夾)
Else
m_path1='E:\Backup\informix資料庫' && 備份檔案路徑 (例如: E:\Backup\informix資料庫\)
Endif
If !Directory(m_path1) && 檢查資料夾是否存在,不存在就建立
Md &m_path1 && 建立資料夾
Endif
***** �}始連線
sagent = "vfp7" && 自訂一個名稱(隨便)
sproxyname = 0 && 不使用Proxy server -->vb 不是 chr(0) 是用 null
sproxybypass = 0 && 不回復訊息
lflags = 0 && 預�]值
* �}啟連結 (建立 internet session)
hopen = internetopen (sagent, 1, sproxyname, sproxybypass, lflags)
* �]定登入的使用者名稱
strhost = '10.0.1.99' && 要登入的ftp位�}或名稱
port=21 && ftp 的通訊埠
struser = 'test' && 使用者名稱
strpwd = 'test' && 密碼
************** 連線至 ftp
*!* hFtpSession = InternetConnect (hOpen, strHost, port, strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
hftpsession = internetconnect (hopen, strhost, port, struser, strpwd, 1, 0, 0)
If hftpsession = 0
Return
Endif
*** 下載 ftp 檔案
If hopen>0 And hftpsession>0
lpfindfiledata = Repli (Chr(0), 320) && lpfindfiledata = 320個chr(0)
Select temp01
Locate For 功能='informix' And 分類='FTP' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
ftpdir=Alltrim(資料夾) && FTP Server 的檔案路徑
Else
ftpdir='/u1/EXPORT/smz.exp/' && FTP Server 的檔案路徑
Endif
lcmask=Alltrim(ftpdir)+'*.*'
hfind = ftpfindfirstfile(hftpsession,lcmask,@lpfindfiledata,16,0) && 取得第一個檔案
If hfind>0 && 判斷是否找到第一個檔案
Select 0 && 切換至空的工作區
Create Cursor temp00 (filename c(20),filesize i,filetime T,fileattrib c(100),dl c(4)) && 建立Cursor
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
Insert Into temp00 (filename) Values (m_filename) && 將檔案名稱寫入Cursor
lnfound =1 && 找到的檔案總數累�[, 從一�}始 ,�]為ftpfindfirstfile已經找到第一個檔案
Do While .T. && �}始找尋下一個檔案
If internetfindnextfile (hfind, @lpfindfiledata) <> 1 && 判斷是否找到下一個檔案
Exit && 找不到, 跳出迴圈
Else
lnfound = lnfound + 1 && 找到的檔案總數累�[
m_filename= Alltrim(Substr(lpfindfiledata, 45,250))
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
*** WIN32_FIND_DATA 轉換
lcfiletime=Substr(lpfindfiledata, 21, 8)
lcsystemtime = Repli (Chr(0), 16)
= filetimetosystemtime (@lcfiletime, @lcsystemtime)
wyear = buf2num (lcsystemtime, 0, 2)
wmonth = buf2num (lcsystemtime, 2, 2)
wday = buf2num (lcsystemtime, 6, 2)
whour = buf2num (lcsystemtime, 8, 2)
wminute = buf2num (lcsystemtime, 10, 2)
wsecond = buf2num (lcsystemtime, 12, 2)
Set Date To Mdy
lcdate = Strtran (Str(wmonth,2) + "/" + Str(wday,2) + "/" + Str(wyear,4), " ","0")
lctime = Strtran (Str(whour,2) + ":" + Str(wminute,2) + ":" + Str(wsecond,2), " ","0")
ltresult = Ctot (lcdate + " " + lctime)
Set Date ymd
*** 將檔案名稱寫入Cursor
Insert Into temp00 (filename,filetime) Values (m_filename,ltresult)
Endif
Enddo
Select temp00 && 切換到Cursor
Scan &&將temp00資料表逐筆�]過一次
lpszremotefile=ftpdir+Alltrim(Lower(temp00.filename)) && 來源檔
*Wait Windows notes+'/'+lpszremotefile Nowait && 將檔案名稱顯示在畫面,這是要監看用的,讓你知道正在下載那一個檔案
lpsznewfile=m_path+'\'+Alltrim(Lower(temp00.filename)) && 目的檔
lnresult=ftpgetfile (hftpsession, lpszremotefile, lpsznewfile, 0, 128, 2, 0) && �}始下載
If lnresult>0 && 判斷是否成功, >0成功 ,寫入temp01
Replace dl With '成功' In temp00 && 寫入dl欄位, 供以後判斷成功與否
Else
Replace dl With '失敗' In temp00
Endif
Endscan
Copy To m_path+'\log00' && 記錄檔存放下載記錄 ,D:\Backup\informix資料庫\smz.exp\log00.dbf
Endif
Endif
= internetclosehandle (hopen) && 關閉FTP連線
*=================================================================================================
*** 呼叫WinRAR 壓縮檔案
*If Os()='Windows 6.01' && 取得作業系統是不是 Windows2008R2 64位元版?
Do Case
Case File("C:\Program Files (x86)\winrar\winrar.exe") && 64位元作業系統WinRAR放在此資料夾,公司伺服器Windows2008R2是64位元,所以會有此問題
Set Default To "C:\Program Files (x86)\winrar" && 切換�{式路徑至 C:\Program Files (x86)\winrar
Case File("C:\Program Files\winrar\winrar.exe")
Set Default To "C:\Program Files\winrar" && 切換�{式路徑至C:\Program Files\winrar
Endcase
aaa='run winrar a -m5 '+m_path1+'\smz_'+Dtos(m_date)+'.rar '+m_path && 將命令�]成字串,命令內容是執行DOS模式 ,前面的RUN代表呼叫DOS模式,後面接著winrar命令
&aaa && 巨集替代,執行字串的內�[ (�]就是把字串變成命令執行)
Select filename,filetime,dl From temp00 Order By dl,filename Into Cursor temp88 && 依照下載成功與否排序
***** 寫入SQL
=SQLSetprop(0,"DispLogin",3)
conn9=Sqlstringconnect('DRIVER=SQL Server;SERVER=192.168.1.1;uid=test;PWD=test;DATABASE=test')
If conn9>0
lc_sss=Alltrim(Str(Seconds()-sss,10,3)) && 計算執行秒數
*** 拼湊HTML
aaa="這是自動信件,請勿直接回覆,謝謝!<br>"
aaa=aaa+'<font color="#cc33ff" size="7">本�{式請勿在凌晨01:00~02:00執行,此時informix正在匯出資料庫</font>'
aaa=aaa+"<br>�{式名稱: "+m_prgname
aaa=aaa+"<br>�{式功能: 自動化FTP下載1:00產生的informix資料庫備份檔案,並呼叫WinRAR壓縮"
aaa=aaa+'<br>執行的電腦:'+m_pcname
aaa=aaa+"<br>目前時間: "+Ttoc(Datetime())
aaa=aaa+"<br>執行秒數: "+lc_sss
aaa=aaa+'<table bordercolor="black" border="1">'
aaa=aaa+'<td>序號</td><td>檔案名稱</td><td>檔案時間</td><td>是否完成</td>'
*** 拼湊HTML的列(Row;Record)
Select temp88 && 切換工作區(切換至記憶體中的資料表)
Scan && 針對此資料表做一筆一筆的掃描一遍
If dl='失敗'
aaa=aaa+'<tr BGCOLOR=red>'
Else
aaa=aaa+'<tr>'
Endif
aaa=aaa+'<td>'+Alltrim(Str(Recno()))+'</td>'
aaa=aaa+'<td>'+Alltrim(filename)+'</td>'
aaa=aaa+'<td>'+ttoc(filetime)+'</td>'
aaa=aaa+'<td>'+Alltrim(dl)+'</td>'
aaa=aaa+'</tr>' && 用<tr></tr>區隔一列資料
Endscan
aaa=aaa+'</table><br><br>'
*** 寫入發信機制,排�{發信
=SQLExec(conn9,"insert into 送信整合信件內容 (電腦名稱,比對電腦名稱,�{式名稱,主旨,內容,信件格式) values (?m_pcname,0,?m_prgname,'"+m_prgname+'_'+Dtoc(m_date)+"',?aaa,'html')") && 對SQL執行SQL命令
=SQLDisconnect(conn9)
Endif
Procedure buf2num
Lparameters lcbuffer, lnoffset, lnbytes
* converts N bytes from the buffer into a numeric value
lnresult = 0
For ii=1 To lnbytes
lnresult = lnresult +;
BitLShift(Asc(Substr (lcbuffer, lnoffset+ii, 1)), (ii-1)*8)
Endfor
Return lnresult
Endproc
|
|
|
| 回頂端 |
|
|
Mark123
註冊時間: 2012-06-28
文章: 6
第 7 樓
|
| 發表於: 星期六 十一月 17, 2012 8:36 am 文章主題: |
|
|
補充修改一些,請把上面程式碼 "*** 拼湊HTML" 這段換掉,順便比對本機暫存檔&壓縮檔是否正確
| 代碼: |
*** 拼湊HTML
aaa="這是自動信件,請勿直接回覆,謝謝!<br>"
aaa=aaa+'<font color="#cc33ff" size="7">本�{式請勿在凌晨01:00~02:00執行,此時informix正在匯出資料庫</font>'
aaa=aaa+"<br>�{式名稱: "+m_prgname
aaa=aaa+"<br>�{式功能: 自動化FTP下載1:00產生的股務資料庫備份檔案,並呼叫WinRAR壓縮"
aaa=aaa+'<br>執行的電腦:'+m_pcname
aaa=aaa+"<br>目前時間: "+Ttoc(Datetime())
aaa=aaa+"<br>執行秒數: "+lc_sss
If Fdate(m_path1+'\smz_'+Dtos(m_date)+'.rar ')<>m_date+1 && 比對壓縮檔案日期是否正確,若不正確就以粉紅色底色表示...m_date+1==>�]為凌晨備份前一天資料,所以備份檔案日期會是+1
aaa=aaa+'<font color="#cc33ff" size="7">壓縮檔沒有正確寫入,請檢查</font>'
Endif
aaa=aaa+'<table bordercolor="black" border="1">'
aaa=aaa+'<td>序號</td><td>檔案名稱</td><td>檔案時間</td><td>是否完成</td>'
*** 拼湊HTML的列(Row;Record)
Select temp88 && 切換工作區(切換至記憶體中的資料表)
Scan && 針對此資料表做一筆一筆的掃描一遍
If !File(m_path+'\'+Alltrim(filename)) && 比對檔案是否存在暫存資料夾,不存在就註記:未存
Replace dl With '未存'
Endif
If Fdate(m_path+'\'+Alltrim(filename))<>m_date+1 && 比對暫存檔案日期是否正確,不正確就註記:日錯...m_date+1==>�]為凌晨備份前一天資料,所以備份檔案日期會是+1
Replace dl With '錯日'
Endif
If dl='失敗' Or dl='未存' OR dl='錯日' Or Ttod(filetime)<>m_date+1 && 比對檔案是否有問題
aaa=aaa+'<tr BGCOLOR=red>' && 有問題的,以紅色底色表示
Else
aaa=aaa+'<tr>'
Endif
aaa=aaa+'<td>'+Alltrim(Str(Recno()))+'</td>'
aaa=aaa+'<td>'+Alltrim(filename)+'</td>'
aaa=aaa+'<td>'+Ttoc(filetime)+'</td>'
aaa=aaa+'<td>'+Alltrim(dl)+'</td>'
aaa=aaa+'</tr>' && 用<tr></tr>區隔一列資料
Endscan
aaa=aaa+'</table><br><br>'
|
我用這程式每天備份UNIX&Linux各式資料,也可以備份Lunix的Oracle的DBF檔&Archive檔,還有Oracle用RMAN備份的資料,然後用iSCSI設備做異地備份,全部用Foxpro搞定
現在可以比對檔案日期時間,跟客戶&廠商溝通的檔案,程式改FTP上傳,然後比對是否正確,一切全自動,只要每天收信就可以全盤了解狀況.
謝謝ckp6250&elleryq相助 |
|
| 回頂端 |
|
|
Mark123
註冊時間: 2012-06-28
文章: 6
第 8 樓
|
| 發表於: 星期三 十一月 21, 2012 8:37 am 文章主題: |
|
|
這幾天排程測試發現小小問題,修正如下:
1. temp88這個Cursor加Readwrite參數,改成可讀寫,這樣才可以改變欄位的值
2. 程式少下載第一個找到的檔案(ftpfindfirstfile檔案被遺忘了),也忘記轉換filetime. (sno欄位就是在抓遺漏的檔案firstfile)
| 代碼: |
Set Dele On && 已經刪除的資料不顯示
Set Safe Off && 檔案IO時不詢問,直接動作
Set Date ymd && 日期格式: yyyy-mm-dd
Set Hours To 24 && 時間為24小時制
Set Century On && 日期格式中,年份�]定為四碼
Set Mark To '-' && 日期分隔符號,例如 2010-11-01
Set enginebehavior 70 && 向下相容foxpro早期版本�{式語法
On Error * && 當有錯誤時不做任何事, *星號是註解,註解就代表什麼都不做
Close Databases All && 關閉所有�}啟的資料庫
*=MESSAGEBOX(SYS(5)+SYS(2003)) &&監看目前�{式執行的路徑,64位元版作業系統要注意排�{�]定"�}始位置",�]為預�]在C:\WINDOWS\SYSTEM32
m_date=Date()-1 && 前一天
m_user=Upper(Alltrim(Right(Sys(0),Len(Sys(0))-At('#',Sys(0))))) && 本機登入的使用者
m_pcname=Upper(Alltrim(Left(Sys(0),At('#',Sys(0))-1))) && 本機電腦名稱
m_prgname='每日FTP下載informix資料庫備份'
m_stime=Datetime() && �{式�}始時間
sss=Seconds() && 記錄�}始執行的時間
Create Cursor temp01 (功能 c(10),分類 c(4),資料夾 c(100)) && 備份資料夾記錄檔, 用來儲存 backup_init.txt 內容
*APPEND FROM Backup_init.txt DELIMITED WITH _ WITH CHARACTER ,
Append From backup_init.txt Delimited With Character , && 讀取 backup_init.txt 檔案,裡面記錄備份要用的資料夾
*****backup_init.txt 是用來隨時改變備份位置的,請將backup_init.txt2檔案與此�{式放在同一資料夾
*****backup_init.txt 內容如下三列(不含前面5個星號)
*****informix,FTP,/u1/EXPORT/smz.exp/
*****informix,暫存,D:\Backup\informix資料庫\smz.exp
*****informix,目的,F:\Backup\informix資料庫
*=================================================================================================
***** 準備 FTP 連線
***** 宣告 wininet.dll
*** �}啟 internet 連結
Declare Integer InternetOpen In wininet;
string sAgent,;
integer lAccessType,;
string sProxyName,;
string sProxyBypass,;
string lFlags
*** 關閉 internet 連結
Declare Integer InternetCloseHandle In wininet ;
integer hInet
*** 連結 ftp or http
Declare Integer InternetConnect In wininet;
integer hInternetSession,;
string sServerName,;
integer nServerPort,;
string sUsername,;
string sPassword,;
integer lService,;
integer lFlags,;
integer lContext
*** 下載 ftp 檔案
Declare Integer FtpGetFile In wininet;
integer hFtpSession, ;
string lpszRemoteFile,;
string lpszNewFile,;
integer fFailIfExists,;
integer dwFlagsAndAttributes,;
integer dwFlags,;
integer dwContext
*** 取得 ftp 目錄資料
Declare Integer FtpGetCurrentDirectory In wininet;
Integer hftpsession, String @lpszdir, Integer @lpdwcurdir
*** 取得目錄中的第一個檔案名稱
Declare Integer FtpFindFirstFile In wininet;
Integer hftpsession, String lpszsearchfile,;
string @lpfindfiledata, Integer dwflags, Integer dwcontent
*** 找下一個檔案名稱
Declare Integer InternetFindNextFile In wininet;
Integer hfind, String @lpvfinddata
*** 取得檔案日期資訊
Declare Integer FileTimeToSystemTime In kernel32.Dll;
STRING @lpFileTime, String @lpSystemTime
*** 建立本機資料夾,並記錄暫存與目的資料夾資訊
Select temp01
Locate For 功能='informix' And 分類='暫存' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
m_path=Alltrim(資料夾) && 如果找到, 則使用該資料夾備份未壓縮的檔案
Else
m_path='D:\Backup\informix資料庫\smz.exp' && 找不到, 就用預�]的資料夾 (例如: d:\Backup\informix資料庫\smz.exp)
Endif
If !Directory(m_path) && 檢查資料夾是否存在,不存在就建立
Md &m_path && 建立資料夾
Else
m_comm='run del '+m_path+' /q' && 刪除資料夾內的檔案
&m_comm
Endif
Select temp01
Locate For 功能='informix' And 分類='目的'
If Found()
m_path1=Alltrim(資料夾)
Else
m_path1='F:\Backup\informix資料庫' && 備份檔案路徑 (例如: F:\Backup\informix資料庫\), F:磁碟機是iSCSI遠端硬碟
Endif
If !Directory(m_path1) && 檢查資料夾是否存在,不存在就建立
Md &m_path1 && 建立資料夾
Endif
***** �}始連線
sagent = "vfp7" && 自訂一個名稱(隨便)
sproxyname = 0 && 不使用Proxy server -->vb 不是 chr(0) 是用 null
sproxybypass = 0 && 不回復訊息
lflags = 0 && 預�]值
* �}啟連結 (建立 internet session)
hopen = internetopen (sagent, 1, sproxyname, sproxybypass, lflags)
* �]定登入的使用者名稱
strhost = '10.0.1.99' && 要登入的ftp位�}或名稱
port=21 && ftp 的通訊埠
struser = 'test' && 使用者名稱
strpwd = 'test' && 密碼
************** 連線至 ftp
*!* hFtpSession = InternetConnect (hOpen, strHost, port, strUser, strPwd, INTERNET_SERVICE_FTP, 0, 0)
hftpsession = internetconnect (hopen, strhost, port, struser, strpwd, 1, 0, 0)
If hftpsession = 0
Return && 無法連線就退出�{式
Endif
*** 下載 ftp 檔案
If hopen>0 And hftpsession>0
lpfindfiledata = Repli (Chr(0), 320) && lpfindfiledata = 320個chr(0)
Select temp01
Locate For 功能='informix' And 分類='FTP' && 找尋 backup_init.txt 內指定的來源資料夾
If Found()
ftpdir=Alltrim(資料夾) && FTP Server 的檔案路徑
Else
ftpdir='/u1/EXPORT/smz.exp/' && FTP Server 的檔案路徑
Endif
*** 先取得檔案資訊寫入Cursor temp00
lcmask=Alltrim(ftpdir)+'*.*'
hfind = ftpfindfirstfile(hftpsession,lcmask,@lpfindfiledata,16,0) && 取得第一個檔案
If hfind>0 && 判斷是否找到第一個檔案
Select 0 && 切換至空的工作區
Create Cursor temp00 (sno i,filename c(20),filesize i,filetime T,fileattrib c(100),dl c(4)) && 建立Cursor
m_filename= Alltrim(Substr(lpfindfiledata, 45,250))
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
*** WIN32_FIND_DATA 轉換
lcfiletime=Substr(lpfindfiledata, 21, 8)
lcsystemtime = Repli (Chr(0), 16)
= filetimetosystemtime (@lcfiletime, @lcsystemtime)
wyear = buf2num (lcsystemtime, 0, 2)
wmonth = buf2num (lcsystemtime, 2, 2)
wday = buf2num (lcsystemtime, 6, 2)
whour = buf2num (lcsystemtime, 8, 2)
wminute = buf2num (lcsystemtime, 10, 2)
wsecond = buf2num (lcsystemtime, 12, 2)
Set Date To Mdy
lcdate = Strtran (Str(wmonth,2) + "/" + Str(wday,2) + "/" + Str(wyear,4), " ","0")
lctime = Strtran (Str(whour,2) + ":" + Str(wminute,2) + ":" + Str(wsecond,2), " ","0")
ltresult = Ctot (lcdate + " " + lctime)
Set Date ymd
Insert Into temp00 (sno,filename,filetime) Values (1,m_filename,ltresult) && 將檔案名稱寫入Cursor
lnfound =1 && 找到的檔案總數累�[, 從一�}始 ,�]為ftpfindfirstfile已經找到第一個檔案
Do While .T. && �}始找尋下一個檔案
If internetfindnextfile (hfind, @lpfindfiledata) <> 1 && 判斷是否找到下一個檔案
Exit && 找不到, 跳出迴圈
Else
lnfound = lnfound + 1 && 找到的檔案總數累�[
m_filename= Alltrim(Substr(lpfindfiledata, 45,250))
If At(Chr(0), m_filename) <> 0
m_filename = Substr (m_filename, 1, At(Chr(0), m_filename)-1)
Endif
*** WIN32_FIND_DATA 轉換
lcfiletime=Substr(lpfindfiledata, 21, 8)
lcsystemtime = Repli (Chr(0), 16)
= filetimetosystemtime (@lcfiletime, @lcsystemtime)
wyear = buf2num (lcsystemtime, 0, 2)
wmonth = buf2num (lcsystemtime, 2, 2)
wday = buf2num (lcsystemtime, 6, 2)
whour = buf2num (lcsystemtime, 8, 2)
wminute = buf2num (lcsystemtime, 10, 2)
wsecond = buf2num (lcsystemtime, 12, 2)
Set Date To Mdy
lcdate = Strtran (Str(wmonth,2) + "/" + Str(wday,2) + "/" + Str(wyear,4), " ","0")
lctime = Strtran (Str(whour,2) + ":" + Str(wminute,2) + ":" + Str(wsecond,2), " ","0")
ltresult = Ctot (lcdate + " " + lctime)
Set Date ymd
*** 將檔案名稱寫入Cursor
Insert Into temp00 (sno,filename,filetime) Values (lnfound,m_filename,ltresult) && 將檔案名稱寫入Cursor
Endif
Enddo
*** �}始下載
Select temp00 && 切換到Cursor
Scan &&將temp00資料表逐筆�]過一次
lpszremotefile=ftpdir+Alltrim(Lower(temp00.filename)) && 來源檔
*Wait Windows notes+'/'+lpszremotefile Nowait && 將檔案名稱顯示在畫面,這是要監看用的,讓你知道正在下載那一個檔案
lpsznewfile=m_path+'\'+Alltrim(Lower(temp00.filename)) && 目的檔
lnresult=ftpgetfile (hftpsession, lpszremotefile, lpsznewfile, 0, 128, 2, 0) && �}始下載
If lnresult>0 && 判斷是否成功, >0成功 ,寫入temp01
Replace dl With '成功' In temp00 && 寫入dl欄位, 供以後判斷成功與否
Else
Replace dl With '失敗' In temp00
Endif
Endscan
Copy To m_path+'\log00' && 記錄檔存放下載記錄 ,D:\Backup\informix資料庫\smz.exp\log00.dbf
Endif
Endif
= internetclosehandle (hopen) && 關閉FTP連線
*=================================================================================================
*** 呼叫WinRAR 壓縮檔案
*If Os()='Windows 6.01' && 取得作業系統是不是 Windows2008R2 64位元版?
Do Case
Case File("C:\Program Files (x86)\winrar\winrar.exe") && 64位元作業系統WinRAR放在此資料夾,公司伺服器Windows2008R2是64位元,所以會有此問題
Set Default To "C:\Program Files (x86)\winrar" && 切換�{式路徑至 C:\Program Files (x86)\winrar
Case File("C:\Program Files\winrar\winrar.exe")
Set Default To "C:\Program Files\winrar" && 切換�{式路徑至C:\Program Files\winrar
Endcase
aaa='run winrar a -m5 '+m_path1+'\smz_'+Dtos(m_date)+'.rar '+m_path && 將命令�]成字串,命令內容是執行DOS模式 ,前面的RUN代表呼叫DOS模式,後面接著winrar命令
&aaa && 巨集替代,執行字串的內�[ (�]就是把字串變成命令執行)
Select filename,filetime,dl,sno From temp00 Order By dl,filetime Into Cursor temp88 Readwrite && Readwrite參數是讓此Cursor可讀寫
***** 寫入SQL
=SQLSetprop(0,"DispLogin",3)
conn9=Sqlstringconnect('DRIVER=SQL Server;SERVER=192.168.1.1;uid=test;PWD=test;DATABASE=test')
If conn9>0
lc_sss=Alltrim(Str(Seconds()-sss,10,3)) && 計算執行秒數
*** 拼湊HTML
aaa="這是自動信件,請勿直接回覆,謝謝!<br>"
aaa=aaa+'<font color="#cc33ff" size="7">本�{式請勿在凌晨01:00~02:00執行,此時informix正在匯出資料庫</font>'
aaa=aaa+"<br>�{式名稱: "+m_prgname
aaa=aaa+"<br>�{式功能: 自動化FTP下載1:00產生的informix資料庫備份檔案,並呼叫WinRAR壓縮"
aaa=aaa+'<br>執行的電腦:'+m_pcname
aaa=aaa+"<br>�}始時間: "+Ttoc(m_stime)
aaa=aaa+"<br>完成時間: "+Ttoc(Datetime())
aaa=aaa+"<br>執行秒數: "+lc_sss
If !File(m_path1+'\smz_'+Dtos(m_date)+'.rar ') Or Fdate(m_path1+'\smz_'+Dtos(m_date)+'.rar ')<>m_date+1 && 比對壓縮檔案日期是否正確,若不正確就以粉紅色底色表示...m_date+1==>�]為凌晨備份前一天資料,所以備份檔案日期會是+1
aaa=aaa+'<br><font color="#cc33ff" size="7">壓縮檔沒有正確寫入,請檢查</font>'
Else
aaa=aaa+'<br>已產生壓縮檔:'+m_path1+'\smz_'+Dtos(m_date)+'.rar '
Endif
aaa=aaa+"<br>�{式�}發人員: Mark"
aaa=aaa+'<table bordercolor="black" border="1">'
aaa=aaa+'<td>序號</td><td>FTP檔案序號</td><td>檔案名稱</td><td>檔案時間</td><td>是否完成</td>'
*** 拼湊HTML的列(Row;Record)
Select temp88 && 切換工作區(切換至記憶體中的資料表) ,temp88有下Readwrite參數,可讀寫
Scan && 針對此資料表做一筆一筆的掃描一遍
If !File(m_path+'\'+Alltrim(filename)) && 比對檔案是否存在暫存資料夾,不存在就註記:未存
Replace dl With '未存' && 將'未存'寫入dl欄位
Endif
If Fdate(m_path+'\'+Alltrim(filename))<>m_date+1 && 比對暫存檔案日期是否正確,不正確就註記:日錯...m_date+1==>�]為凌晨備份前一天資料,所以備份檔案日期會是+1
Replace dl With '錯日'
Endif
If dl='失敗' Or dl='未存' Or dl='錯日' Or Ttod(filetime)<>m_date+1 && 比對檔案是否有問題
aaa=aaa+'<tr BGCOLOR=red>' && 有問題的,以紅色底色表示
Else
aaa=aaa+'<tr>'
Endif
aaa=aaa+'<td>'+Alltrim(Str(Recno()))+'</td>'
aaa=aaa+'<td>'+Alltrim(Str(sno))+'</td>'
aaa=aaa+'<td>'+Alltrim(filename)+'</td>'
aaa=aaa+'<td>'+Ttoc(filetime)+'</td>'
aaa=aaa+'<td>'+Alltrim(dl)+'</td>'
aaa=aaa+'</tr>' && 用<tr></tr>區隔一列資料
Endscan
aaa=aaa+'</table><br><br>'
*** 寫入發信機制,排�{發信
=SQLExec(conn9,"insert into 送信整合信件內容 (電腦名稱,比對電腦名稱,�{式名稱,主旨,內容,信件格式) values (?m_pcname,0,?m_prgname,'"+m_prgname+'_'+Dtoc(m_date)+"',?aaa,'html')") && 對SQL執行SQL命令
=SQLDisconnect(conn9)
Endif
Procedure buf2num
Lparameters lcbuffer, lnoffset, lnbytes
* converts N bytes from the buffer into a numeric value
lnresult = 0
For ii=1 To lnbytes
lnresult = lnresult +;
BitLShift(Asc(Substr (lcbuffer, lnoffset+ii, 1)), (ii-1)*8)
Endfor
Return lnresult
Endproc
|
|
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
