VFP 愛用者社區

[puby]

請教各位大大，有無可以將圖片插入至 EXCEL的方法？

例如，我要將 c:\temp\sample1.jpg 插入至 c:\temp\Sheet1\tesl.xls 的 sheet1 C3 。

我已經很認真爬文了，但沒有找到，因此勞煩各位大大幫忙，謝謝。

[syntech]

LogoFile = "C:\LOGO.JPG"
oleEXCEL.ActiveWorkbook.Sheets(1).Shapes.AddPicture(LogoFile, .T., .T.,0, 15, 75, 44)


其它自己處理.
貼圖是看XY,不是看欄位位置

[chilin]

TFA=[c:\temp\test.xls]
PIC=[c:\temp\sample1.jpg]

IF NOT FILE(TFA)
RETURN
ENDIF
OEXCEL = CREATE("EXCEL.APPLICATION")
OEXCEL .VISIBLE=.F.
OEXCEL.WORKBOOKS.OPEN(TFA)

*OEXCEL.WORKSHEETS("SHEET1").ACTIVATE &&最好不要用SHEETS名稱，因為EXCEL2010繁體版的SHEETS名稱為中文[工作表1]，會造成程式錯誤
OEXCEL.WORKSHEETS(1).ACTIVATE &&SHEETS ID是依序由左至右排列
OEXCEL.CELLS(3,3).SELECT
OEXCEL.ACTIVESHEET.PICTURES.INSERT(PIC).SELECT
=EXCEL_PHOTO(3,3,100,0,1.5,3) &&圖片大小位置微調 【高度:100,寬度:0(表示依高度比例縮放),往下調1.5,往右調3】

OEXCEL.CELLS(1,1).SELECT
OEXCEL.ACTIVEWORKBOOK.SAVE
OEXCEL.WORKBOOKS.CLOSE
OEXCEL.QUIT
RELEASE OEXCEL


*************************
FUNCTION EXCEL_PHOTO
*************************
PARAMETER P_Y,P_X,P_HEIGHT,P_WIDTH,P_TOP,P_LEFT
T_PIC="_"+STRTRAN(TIME(),":","")+"_"+RIGHT(SYS(2015),7) &&EXCEL物件名稱不能使用"-"符號
oExcel.Selection.Name = T_PIC
WITH oExcel.ActiveSheet.Pictures(T_PIC)
.Left = oExcel.ActiveSheet.Cells(P_Y,P_X).Left
.Top = oExcel.ActiveSheet.Cells(P_Y,P_X).Top
ENDWITH
*********************
WITH oExcel.Selection.ShapeRange
.LockAspectRatio =.T.
IF NOT EMPTY(P_HEIGHT)
.Height = P_HEIGHT
ENDIF
IF NOT EMPTY(P_WIDTH) AND .Width>P_WIDTH
.Width = P_WIDTH
ENDIF
IF NOT EMPTY(P_TOP)
.IncrementTop(P_TOP)
ENDIF
IF NOT EMPTY(P_LEFT)
.IncrementLeft(P_LEFT)
ENDIF
ENDWITH
ENDFUNC