 |
VFP 愛用者社區
本討論區為 Visual Foxpro 愛用者經驗交流的地方, 請多多利用"搜尋"的功能, 先查看看有無前例可循, 如果還有不懂的再發問. 部份主題有附加檔案, 須先註冊成為社區居民才可以下載.
|
| 上一篇主題 :: 下一篇主題 |
| 發表人 |
內容 |
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 1 樓
|
 發表於: 星期一 十一月 21, 2005 2:15 pm 文章主題: [原創]VFP 之 MOD() 函數改良 |
 |
|
這篇是由 http://fox.hanyu.com.tw/View.aspx?fbId=1&Id=33251 這主題所延伸出來的，本來沒想寫，誰知在假日翻譯說明檔及趕公司程式的狀況下，想換個心境就突然寫這個函數，有興趣的狐友幫我檢查看看，有問題請告知
| 代碼: |
oTest = CREATEOBJECT("VFPUFD")
? oTest.MOD(167.4,4.65)
? EMPTY(oTest.MOD(167.4,4.65))
? oTest.MOD(167.4,4.649)
? EMPTY(oTest.MOD(167.4,4.649))
DEFINE CLASS VFPUFD AS Session OLEPUBLIC
FUNCTION MOD(nDividend AS Number ,nDivisor AS Number) AS Number
* 函數說明：改良 VFP 原來 MOD() 函數隱藏餘數為零的問題。
* 作者：朱育興 YSC5096 2005/11/21
* ------------------------------------------------------------------------------------------- *
* 參數名稱 型態 說明
* ----------- ---- --------------------------------------------------------------------------
* InPut: (不做驗證，有問題就由 VFP 的錯誤機制自行處理)
* nDividend N 代表被除數。
* nDivisor N 代表除數。
* OutPut:
* nModulus N 1.代表餘數。
* 2.餘數介於零與除數之間的數，其小數位數與被除數一致(依四捨五入原則)。
* 3.若發生疑似(但實際不是)餘數為零的狀況時，其小數位數依實際結果顯示。
* ------------------------------------------------------------------------------------------- *
* 範例：
* oTest = CREATEOBJECT("VFPUFD")
*
* ? oTest.MOD(167.4,4.65) && 0.0
* *& VFP 的 MOD(167.4,4.65) 看起來是 0.0，但用 ROUND(MOD(167.4,4.65),15) 看就不是了，但實際上
* *& 它應該要等於 0.0 (VFP 在這裏應該沒處理好)
*
* ? EMPTY(oTest.MOD(167.4,4.65)) && .T.
* *& VFP 的 EMPTY(MOD(167.4,4.65)) 當然會得到 .F. (這裏當然就跟著錯了)
*
* ? oTest.MOD(167.4,4.649) && 0.036
* *& VFP 的 MOD(167.4,4.649) 看起來是 0.0，但用 ROUND(MOD(167.4,4.649),15) 看就不是了
*
* ? EMPTY(oTest.MOD(167.4,4.649)) && .F.
* *& VFP 的 EMPTY(MOD(167.4,4.649)) 誤打誤撞得到了 .F.
* ------------------------------------------------------------------------------------------- *
LOCAL nModulus AS Number
LOCAL W1_nDecimal AS Integer
* 初步取得餘數：VFP 自己算出來的餘數
nModulus = MOD(nDividend,nDivisor)
* 當餘數似乎看起來等於所謂的零時要做進一步處理 (這是 VFP 本身目前未處理好的部分)
W1_nDecimal = This.DECIMAL(nDividend)
IF EMPTY(ROUND(nModulus,W1_nDecimal))
nModulus = nDividend - INT(nDividend/nDivisor) * nDivisor
IF nModulus = 0 && 餘數是真正的零：讓餘數的小數位數與被除數一致 (依 VFP 的規定)
nModulus = ROUND(nModulus,W1_nDecimal)
ELSE && 餘數不是真正的零：讓餘數的正負值與除數一致 (餘數真正長得樣子)
IF SIGN(nDivisor)*SIGN(nModulus) < 0
nModulus = nModulus + nDivisor
ENDIF
ENDIF
ELSE
nModulus = ROUND(nModulus,W1_nDecimal)
ENDIF
* 傳回值
RETURN nModulus
ENDFUNC
HIDDEN FUNCTION DECIMAL(nNumber AS Number) AS Integer
* 函數說明：取得數值的小數位數
* 作者：朱育興 YSC5096 2005/11/21
* ------------------------------------------------------------------------------ *
* 參數名稱 型態 說明
* ----------- ---- -------------------------------------------------------------
* InPut:
* nNumber N 代表任意數值。
* OutPut: I 1.代表 nNumber 參數的小數位數是幾位小數。一般而言是非負整數。
* 2.如果 nNumber 參數不是數值，則以 -1 表示。
* ------------------------------------------------------------------------------ *
* 備註：
* 1.目前將小數中的後置零也算入小數位數中，若以後需要將後置零給排除後才取得小數
* 位數時，本函數就需多一個參數來處理。
* 2.本函數不適用 VFP 6.0 以前(含)版本：其問題目前是出在乘以 0.1 後，TRANSFORM
* 函數所表達的方式有時不是我所預期的樣子。
* ------------------------------------------------------------------------------ *
IF TYPE("nNumber") != "N"
RETURN -1
ELSE
RETURN LEN(TRANSFORM((nNumber-INT(nNumber/1)+1)*0.1))-AT(".",TRANSFORM((nNumber-INT(nNumber/1)+1)*0.1))-1
ENDIF
ENDFUNC
ENDDEFINE
|
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ
朱育興 在 星期三 十一月 23, 2005 12:50 pm 作了第 1 次修改 |
|
| 回頂端 |
|
 |
jeff25
註冊時間: 2004-10-22
文章: 76
來自: taiwan
第 2 樓
|
| 發表於: 星期一 十一月 21, 2005 6:05 pm 文章主題: |
|
|
>* ? oTest.MOD(167.4,4.649) && 0.036
> * *& VFP 的 MOD(167.4,4.649) 看起來是 0.0，但用 ROUND(MOD(167.4,4.649),15) 看就不是了
如果是 VFP 的 MOD(167.400,4.649) 就是 0.036 了
vfp 的 mod 是以第一個參數的小數位數為主,來取得餘數的小數位數
_________________
jeff |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 3 樓
|
| 發表於: 星期一 十一月 21, 2005 10:15 pm 文章主題: |
|
|
| jeff25 寫到: | >* ? oTest.MOD(167.4,4.649) && 0.036
> * *& VFP 的 MOD(167.4,4.649) 看起來是 0.0，但用 ROUND(MOD(167.4,4.649),15) 看就不是了
如果是 VFP 的 MOD(167.400,4.649) 就是 0.036 了
vfp 的 mod 是以第一個參數的小數位數為主,來取得餘數的小數位數 |
沒錯，但問題是您要如何知道任何一個數值要在其後面加多少個零才會避免掉這個問題，我舉的範例當然用眼睛看加測試是知道加兩個零就可以了；但對於其他任何數，我們是不可能都要一一這般處理，事實上也不可能，除非把所有狀況都列舉出來，但那又是一種不可能...
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
garfield
Site Admin
註冊時間: 2003-01-30
文章: 2160
第 4 樓
|
| 發表於: 星期一 十一月 21, 2005 11:14 pm 文章主題: |
|
|
如果能變成將有小數點的除數變成整數再來做mod 就正確了,
因為vfp是在有小數點時計算才會有問題,
例:
mod( 167.4 , 4.649 )
變成用
mod( 167.4* 10^3 , 4.649* 10^3 )
這樣是否就正確無誤了
_________________
利用>>搜尋<<的功能會比問的還要快得到答案. |
|
| 回頂端 |
|
|
freehotpc
註冊時間: 2005-03-27
文章: 28
第 5 樓
|
| 發表於: 星期二 十一月 22, 2005 12:02 am 文章主題: |
|
|
| garfield 寫到: | 如果能變成將有小數點的除數變成整數再來做mod 就正確了,
因為vfp是在有小數點時計算才會有問題,
例:
mod( 167.4 , 4.649 )
變成用
mod( 167.4* 10^3 , 4.649* 10^3 )
這樣是否就正確無誤了 |
mod( 167.4* 10^3 , 4.649* 10^3 )/10^3
那么只需在程序中判断被除数和除数的最大小数位就行了。 |
|
| 回頂端 |
|
|
jeff25
註冊時間: 2004-10-22
文章: 76
來自: taiwan
第 6 樓
|
| 發表於: 星期二 十一月 22, 2005 9:35 am 文章主題: |
|
|
>沒錯，但問題是您要如何知道任何一個數值要在其後面加多少個零才會避免掉這個問題，我舉的範例當然用眼睛看加測試是知道加兩個零就可以
>了；但對於其他任何數，我們是不可能都要一一這般處理，事實上也不可能，除非把所有狀況都列舉出來，但那又是一種不可能...
重點就是把兩個參數的小數位設成一樣就好了呀
a=167.4
b=4.649
? mod(a/1,b/1)
***---> 注意除以 1 這個動作
_________________
jeff |
|
| 回頂端 |
|
|
garfield
Site Admin
註冊時間: 2003-01-30
文章: 2160
第 7 樓
|
| 發表於: 星期二 十一月 22, 2005 10:31 am 文章主題: |
|
|
除以 1
程式是死的, 人是活的.
厲害 !!
_________________
利用>>搜尋<<的功能會比問的還要快得到答案. |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 8 樓
|
| 發表於: 星期二 十一月 22, 2005 11:56 am 文章主題: |
|
|
| jeff25 寫到: | >沒錯，但問題是您要如何知道任何一個數值要在其後面加多少個零才會避免掉這個問題，我舉的範例當然用眼睛看加測試是知道加兩個零就可以
>了；但對於其他任何數，我們是不可能都要一一這般處理，事實上也不可能，除非把所有狀況都列舉出來，但那又是一種不可能...
重點就是把兩個參數的小數位設成一樣就好了呀
a=167.4
b=4.649
? mod(a/1,b/1)
***---> 注意除以 1 這個動作 |
唉！你這是誤打誤撞得出答案來的；還有我是針對任意數字做處理的，而不是只有處理 MOD(167.4,4.649) 這單一案例而已
除以 1 這個動作只是湊巧矇到的 (你剛好只是因為餘數是從小數第二位不是零，和預設小數位數為 2 位)
若 a=16.74,b=0.4649 時 mod(a/1,b/1) 的答案是 0.00 而不是 0.0036
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
jeff25
註冊時間: 2004-10-22
文章: 76
來自: taiwan
第 9 樓
|
| 發表於: 星期二 十一月 22, 2005 3:37 pm 文章主題: |
|
|
> 唉！你這是誤打誤撞得出答案來的
別這麼說, 我可不是誤打誤撞得出答案來的,程式本來就是死的,就看你怎麼用,解法有許多種,巧妙各不同
小數是跟 set decimal 有關
如果你要精確到小數4 位
你可下 set decimal to 2 ( 不是 set decimal to 4 )
這樣
若 a=16.74,b=0.4649 時 mod(a/1,b/1) 就會 = 0.0036 了
_________________
jeff |
|
| 回頂端 |
|
|
freehotpc
註冊時間: 2005-03-27
文章: 28
第 10 樓
|
| 發表於: 星期二 十一月 22, 2005 4:46 pm 文章主題: |
|
|
| jeff25 寫到: | > 唉！你這是誤打誤撞得出答案來的
別這麼說, 我可不是誤打誤撞得出答案來的,程式本來就是死的,就看你怎麼用,解法有許多種,巧妙各不同
小數是跟 set decimal 有關
如果你要精確到小數4 位
你可下 set decimal to 2 ( 不是 set decimal to 4 )
這樣
若 a=16.74,b=0.4649 時 mod(a/1,b/1) 就會 = 0.0036 了 |
高！ |
|
| 回頂端 |
|
|
朱育興
註冊時間: 2003-08-25
文章: 661
來自: 台中市大里區
第 11 樓
|
| 發表於: 星期二 十一月 22, 2005 5:08 pm 文章主題: |
|
|
我了解，但對任何兩個 a 與 b 來說，一般來講它們是不定數，在程式裏面不可能寫死定出它應該精確到小數幾位，而 VFP 本身的 MOD() 並沒有什麼大錯，它只是在當餘數看起來似乎是 0 時，才發生了一些誤差
像 MOD(1674,4.65) 它的餘數應該要等於 0，但小數位數精確到小數點第 13 位時才會發現它開始不為 0，這是 VFP 處理上發生了問題，而且若判斷 MOD(1674,4.65)=0 時是 .T.，但 EMPTY(MOD(1674,4.65)) 時是 .F.
像 MOD(1674,4.649) 它的餘數應該要等於 0.36，但看到是它顯示 0，這是 VFP 遵循其 MOD 函數的規範：四捨五入到整數(因為此例的被除數是整數)，而且若判斷 MOD(1674,4.649)=0 時是 .F.，但 EMPTY(MOD(1674,4.649)) 時是 .F.
我的意思是說 MOD(1674,4.65) 與 MOD(1674,4.649) 得出都是 0，而
MOD(1674,4.65)=0 是 .T.
MOD(1674,4.649)=0 是 .F.
但
EMPTY(MOD(1674,4.65)) 是 .F.
EMPTY(MOD(1674,4.649)) 是 .F.
我的目的基本上尊重 VFP 對其 MOD() 函數的規範，只有當發生上述問題時，餘數該是 0 的就該是 0；
不該是 0 的卻因為受限位數的表達，而造成它表達成 0 (但實際它真的不是 0)，在這情況下，為了表達出該餘數的實際值，此時就沒遵守餘數與被除數的小數位數一致的規範；只要不是這情況，就應該遵守 VFP 的規範
_________________
希望有更多人來參與
VFP wiki - 需要大家一起完成的VFP電子書與FAQ |
|
| 回頂端 |
|
|
|
|
您 無法 在這個版面發表文章
您 無法 在這個版面回覆文章
您 無法 在這個版面編輯文章
您 無法 在這個版面刪除文章
您 無法 在這個版面進行投票
您 無法 在這個版面附加檔案
您 無法 在這個版面下載檔案
|
|
常見問題
搜尋
會員列表
會員群組
會員註冊
個人資料
登入檢查您的私人訊息
登入
