VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

資料來源：foxtalk 2001年4月刊

報表編寫技巧第三部分

作者：Cathy Pountney
譯者：fbilo
譯文出自：foxer資料站（http://fbilo.myrice.com）
___________________________________________________________________
前言：
這個月，Cathy Pountney 繼續展示更多的報表編寫技巧。這一次，她關心的焦點是在你的報表中使用變數和計算的大量途徑，包括當組們被拆分到多頁的情況下怎樣在你的報表上列印“繼續...”這樣的事例。她還解釋了怎樣完成如強制一個組從奇數頁開始的困難任務。

正文：
通過過去這幾個月來我收到的Email判斷，你們中的許多人認爲這個報表編輯系列很有意義，所以我非常高興！FoxPro 團體一直是一個樂於共用資訊和互相幫助的團體。我清楚我已經作爲接受的一方很多、很多、很多——我說過很多了吧？——次了。最終能夠回饋給大家的感覺非常的棒。

這個月，我將爲你展示怎樣使用簡單報表變數和計算，例如組的小計和總計。我還將爲你展示怎樣使用複雜變數和計算，例如在組的小計和帶區總計中有條件的包含特定資訊。然後我將爲你展示怎樣處理非常困難的任務：強制組從偶數頁開始。我確信一旦你學會了這些新的技巧，你將能夠爲你的用戶建立令人生畏的報表。也許你甚至還能做的更好！

那麽，讓我們開始吧。可以從WWW.pinnaclepublishing.com/ft 下載的源代碼文件包含著組合了這些技巧中的每一個的工作示例。你可以查看Readme.TXT文件，裏面包括哪個文件演示哪個技巧的列表。

報表變數和計算

FoxPro 的報表編輯器擁有動態使用變數和計算的能力。某些程式師儘量避免這麽做而堅持在運行報表前自己準備資料的習慣，包括進行計算。原因是與其他型式的輸出相比，你的代碼更加靈活。一旦資料被準備好了，它就是一個發送結果到一個速算表而不是FoxPro 報表引擎的快速更動。如果在你的報表中有變數和計算，更動將變得非常的複雜。

那就是說，我將在大多數我設計的報表上繼續使用變數和計算。有些時候我預先準備資料，但不常這麽做。我無法讓自己相信建立一個與當前表擁有同樣的50000個記錄、以及擁有一個額外的簡單求和或者統計功能的欄位的臨時表是有價值的。我知道FoxPro是快速的，但是當我在開發的時候，我所關心的主要問題中的一個是爲我的用戶提供的性能，而在建立游標的時候讓用戶等待只會讓我相信選錯了路。所以選擇哪個方法會根據我正在設計的報表的情況和需要來決定。

一個簡單的例子

報表變數和計算非常容易使用。我將通過一個客戶列表的例子來爲你展示它有多麽的容易，這個例子中要爲頁上面的每個細節記錄（客戶）列印一個行號，每一頁都從頂端的行 #1 開始。從建立一個快速報表開始，在它的細節帶區中包含客戶的資訊。下一步，從功能表欄中選擇“報表”，然後從下拉功能表中選擇“變數...”。在 FoxPro 2.x中，下一步應該是選擇“Add”按鈕以爲你正在添加的新變數打開變數定義對話方塊。在 VFP 中，它的工作方式有點不同。你從功能表中選擇了“變數...”後馬上就打開了報表變數定義對話方塊，而滑鼠游標已定位在變數列表中以讓你輸入一個新的變數名。無論你在使用哪個版本的FoxPro，只管輸入你正在建立的變數名。我在我的例子中用的是“nLine”。

你需要做的下一件事情是解釋你想要在變數中儲存什麽東西。這是通過“要儲存的值”和計算選項來做到的。對於這個簡單的計算行數的例子，在“要儲存的值”欄位中輸入數位“1”，並從可用的計算功能中選擇“計數”選項。這是告訴報表編輯器對它處理的每一個記錄增大這個變數。

需要設置的最後一件事情是那個 Reset 值。因爲在這個例子裏需要在每一頁的開始讓計數器 Reset 爲 1，從“重置”選項中選擇“頁尾”。這告訴報表編輯器，當它完成一頁的時候把這個變數重定爲0。現在你已經把這個變數設置好了，你可以在細節帶區中放入一個域物件，並使用你的變數名作爲運算式。就這麽簡單！

關於計算的更多內容

報表計算的另一個常見的用途是建立組小計和報表總計。同樣對剛剛提到的客戶清單示例進行工作，我將爲你演示怎樣給這個報表添加一個新的列來爲每個客戶顯示銷售額數字。並且，爲了使它有趣些，我將讓你建立一個組，在每次當公司名稱的第一個字母改變時分隔，這樣你可以爲每個組列印一個小計，並在報表的末尾列印一個總計。

這個例子不需要使用報表標量，但它確實需要一個計算。通過給報表的細節帶區添加一個新的域控制項來列印銷售額數字。在運算式中輸入“Sales”(銷售額)，在我的例子中它是客戶表的Sales欄位名。下一步，用下面的運算式給報表添加一個組以當每次公司名稱的第一個字母改變的時候強制分隔：

LEFT(comp_name, 1)

現在你已經建立了一個組，你可以在組注腳帶區中建立小計了。首先調整帶區的高度以能放入銷售額數字。接著，使用你之前添加到細節帶區中的同一個控制項，把它添加到報表的組注腳帶區中去（你可以剪切和粘貼它）。一旦添加好了，雙擊新的控制項來打開報表運算式對話方塊，這樣你就可以設置相應的計算。在 FoxPro 2.x 中，要選中計算單選框來打開計算欄位對話方塊。在VFP 中，選擇計算按鈕來調用同一個對話方塊。

注意那個重置選項現在已經被設置到你剛剛建立的組裏面去了，既然這個物件現在變成了放在組注腳帶區裏面，FoxPro 也足夠聰明得能搞清這一點，甚至可能更好，每次當組改變的時候你將需要讓計算被重置。這就是你需要爲這個例子所做的東西，所以你可以讓那個欄位留下來。但在關閉對話方塊之前，你確實需要選中求和選項。

現在你在報表上已經有了一個小計，你還需要在報表的末尾添加一個總計。這是通過首先建立一個總結帶區來做到的。當你建立了總結帶區以後，隨便從細節帶區還是組帶區拷貝Sales（銷售額）控制項並把它放到總結帶區裏面。使用前面細述的同樣方法，把這個控制項的計算改爲求和、把重置改爲在報表末尾。運行這個報表，你將看到所有的A們，後面跟著一個小計；然後是B們和它們的小計，等等、等等，直到你到了報表的末尾，你在那裏將看到一個總計。

複雜變數和計算

既然你已經有了怎樣在報表中使用變數和計算的基本知識，是時候學習一些更複雜的內容了。再次在同一個客戶列表的例子上展開，我將要爲你展示怎樣增加另一個銷售列到報表上。區別是這個列只有當這個客戶在美國時才會列印。這也意味著這個新列的小計和總計將只包括美國客戶的銷售額。

起初，你可能會以爲"這個簡單，我將使用邏輯性型的 Print When。"但是你只對了一半。試一下它，你將瞭解我的意思。使用剪切和粘貼來從細節帶區、組注腳帶區、和總結帶區複製所有的銷售額控制項，並且把新的副本放置到緊跟在原來的列的後面。爲包含于細節帶區中的新的銷售額的邏輯型的 Print When增加下列運算式∶

country = ' USA '

現在運行該報表，你多半會驚訝。該新的銷售額列只有當客戶在美國的時候才會列印--那就是你所需要的。但是該小計和總計還包括全部的客戶--而這不是你想要的。那是爲什麽呢？答案是那個邏輯性的 Print When做的只不過是它所說的那樣，它只控制什麽時候一個資料項目需要被列印。但不控制該資料項目是否用於計算。這是要記住的一件重要事情。許多新的程式師犯了這樣的錯誤，他們假定如果資料項目沒有被列印在報表上，它就不會包含在任何計算之內，而那與事實相去甚遠。

要有條件地在總計中包含資訊的話，你需要使用一個報告變數。給你的報表添加一個名爲" nUSASales "的新變數。在"要存儲的值"區域鍵入下列運算式∶

IIF ( country = ' USA ', sales, 0)

這一點告訴 FoxPro:如果這個記錄是在美國的，則爲銷售額設置變數。否則，它會把這個新的變數設置爲零。此外，在關閉報表變數對話方塊以前，請確保你選擇了在可用的計算列表下的None選項。在細節帶區、組帶區和總結帶區的每一新的銷售額欄位上雙擊，並把運算式" sales"改爲" nUSASales "。所有的Print When和計算資訊可以繼續保留。運行這個報表，該小計和總計將只反映美國客戶。

防止孤立的組

如果你一直仿照並運行了在下載文件中的示例報表或建立了如你所需的自己的報表，你也許已注意到，有時，一個新組開始于如此接近於一個新頁的底部的地方，以至於列印出來的結果或者沒有細節線條，或者在下一頁開始以前只有一條細節線。這看起來不是那麽專業，只因爲它坐在頁的底部看起來有點孤單。但是不要煩惱- FoxPro自帶的報表編輯器允許你在當有些多餘的空間時，強制該組從新的一頁開始。

在FoxPro 2.x中，在小的灰色正方形上雙擊--該說得更精確些是在該組標頭帶區的灰色條紋的左側。這會打開組資訊對話方塊。在該對話方塊中間，你將看到一條線條，它的意思是說："如果[ ______ ]小於標頭,則開始新的一頁。"在VFP中，從功能表欄選擇報表，並且從下拉功能表中選擇資料分組。這會打開資料分組對話方塊。在接近對話方塊底部的地方，你將看到一條線條，它的意思是說："當小於[ ______ ]時，從新的一頁上開始組。"

不管你是使用哪個版本就 FoxPro，鍵入你想要在一頁的底部留出的最小空間的尺寸。例如：如果單個細節線條有0.25 "高，而你想要列印至少二個線條，則在這個區域鍵入0.5 "。這告訴 FoxPro,當它開始一個新的組時，要檢查並確保在一頁的底部至少留出 0.5 "。如果沒有充足的位置，新的組將要從新的一頁開始。注意∶如果你的報表在組標頭帶區中有資訊，記住把組標頭的高度增加到你剛才計算的尺寸中去。

To be continued（待續）...

每當組包含於一個報表，並且你沒有選擇從新的一頁上開始每個組的時候，你就要冒著一個組交叉跨越兩個或更多頁的危險。有時這可能使讀報表的某人感到混淆，尤其是如果組標頭在每頁上被重復的情況。當看到第二頁的時候，一個讀者未必能意識到它是前一頁的延續。所以,因爲你是這樣一個負責的程式師，你會想要爲讀者提供一個表示報表是從前一頁延續的標誌。Heck，你是負責的程式師的話，當一個組將要延續到下一頁的時候，你甚至可能想在第一頁的底部指出它。

在頁的頂部列印 " continued.. ."

第一部分-當一個組是從前一頁延續的時候的標誌一可以相當輕而易舉的用一個報表變數來做到。從建立一個有基本資訊的客戶目錄報表開始，比如在細節帶區中的公司名稱、城市，和地區細節帶區等等。其次，建立一個在下列運算式上中斷的組∶

LEFT(comp_name,1)

爲了在組標頭帶區中添加一個帶著白體字的黑格來指示列印的是哪個字母，從添加一個矩形控制項開始。把這個矩形的填充色改爲黑色。下一步，在這個矩形的頂部添加一個帶著下列運算式的域控制項∶

LEFT(comp_name,1)

把域控制項的文本顔色改變爲白色、粗體，並且更改字體爲一個較大的數位。你現在應該有了一個在黑色矩形之上的白體字，就象一個電話號碼簿一樣。

要把"continued..."文本添加到這個標頭中去，你需要通過添加一個新的名爲"nGrpLines"的報表變數開始。把"要儲存的值"設置爲"1"，選擇統計選項，並把變數設置爲在組的末端重置。在那組標頭帶區，在矩形的邊上增加一新的域控制項。使用象下面那樣的運算式∶

IIF(nGrpLines = 0, '', 'continued ...')

最後一步是告訴報表編輯器在每頁的頂部列印組標頭，即使它沒有開始一個新組。這是通過檢查那個矩形來做到的，這個矩形表示"在後續的頁上重新列印標頭"（如果使用VFP，則是"在每頁上重新列印組標頭"）。你可以在你輸入尺寸以防止孤立的組的同一個對話視窗裏找到這個核取方塊（見前面的描述）。

就這樣運行這個報表，你將在每個組開始得到一個好看的矩形框和字母。和每當一組交叉跨越兩頁的時候，你將看相應的" continued…"資訊。

你可能會驚訝：爲什麽我用一個帶著IIF ()命令的域控制項，而不是一個TEXT控制和一些Print When邏輯條件來獲取列印" continued..."文本。對於這一點有一個很好的理由 -這個Print When邏輯條件不會工作!這種情況下，報表編輯器處理變數、組和Print When邏輯條件的次序無助於在組標頭中使用Print When。記住這個小消息，你可以爲你自己省下大量悲痛和惱怒。

在頁的底部列印" continued.. ."

當一個組跨越多頁時，在一頁的底部列印" continued.. ."標記不那麽容易。你可以用幾乎同樣的nGrpLines報表變數和概念來做到這件事，然而並非完全相同。當你在上頁的時候，你無法知道會碰到什麽情況。即使明顯地沒有延續，你也將在上頁的底部以" continued.. ."資訊結束。類似於我剛才提到關於Print When不能完全正常在組標頭中工作的消息，在頁腳的EOF ()同樣爲true。如果你所有要做的只是EOF（）就好了，但是，不幸地是，這個辦法在頁腳不頂用。

爲檢查文件的末尾，在運行這報告之前，你不得不使用一個設置在你的調用程式的變數。在調用你的報表的程式中輸入以下代碼（把它放在REPORT FORM命令之前）∶

* Get Last Record
PRIVATE nLastRec
GOTO BOTTOM
nLastRec = RECNO()

這段代碼將建立一個變數爲在你的表裏的上一個記錄的RECNO ()（基於當前的索引順序）。現在你知道上一個記錄號，你可以使用nGrpLines變數和你剛才建立的nLastRec變數來正確地決定何時列印continued資訊。調整頁腳的大小以能容納一個域控制項。增加一個帶著以下運算式的域控制項∶

IIF(nGrpLines > 0 AND NOT RECNO() = nLastRec, ;
'Continued on next page ...', '')

然後你將有一個在頁的頂部和底部列印適當的" continued.. ."資訊的報表，而你的用戶將爲你的服務周到而讚揚你！

強制一個組在一個"偶數"頁上結束

我可以想到你可能想要強制每個組從一個奇數頁開始、或從一個偶數頁開始、或者在一個奇數的頁結束、或者....的幾種不同的情況，好，你該瞭解概略的情況了。例如：當列印一本大型圖書時——就像報表，你可能想要在一個奇數頁上開始每個新"章"。或者，如果你是在列印一個雙面列印的報表，你可能想要確保每個新組從一頁的前面開始而不是上一頁的背面。

初看起來，用自帶的報表編輯器做到這一點幾乎不可能。但是用一點——不對，大量——的創造力，這個技巧是可以被發現的。波士頓的 nadya nosonovsky因爲這個tip而受到當之無愧的讚揚。當她面臨這種情況的時候，通過絕對的決心和毅力，她悟出了這個技巧並大方的發佈在 Universal Thread（譯者注：一個國外著名的VFP網站）上與別人共用。謝謝你，nadya !

在這個技巧後面的基本概念是你必須首先把報表列印到一個文件。當報表列印到文件的時候，你把僞記錄添加到這個報表以虛構必要的空白頁。一旦這這個虛擬的傳遞完成並且所有的虛構的空白記錄已經被添加，你可以預覽或者列印真正的報表了，並且你所有的組都將從正確的頁開始。我是將要爲你展示的是如何修改以前在" To be continued…"節描述的客戶目錄報表。與那個報表類似，這個報表有一個基於這個公司名稱的第一字母的組。然而，區別是這個報表的每個新字母將從一個奇數頁開始。

第一步將建立調用這個報表的程式。下面的代碼是列印這個報表的程式的完整列表。它看起來有點令人窒息，但是不必擔心——我將爲你解釋每個部分究竟是做什麽的。?

* 打開文件
SELECT 0
USE customer

* 建立臨時游標
PRIVATE cCursor
cCursor = SYS(3)
SELECT *, ;
' ' AS blnkpage, ;
0000 AS pageno ;
FROM customer ;
INTO CURSOR csrTemp
SELECT 0 USE DBF("csrTemp") again alias csrReport
USE IN csrTemp
SELECT csrReport
INDEX ON comp_name + blnkpage TAG SortOrder

* 初始化變數
PRIVATE nPageNo, bProcessing, cTemp
nPageNo = 0
bProcessing = .t.
cTemp = SUBSTR(SYS(2015), 3, 10) + '.txt'

* 處理報表
REPORT FORM vfpcust6 NOCONSOLE TO FILE &cTEMP
ERASE (cTemp)
bProcessing = .f.
WAIT CLEAR

* 預覽/列印報表
REPORT FORM vfpcust6 TO PRINTER PROMPT PREVIEW

* 關閉文件Close files
USE IN csrReport
SELECT customer
USE

****************** PROCEDURE BlnkPage ******************
* 如果這個頁不是偶數頁，在這個組後強制一個空白頁

IF bProcessing AND MOD(_PAGENO,2) <> 0 AND ;
blnkpage <> 'Y'
SCATTER MEMVAR BLANK
m.comp_name = comp_name
m.blnkpage = 'Y'
APPEND BLANK
GATHER MEMVAR ENDIF RETURN ''

****************** PROCEDURE IncrPage ******************
* 加大頁碼，並儲存這個記錄

IF NOT bProcessing AND pageno = 0
nPageNo = nPageNo + 1
REPLACE pageno WITH nPageNo
ENDIF
RETURN ''

代碼的第一部分打開客戶表，然後建立一個基於客戶表的游標。（在 VFP 7.0中的DBF功能使你不需要再次打開一個游標，因爲你可以建立一個可寫的游標了。）注意，當我建立新表的時候我給它添加了兩個額外的欄位。blnkpage欄位將被用來標記這個我添加的僞記錄，這樣我就會知道哪個記錄是用來強制一個空白頁的僞記錄。pageno欄位用來列印相應的頁碼（稍候我將做更多的解釋）。我還添加了一個索引，我將隨後解釋它。

下一步，我初始化我的變數。bProcessing變數是一個指出我是在運行第一個虛擬的傳遞過程處理資料還是運行真正的列印報表過程的標記。npageno變數將被用來在這個報表上列印頁碼。但是爲什麽我就是不使用 _pageno系統變數？這有一個很好的理由。爲了正確地利用這個技巧，你必須把這個組標記爲“每組的頁號重新從1開始”。我不希望我的報表中的每個組都從頁1開始。所以我將要使用這個變數,連同被加到這個表的 pageno欄位來建立我自己頁面計數器。要初始化的最後一個變數是當列印這個虛構報表時要使用的暫存檔案檔案名。

代碼下一部分列印報表到一個暫存檔案,然後刪除這個暫存檔案。當它完成時，它把 bProcessing標記設置爲.f.來指出它已經完成了處理。在一個應用程式産品中，在這個區域的代碼應該更複雜一點，以確保選擇了正確的印表機，並且我希望掩蓋" Printing..."對話方塊。在這個系列文章的過去部分裏我描述了如何做到這些的方法（查看 foxtalk 2001年二月刊裏的第二部分），因此在這裏我不再重復了。

一旦這個僞處理報表運行已完成，我就真正列印這個報表，然後關閉所有使用的文件。

那麽代碼的最後兩個過程是什麽目的呢？好的，duh--它們是用來在需要的地方強制一個空白頁。但是這個程式的任何地方都沒有調用它們呀，你說呢？非常仔細!它們被從這個報表本身所調用。我猜測我最好解釋一下這個。回到開頭並建立一個以客戶表爲基礎的報表。把公司名稱及你需要的其他欄位放入細節帶區。確保使用不帶別名的欄位名（記住，你是駕禦帶著一個游標的報表）。

下一步，建立一個基於公司名稱的第一個字母的組。如果你忘了，那麽這個運算式是 LEFT（comp_name，1）。一旦你已經建立這個組，選中相應的"從新的一頁上開始每個組"選項，並且爲每個組設置頁碼重置爲1。你可能還想讓組標頭在每個頁上重新列印。你可以給這個組標頭添加你想要的無論什麽資訊。我會推薦跟被用於" To be continued…"部分同樣的黑色矩形框和白體字。

現在,添加一個對 BlnkPage（）過程的調用。在VFP中，你通過在組注腳帶區的"出口處"部分添加以下運算式來做到這一點∶

BlnkPage()

在 FoxPro 2.6中，這有點棘手並且涉及一些更多的步驟。首先，向組注腳帶區添加一個域物件並使用與 VFP中同樣的運算式。在你已經添加這個域物件之後，選擇它並選擇"置後"選項。這保證這個常式是在這個細節帶區裏最後被處理的東西（以免你有在這個帶區裏其他的物件）。下一步，把這個組注腳帶區的高度改回爲0，這樣它不會在這個報表上佔據任何空間。否則，它可能影響虛構的頁被添加的途徑。

那麽這個對 BlnkPage（）的調用又是怎麽做的呢？儘管勒住你的馬--我將會告訴你的。遍閱代碼，你將會清楚的看到它所做的第一件事是判斷這個常式究竟是否需要被運行。第一個檢查是 bProcessing被設置爲true。我們僅想在這是報表的第一個虛擬過程的情況下運行這個常式--如果這個是真實的列印過程則不運行。檢查的下一步將是看看這個頁碼是否是偶數。如果它不是偶數，我們需要添加僞記錄來虛構一個空白頁。如果它是偶數，我們不需要爲這個組添加一個僞記錄。它檢查的最後一件事情是 blnkpage是否設置爲"Y"。如果是，這個意味著這已經是一個僞記錄了。因此，我們就不需要添加另一個了。

一旦你已經決定你確實需要添加僞記錄，回到開頭並做好它。從執行一個SCATTER MEMVAR BLANK來初始化和清除全部變數開始。下一步，把 M.COMP_NAME變數設置爲在當前記錄裏的那個，並把 M.BLNKPAGE變數設置爲" Y"。最後，把這個新記錄添加到臨時表上。這個新添加的記錄將被插入到你正在處理的記錄的後面。這是因爲索引是基於公司名稱和blnkpage欄位的。新的記錄有著同樣的公司名稱的值，但是BlnkPage欄位被設置爲"Y"，而在所有正常的記錄裏這個欄位的值都是空的。因此，這個新記錄將作爲需要放在這個組後面的虛構頁的控制器。

你可能是問爲什麽我使用一個字元" Y"而不是一個通常的".t ."。答案是：讓我更輕鬆一點。臨時表的索引運算式是comp_name + blnkpage。這樣，通過把新欄位做成一個字元型欄位，我不必爲這個索引做任何轉換。

剩下需要做的只有一件事情了，那就是處理頁面計數器。象我前面提到的那樣，你必須把這個報表設置爲每組的頁號重新從1開始。如果那正是你所希望的，那麽很好！不再需要其他的工作了。只管使用 _pageno系統變數來列印頁碼，你就全部設置好了。但是我是一個貪吃的人，作爲處罰，我將要爲你展示如何建立你自己的頁面計數器。

給頁標題帶區添加一個域物件（如果你還沒有做一個的話）並使用以下運算式∶

pageno

下一步，添加一個對加大頁面計數器的常式的調用。在VFP中，在頁標頭帶區的"入口"部分輸入以下運算式∶

IncrPage()

在FoxPro 2.x中，添加一個帶有前面運算式的域物件，然後選擇“置前”選項以允保證這是在這個頁標題中決定首先處理的事情。如果你不先完成這個，你很可能會以不正確的頁碼結束，並且你將開始迷惑這是爲什麽。原因是這是在頁碼常式被調用來正確的計算頁碼前的頁碼。

那麽IncrPage（）怎樣工作？很好，如果我確實自己這麽說了!把別的事情放在一邊，這裏就是它所做的：首先、它檢查來確保你不在運行僞處理操作。頁碼只會在真正的列印過程中設置。下一步是檢查這個記錄的pageno變數是否被設置爲零，因爲你僅想要在它還沒有被設置的情況下設置它。爲什麽？因爲我這樣說過了（你能說它遲到了嗎？）。

答案與預覽報表有關。比如，用戶可能會從第一頁開始預覽這個報表、然後跳到第10頁、然後跳到前一頁、然後跳到下一頁、然後跳回到第５頁、等等。如果你每次當一個頁被顯示的時候設置頁碼，你將以到處都不正確的頁碼結束。只有在首次一個頁被處理的時候設置頁碼，你才能保證頁碼的次序正確。

那麽回到 IncrPage（）過程。一旦你已經確定你應該增加頁面計數，就增加它並把它保存到當前記錄中去。

Whew（吹哨聲）!真是浩大的工程!但是當你面臨這種情況並且你的用戶要求每個組從一個奇數頁開始的時候，放心，這是辦得到的。只是確保你的用戶認識到他們將爲此而付出的代價。不僅你將要向他們收取昂貴的費用，而且報表的性能也將受到影響，因爲報表處理到文件一次棗而那是緩慢的棗然後才發送到印表機。

展望未來

知識就是力量!下月、我將爲你展示使用 FoxPro 報表編輯器的更多技巧和提示。幸運的是，我爲你展示的越多，你就會變得越強大。不久，所有 foxtalk 讀者都將變成爲軟體程式師群體裏的 Suppermen（和 Wonder Women）!我將要說“生化男人和女人”但那與我無關。如果你沒有聽到“na - nah, na - nah, na - nah, nah!”、並且在你讀到前面的句子的時候沒有看到 Lee 少校和 Lindsey Wagner 以慢動作在天邊偶遇，你就不像我那麽老！

Download 03POUNSC.ZIP