VFP 愛用者社區

Ruey · 註冊時間: 2003-03-12 文章: 1698 來自: tunglo 第 1 樓

接受VFP8中的集合
來源:童心未眠
http://childish.meibu.com/dvbbs/dispbbs.asp?boardID=84&ID=3954

作者：Andy Kramek & Marcia Akins
譯者：fbilo
Visual FoxPro 8.0 中新增的幾個基類極大的擴展了這個產品的功能。不過，如果從現有應用程式的角度來看，我們需要嘗試並判定是否真的需要用它們來代替已有代碼中的相應部分。其中一個新類就是“Collection（集合）”基類。在這個月的專欄中，Andy Kramek （以下簡稱安迪）和 Marcia Akins （以下簡稱瑪西婭）考察了一下到底什麼是集合類、它是怎麼工作的、以及它能在 Visual FoxPro 中為我們做些什麼。
瑪西婭：新年快樂，安迪，還有所有的讀者，也祝你們新年快樂。我們都希望新的一年將只帶給你好事兒！假期裏你是怎麼過的？
安迪：除了象往常一樣在吃喝玩樂以外，我在玩 8.0 Beta。它有許多非常酷的新東西，不過其中有一樣東西我不確定會有什麼好處，它就是“集合”。
瑪西婭：大多數的 Microsoft 產品都廣泛的使用集合——事實上，Visual FoxPro 裏沒有集合反而讓它顯得有些怪僻。
安迪：是的，不過到底集合是什麼東西呢？是否它就是陣列的一個花名？畢竟，我們在 Visual FoxPro 中已經有了你能夠想到的所有需要用來處理陣列的功能，如果你用過了今年早些時候我們討論過的那個類（見 FoxTalk 2002年2月刊中的《我們應該用好陣列》一文），你就能夠很輕鬆增強 VFP 在陣列的元素們、行、列中進行搜索的能力。
瑪西婭：好的，在 Visual Basic 的幫助中對集合的定義是：
“一個集合，是可以當作一個單元（unit）被引用的經過排序了的一套資料項目。”
幫助中還繼續指出，集合提供了一種簡易的“把一組相關的資料項目當作單個物件來引用”的途徑。總之，它指出集合最主要的好處是在一個集合中的資料項目（或者叫做“成員”）不需要是同一資料類型的。
安迪：我可以理解在 Visual Basic 中這是一個很大的好處，因為如果你把陣列定義為物件類型，那麼這是唯一讓陣列——或者集合——可以使用不同類型資料的辦法。我奇怪的是在 Visual FoxPro 中這麼做真的有好處嗎？我們本來就可以在陣列中使用混合資料類型了。
瑪西婭：是的，也許真的沒有這個好處。有趣的是，Visual FoxPro 幫助檔中對集合的定義卻是非常不同的：
“你可以把集合(Collection)用作將一系列相關的資料項目(Item)——通常它們是一些物件——分成一組，這些資料項目可以是任何類型的。集合提供了一種對存儲在容器中的物件們進行操作的機制，並且提供了一種訪問和疊代在一個集合中的物件們的途徑。集合類表現為一個真正的容器類，雖然它不像表單和頁框類那樣有 AddObject 方法。”
安迪：嗯，是的，它確實提供了一種不同的機制，不是嗎？既然你已經打開了幫助檔，那麼 Visual FoxPro 的集合類有哪些屬性、時間和方法呢？
瑪西婭：撇開那些所有類都會有的標準 PEMs （PEMs：指屬性、事件和方法）——BaseClass、Class、Init()、Error()、以及 Destory()等等——不談，我在表1中列出了其他專用的 Pems，並一併提供了一個簡要的解釋。
——————————————————————————————————————————
表1.集合類的屬性和方法
名稱類型解釋
Count P 在一個集合中包含資料項目的數量，自動維護。當集合為空的時候，Count = 0（注意：這個Count屬性是唯讀的）。
KeySort P 定義順序的一個數值型值。用於象使用 For Each...Next 迴圈來遍曆一個集合的情況。可用的值有：
0 （默認）按昇冪排列的資料項目索引值（1,2,3...n）
1 資料項目索引值按降冪排列(n...3,2,1)
2 資料項目的鍵（key）按昇冪排列（A,B,C...Z）
3 資料項目的鍵（key）按降冪排列（Z...C,B,A）
Add M 給集合添加一個資料項目(Item)。你可以給資料項目（Item）指定一個鍵（Key），也可以指定它在集合中相對於其他已有的資料項目的位置（之前或之後）。集合的Count屬性會自動增加。
Remove M 用指定的索引值從集合中刪除一個資料項目。集合的Count屬性會自動減小。（注意：你可以用GetKey()方法來返回一個知道名字的資料項目的索引值）
GetKey M 返回一個資料項目在集合中相應的索引值。如果給它傳遞一個數值型的值，則返回鍵（如果已經給資料項目指定了鍵的話）或者一個空字串。如果給它傳遞一個字元型值，則返回相應的資料項目的索引值或0。如果給它傳遞其他任何類型的值，則會彈出一個“函數變數的值、資料類型或者數量無效”的錯誤（錯誤號11）。
Item M 返回指定的集合成員（Collection member）。可以使用數值型的索引，也可以使用字元型的鍵。如果指定的資料項目不存在，會彈出一個“索引或運算式與集合的任一個成員不匹配”錯誤（錯誤號2061）。
安迪：我注意到一件事情：Keysort 的值是以 0 為基數的！這在 Visual FoxPro 中真是非常少見，通常我們總是用1到4而不是0到3來表示四個選項。我的意思是說，我們有五種緩衝模式（包括不打開緩衝），它們的編號是從1到5，象 SourceType、UpdateType 和 WhereType 這樣的屬性情況也與此類似，都是從1到n。
瑪西婭：是的，在 Visual FoxPro 的觀念中這的確有點怪異，不過以0為基數的情況在 COM 部件和 ActiveX 控制項中相當的常見。只要在物件流覽器中檢查任何類型庫，你都會看到大量這樣的情況。
安迪：很合理（雖然他這麼說，不過卻不是真的信服了）。那麼這個新的集合類有什麼好處呢？
瑪西婭：首先，讓我們先搞清楚一件事情：你能夠在 Visual FoxPro 中結合使用陣列和 Access/Assign 方法自己去實現集合。所以集合並不是什麼新鮮事物，只不過現在不需要你自己去寫代碼來實現集合了，現在它們是 VFP 自帶的。與陣列相比，集合主要有三個好處：
× Count 屬性是自動維護的。這樣我們就擺脫了重要的檢查陣列的長度、測試每一列以判定某一行是否為空的工作。
× 你可以用一個表示資料項目在集合中位址的索引值或者用一個有意義的鍵來指定資料項目，你可以根據自己的需要選擇哪種位址模式。
× 集合類有自帶的添加、刪除一個資料項目的方法。
安迪：那麼讓我們來比較一下。下面是一些代碼，它建立一個名為“fruits（水果）”的陣列，該陣列有四個元素：
Dimension afruits[4,2]
aFruits[1,1] = NEWOBJECT( 'Empty')
aFruits[1,2] = "Apples" && 蘋果
aFruits[2,1] = NEWOBJECT( 'Empty')
aFruits[2,2] = "Bananas" && 香蕉
aFruits[3,1] = NEWOBJECT( 'Empty')
aFruits[3,2] = "Cherriess" && 櫻桃
aFruits[4,1] = NEWOBJECT( 'Empty')
aFruits[4,2] = "Dansons" && 紫葡萄
瑪西婭: 而同樣效果的建立一個水果集合的代碼如下（順便問一句，什麼是 Dansons？）
oFruit = Newobject("collection")
oFruit.Add( Newobject( 'Empty' ), 'Apples')
oFruit.Add( Newobject( 'Empty' ), 'Bananas')
oFruit.Add( Newobject( 'Empty' ), 'Cherriess')
oFruit.Add( Newobject( 'Empty' ), 'Dansons')
安迪：Dansons 是一種小的紫色葡萄（我從它的名字來推測它可能通常是從大馬士革進口的）。我不得不說，你的代碼很簡潔。現在，讓我們再看看——我有兩種方法可以取得一個對我陣列中的 Cherries 物件的引用。第一種，如果我知道第3行第1列是 Cherry 物件的話，我可以直接訪問陣列的[3,1]元素。
loCherry = aFruits[3,1]
瑪西婭：很抱歉，實際情況中通常沒這麼樂觀。你難道會每次都準確的知道行號和列號？通常為了找到想要的資訊都會需要跟代碼奮鬥一番。不過，就事論事，用集合要這麼做也很簡單：
loCherry = oFruit.Item(3)
安迪：是的，所以通常我都是用 ASCAN() 來在第二列中搜索“cherries”這個名字，再返回行號。然後我就可以從這一行的第二列來獲得對該對象的引用，就像這樣：
lnRow = ASCAN( aFruits, 'cherries', -1, -1, 2, 15)
loCherry = aFruits( lnRow, 1)
(注意：如果你用的不是 VFP 7，那麼你就不能這麼做。不過為什麼你還沒用上 VFP 7.0？馬上升級吧！）
瑪西婭：很簡潔——你只需要記住你需要用兩個－1 來表示開始搜索的位置和要搜索元素的個數、一個 2 來限制在第2列中搜索、一個 15 表示執行的是大小寫不敏感搜索並且 Exact 為 ON，這樣就會返回找到的行號。不過我更喜歡象這樣用集合！
loCherry = oFruit.Item( 'Cherries' )
安迪：嗯！儘管這個鍵是大小寫敏感的，不過我還是開始同意你的意見了——這實在是簡單的太多了。
瑪西婭：OK，現在讓我們從我們的集合和陣列中分別刪除 Cherry 物件。你會怎麼做？
安迪：那很簡單，就是用 ADEL()。當然，我們首先需要取得要被刪除的資料項目的索引值，所以我們就需要有兩行代碼，象這樣：
lnRow = ASCAN( aFruits, 'cherries', -1, -1, 2, 15)
ADEL( aFruits, lnRow)
瑪西婭：可你並沒有刪乾淨！現在你的陣列中就會有一個空的列——你還需要重新定義一下這個陣列。
安迪：哦，是的，當然！所以完整的代碼應該是：
lnLen = ALEN( aFruits, 1)
lnRow = ASCAN( aFruits, 'cherries', -1, -1, 2, 15)
ADEL( aFruits, lnRow)
DIMESSION aFruits[ lnLen - 1, 2]
瑪西婭：而在集合中相應的代碼是這樣的：
oFruit.Remove( 'Cherries' )
Ta-da!
安迪：我服了！這個集合維護起來比陣列簡單的太多了。還有一些什麼我們可以做的嗎？
瑪西婭：是的。如果你傳遞一個索引值，GetKey() 方法會返回對應的鍵，就象這樣：
FOR lnCnt = 1 TO oFruit.Count
lcKey = oFruit.GetKey( lnCnt )
IF LOWER( lcKey ) = "damsons"
*** 忽略 damsons
ELSE
*** 處理所有其他的水果
ENDIF
NEXT
安迪：我想如果你知道鍵的話也可以用它來取得索引值（儘管我開始奇怪為什麼會有人操心這些），就象這樣：
lnIndex = oFruit.GetKey( 'Damsons' )
瑪西婭：不過，我們還沒有注意到集合類擁有的最重要的功能：它是一個 Visual FoxPro 的基類，所以你可以建立它的子類！這就意味著我們可以建立自己的集合類，並給它添加自定義屬性和方法。
安迪：那麼我想你會說的就是：不管你在舊代碼的什麼地方找到一個陣列，你都能把它替換成一個集合。但更重要的是，你可以把它替換成一個不僅能象陣列那樣存儲資料、還可以把處理陣列的代碼都集成起來的集合類。換句話來說，你能夠封裝一個陣列了。
瑪西婭：正確。這篇文章的附件包含了一個面向各種類型的檔的自定義集合類，它就做到了你說的那些事兒。類庫 colbase.vcx 包含一個根類（colfiles）和一些專用於 PRG 文件、表單和類庫的子類（colprgs、colforms 和 colvcxs）。
安迪：Cool。它是怎麼工作的？
瑪西婭：好，每個子類有四個需要你設置的自定義屬性，如表2
________________________________________________________
表2.自定義集合類的屬性
屬性解釋
cfiletype 在當前集合中的檔類型。定義在根類中的預設值都是（"*"）。在各個子類中指定相應的副檔名（例如 “PRG”、“SCX”、或者“VCX”）。
copencmd 用來從集合中打開一個檔的命令。預設值為空。如果什麼都沒有指定，當第一次調用 FileModify() 方法的時候會打開一個 Inputbox 讓你輸入必要的命令。
cruncmd 用來從集合中運行一個檔的命令。預設值為空。如果什麼都沒有指定，當第一次調用 FileRun() 方法的時候會打開一個 Inputbox 讓你輸入必要的命令。
laddquotes 當設置為 .T. 的時候會在運行 Modify 或者 Run 命令的時候在檔案名的兩端加上引號。預設值為 .F.。
安迪：我理解了。那麼，對於 colprgs 子類來說，唯一要做的就是設置 cFileType = "PRG"、cOpenCmd = "Modify Command"、cRunCmd = "DO"。我們不需要引號，所以可以把 lAddQuotes 保留為預設值。那麼關於這些類的方法有什麼要說的嗎？
瑪西婭：也只有一點點要做的東西，因為大多數需要的功能都已經由集合類自己做好了。剩下的就是封裝一些處理檔的專用方法了。表3列出了這些自定義方法：
———————————————————————————
表3.自定義集合類的方法
方法解釋
filesadd 從當前工作路徑中返回指定類型的文件和第一層子目錄，並把它們添加到集合中去。用到了 cFileType 屬性指定的檔概要。
fileslist 建立一個在集合中所有檔的列表，並用一個彈出功能表來顯示它們。選定的檔被保存到 cSelFile 屬性，以供 Run 和 Modify 方法使用。
filemodify 用 cOpenCmd 屬性中指定的命令打開 cSelFile 屬性中指定的檔。如果 cSelFile 為空，則調用 Fileslist() 方法。
filerun 用 cRunCmd 屬性中指定的命令運行 cSelFile 屬性中指定的檔。
makefileobj 這是一個受保護的方法，給它傳遞路徑和檔案名參數，它會返回一個將被添加到集合中去的檔物件。
安迪：就看看在 FilesAdd() 方法中的代碼吧，我看到它就是一段普通的 VFP 代碼，用 ADIR() 和本地陣列來建立一個當前目錄下檔的列表。MakeFileObj() 方法只是用到了 Empty 基類，並給它添加了一些基本的檔屬性：一個檔案名、路徑、檔類型、以及一個“RunAs”(就我所見，它只是把路徑和檔案名加起來而已)，然後返回 Empty 物件。我看到的唯一專用于集合的代碼就只有這一行：
This.Add( loFile, JUSTSTEM( lajunk[ lnFCnt, 1]) )
瑪西婭：東西就那麼多——loFile 是檔物件，而“lajunk”裏包含的是檔案名，我們用它來作為該檔物件在集合中的鍵，FileList() 方法也用到並會顯示這個鍵。那些都太簡單了。如你所見，大多數的代碼都是與構造彈出文件列表有關的東西。我們使用集合的 Count 屬性來控制功能表的生成過程，用 Getkey()方法來返回我們作為鍵儲存的檔案名。
LOCAL lnBar, lnCnt, lcName
PRIVATE pcSelFile
WITH This
DEFINE POPUP shortcut SHORTCUT RELATIVE
FROM MROW(),MCOL()
lnBar = 0
FOR lnCnt = 1 TO .Count
lcName = PROPER( .GetKey( lnCnt ))
lnBar = lnBar + 1
DEFINE BAR (lnBar) OF shortcut PROMPT (lcName)
ON SELECTION BAR (lnBar) OF shortcut
pcSelFile = PROMPT()
IF lnCnt < .Count
*** 給除了最後一項以外的所有功能表項添加一個起劃分作用的行
lnBar = lnBar + 1
DEFINE BAR (lnBar) OF shortcut PROMPT "\-"
ENDIF
NEXT
ACTIVATE POPUP shortcut
*** 把選擇保存到屬性裏
*** （注意：鍵名都是大寫的)
.cSelFile = UPPER( ALLTRIM( pcSelFile ))
ENDWITH
安迪：GetKey() 方法在這裏太有用了——跟操作一個陣列相比，它實在是太簡單了。當然，我們只是用那個鍵來獲得檔案名...還有別的地方要用到這個檔物件嗎？
瑪西婭：哦，是的，在 Run 和 Modify 方法裏。建立檔物件的理由，是我們可以直接訪問它的屬性。在 Modify 和 Run 方法裏我們從 cSelFile 屬性來獲得我們想要用到的檔的檔案名，然後使用這個集合的 Item() 方法來用鍵名來返回該物件本身。這樣我們就可以訪問它的任何屬性了：
*** 使用鍵名來返回檔物件
loFile = .Item( lcFile )
安迪：還有一個好處是，如果你需要的話，你可以把它建立為一個可視類。那麼要使用這個類來編輯我的程式檔的話，只需要做：
*** 建立檔集合
oPrgs = NEWOBJECT( 'colprgs', 'colclass.vcx' )
*** 添加當前目錄下的所有 PRG 檔和第一層子目錄
oPrgs.FileAdd()
*** 在一個功能表中顯示檔列表
oPrgs.FileList()
*** 編輯選中的檔
oPrgs.FileModify()
*** 運行選中的檔
oPrgs.FileRun()
*** 另選一個檔
oPrgs.FileList()
瑪西婭：代碼的順序是正確的，不過你並不需要顯式的調用 FileList() 方法——當你初次調用 Modify 或者 Run 方法的時候，系統會提示你選擇一個要操作的檔的。
安迪：非常簡潔。我相信你也可以不用集合類就做到這些事情，但我更確信有了集合事情就要簡單多了！希望你們在看了這篇文章以後也會象我一樣有著堅定的信心去升級到 Visual FoxPro 的最新版本。