VFP 愛用者社區

朱育興 · 註冊時間: 2003-08-25 文章: 661 來自: 台中市大里區 第 1 樓

[轉貼]在VFP中控制TWAIN設備 webcam / 視訊 / 網路攝影機

本篇來自童心未泯軟體開發工作室

SiBill翻譯 http://www.gdjyc.com
想要在你的應用程式中驅動一個掃瞄儀或攝像頭嗎？這裏將告訴你怎麼做。
我們最近在編寫一個用來處理出席一個國際性會議的代表的註冊的Visual Foxpro應用程式。客戶希望能夠獲取每個到會的代表的照片，並且也要儲存代表名片的掃瞄圖。因為有大量的代表，攝影和掃瞄過程必須盡可能的流暢和避免發生問題。允許操作者對連接到他們的PC上的數碼相機或者掃瞄儀的控制就顯得非常重要。

在這篇文章中，我們將告訴你我們是如何著手這個設計方案的。在這個過程中我們採用的是相當普通的而沒有指定任何特殊的掃瞄設備。如果你希望的話你可以毫不困難的將我們的技巧應用到你自己的應用程式中。

第一步：選擇硬件
對於攝影，我們排除標準數碼相機，主要因為我們沒有找到一個可以直接從數碼相機攝取並傳送圖像到我們的應用程式的的方法。我們選擇的是一個菲利浦ToUcam網絡攝像頭。這種設備更多地被用於視頻會議和作為一個在線的網絡攝像頭，但他也可以捕捉單幀的快照。它有TWAIN適應性的優勢並且可以被PC完全的控制。

掃瞄儀我們採用的是一個Targus迷你名片掃瞄儀。就像它的名字一樣，它是專門設計用來掃瞄名片的。和攝像頭一樣，它也具有TWAIN適應性。

雖然我們樂於推薦這兩種設備，其實幾乎所有的網絡攝像頭和掃瞄儀都能夠達到我們的要求。本文中我們列出的代碼可以從任何具有TWAIN適應性設備中捕捉圖片。

然後是軟體
有很多軟體產品可用來讓你在程式時驅動TWAIN設備。我們選擇的是來自Dosadi的EZTWAIN。我們採用此產品是基於以下原因：

易於程式。只有大約半打的函數呼叫需要我們操心。
易於分發。因為他是一個DLL，這就勝於一個ActiveX控制項，我們不需要為在使用者的系統中註冊它而操心。
低成本。根據你的需要和你編寫的應用程式的類型，價格在免費到US$200之間。
可以從產品的作者Spike McLarty那裏獲得極好的支援。
聲明你的函數
EZTWAIN DLL有超過70個函數，但是對於絕大部分應用程式你只需要用到其中的七八個。這裏有幾個比較常用的函數的聲明：

DECLARE INTEGER TWAIN_SelectImageSource ;
IN Eztw32.DLL INTEGER hWnd
DECLARE INTEGER TWAIN_GetSourceList ;
IN Eztw32.dll
DECLARE INTEGER TWAIN_GetNextSourceName ;
IN Eztw32.dll STRING @cSourceName
DECLARE INTEGER TWAIN_OpenSource ;
IN Eztw32.DLL STRING cSourceName
DECLARE INTEGER TWAIN_AcquireNative ;
IN Eztw32.DLL INTEGER nAppWind, INTEGER nPixelTypes
DECLARE INTEGER TWAIN_WriteNativeToFilename ;
IN Eztw32.DLL INTEGER nDIB, STRING cFilename
DECLARE INTEGER TWAIN_FreeNative ;
IN Eztw32.DLL INTEGER nDIB
DECLARE INTEGER TWAIN_SetMultiTransfer ;
IN Eztw32.dll INTEGER nFlag
捕捉圖像
如果你只安裝了一個TWAIN設備，只需要呼叫TWAIN_AcquireNative()就可以捕捉圖像。此函數將啟動捕捉進程。當它執行完畢後，圖像將以設備無關的位圖(DIB)格式存在於記憶體中。該函數有兩個整形參數：在大多數情況下他們的值都是0。它傳回的是圖像的控制碼。

在我們使用ToUcam網絡攝像頭的情況下，呼叫TWAIN_AcquireNative()啟動攝像頭的預覽視窗。他顯示一個連續的圖像流。在任何情況下，使用者可以點擊捕捉按鈕取得圖像。

一旦 DIB 圖像被放入記憶體，你可以呼叫TWAIN_WriteNativeToFilename()來將它寫入你指定的檔案。預設情況下，它將是一個BMP檔案，但是也支援其它格式。你可以傳遞兩個參數到此函數：TWAIN_AcquireNative()傳回的DIB控制碼，還有目標檔案的有效檔案名。

最後，呼叫TWAIN_FreeNative()來清除DIB圖像。如果你沒有這麼做，你很快將會記憶體不足。

下面是我們用來從網絡攝像頭獲取圖像的代碼：

LOCAL lcFile, lnImageHandle, lnReply
lcFile = "c:\test\test_image.bmp"
* 獲取圖像
lnImageHandle = TWAIN_AcquireNative(0,0)
* 寫入到磁碟檔案
lnReply = ;
TWAIN_WriteNativeToFilename(lnImageHandle,lcFile)

* 釋放圖像控制碼
TWAIN_FreeNative(lnImageHandle)

* 檢測錯誤
IF lnReply = 0
* 圖像被成功寫入檔案
ELSE
* 某些東西出現錯誤
ENDIF
注意，TWAIN_WriteNativeToFilename()的回復將告訴你檔案是否成功寫入。可是，如果捕捉過程正確就算沒有捕捉到圖像它將不會告訴你——而捕捉過程可能因為某些原因而失敗，或者它可能會被使用者取消了。有一個方法可以進行測試，那就是檢查最終檔案的大小：如果大小為0，那麼就是備有捕捉到圖像。

多個設備
上面的代碼將從任何一個你已經安裝的TWAIN設備中捕捉圖片。如果你安裝攝像頭之前還有一個掃瞄儀，那麼代碼將啟動掃瞄進程並儲存被掃瞄的圖像。

但是要如何才能從同一台PC中操縱兩台捕捉設備呢？這就是我們的應用程式中的情況，相同的使用者需要同時控制攝像頭和名片掃瞄儀。

預設情況下，TWAIN_AcquireNative()將從它找到的第一台TWAIN設備中進行捕捉。但是，EZTWAIN DLL有一個函數叫做TWAIN_SelectImageSource()，它可以讓使用者選擇不同的捕捉設備。當你呼叫這個函數（通常用0作為參數），使用者將看到標準TWAIN選擇來源對話方塊。如果使用者取消對話方塊或者沒有安裝捕捉設備函數將傳回0，否則傳回1。

在我們的實際情況中，我們不希望使用者看到這個對話方塊。因為我們的應用程式對於攝像頭和名片掃瞄儀都有特定的命令按鈕進行選擇，我們不希望在程式以外選擇設備。

我們的做法是，使用兩個另外函數：先用TWAIN_GetSourceList()將設備名列表讀取到EZTWAIN的記憶體中；然後用TWAIN_GetNextSourceName()從列表中獲得下一個設備。在呼叫一次TWAIN_GetSourceList()之後，重複呼叫TWAIN_GetNextSourceName()直到它傳回0，表示列表中沒有其他的名稱。

作為範例，這裏有一段代碼可以用來把可用的設備名裝載到組合框中：

LOCAL lcSource, lnReply

* 獲取設備列表到記憶體
TWAIN_GetSourceList()

lcSource = SPACE(255)
DO WHILE .T.
* 獲取下一個設備名
lnReply = TWAIN_GetNextSourceName(@lcSource)
IF lnReply = 0
* 沒有更多的來源設備名
EXIT
ENDIF

* 消除尾隨空格等等
lcSource = ;
LEFT(lcSource,AT(CHR(0),lcSource)-1)

* 增加到組合框
THISFORM.cboDevices.AddItem(lcSource)
ENDDO
一旦你知道來源的名稱，你可以將它傳遞到TWAIN_OpenSource()函數。呼叫TWAIN_AcquireNative()確定下一個來源。

預設情況下，TWAIN_AcquireNative()將在捕捉完成後關閉捕捉來源。所以，如果你有多個設備，你將需要在每次呼叫TWAIN_AcquireNative()之前先呼叫TWAIN_OpenSource()。不過，開啟捕捉來源是比較費時的。根據不同的設備，在捕捉設備能夠啟動之前使用者可能需要等待幾秒鐘。

一種折中的辦法，你可以呼叫TWAIN_SetMultiTransfer(1)來告訴EZTWAIN同意捕捉來源保持開啟狀態。這種情況下，當你需要切換到不同的來源時你只需要呼叫TWAIN_OpenSource()。我們也試著這麼做，但是，我們發現ToUcam攝像頭的預覽視窗在整個過程中總是逗留在螢幕上，而且在我們自己的應用程式視窗之上。這使我們的應用程式視窗有一部分被遮擋住。基於這個原因，我們選擇不讓來源保持開啟狀態。

更進一步
在此文章中，我們試著讓你體驗一下EZTWAIN DLL。這是一個非常能幹的工具，除了我們這裏介紹的函數之外還有很多功能。如果你需要在Visual Foxpro應用程式中控制一個或多個TWAIN設備，何不不下載一個評估版然後資及探索一下？

關於EZTWAIN和其他TWAIN相關產品的訊息，或者想下載這個DLL的評估版，請存取http://www.dosadi.com/。

（下面是相關產品的廣告，本來不想翻譯的，但是為了保持完整性還是翻譯一下吧。）

如果你想知道更多關於菲利浦ToUcam網絡攝像頭的訊息：

存取菲利浦網站，在 http://www.pcstuff.philips.com/。
或從Amazon.com購買（價格大約在$30；僅限於美國消費者）。
或者從Amazon.co.uk購買（價格大約在¡ê28.99；僅限於英國和愛爾蘭消費者）。
Targus 名片掃瞄儀的價格大約在US$125：

從Amazon.com購買（價格大約在$30；僅限於美國消費者）。
或存取 http://www.targus.com/ 獲取本地供應商的詳細訊息。
麥克·劉易斯咨詢有限公司。2003年二月

kmkna1103 · 發表於: 星期二八月 18, 2015 4:22 pm 文章主題:

我產生出來的圖檔畫面都是黑的不知道是什麼問題，有人知道嗎?

kmkna1103 · 發表於: 星期四八月 20, 2015 3:44 pm 文章主題:

問題解決了，NB內建的鏡頭確實都無法抓到影像，用外接的就行了。

kmkna1103 · 發表於: 星期四九月 10, 2015 3:32 pm 文章主題:

如果呼叫出視窗後不去選擇圖檔的話直接按取消整個程式會當掉，請問是否有人使用遇到過這個問題。