VFP 愛用者社區

[chinyu]

RowSourceType=0
RowSource=無
使用AddItem只能加到第一個column不知要如何加到第二column，又如何刪除與查詢呢？
請各位前輩指點一下。
謝謝

[小賴]

WITH THIS
.ColumnCount = 3
.ColumnWidths = "100, 100, 100"
.AddItem( 'Cleveland' )
.List[.NewIndex, 2] = 'Ohio'
.List[.NewIndex, 3] = '44122'
.AddItem( 'Caversham' )
.List[.NewIndex, 2] = 'England'
.List[.NewIndex, 3] = 'RG4 8BX'
.AddItem( 'Buffalo' )
.List[.NewIndex, 2] = 'New York'
.List[.NewIndex, 3] = '14228'
.AddItem( 'Milwaukee' )
.List[.NewIndex, 2] = 'Wisconsin'
.List[.NewIndex, 3] = '43225'
.AddItem( 'International Falls' )
.List[.NewIndex, 2] = 'Minnesota'
.List[.NewIndex, 3] = '42666'
ENDWITH


WITH This
.ColumnCount = 3
.ColumnWidths = "100, 100, 100"
.AddListitem( 'Cleveland' )
.AddListItem( 'Ohio', .NewItemID, 2 )
.AddListItem( '44122', .NewItemID, 3 )
.AddListItem( 'Caversham' )
.AddListItem( 'England', .NewItemID, 2 )
.AddListItem( 'RG4 8BX', .NewItemID, 3 )
.AddListItem( 'Buffalo' )
.AddListItem( 'New York', .NewItemID, 2 )
.AddListItem( '14228', .NewItemID, 3 )
.AddListItem( 'Milwaukee' )
.AddListItem( 'Wisconsin', .NewItemID, 2 )
.AddListItem( '43225', .NewItemID, 3 )
.AddListItem( 'International Falls')
.AddListItem( 'Minnesota', .NewItemID, 2 )
.AddListItem( '42666', .NewItemID, 3 )
ENDWITH


WITH This
.ColumnCount = 3
.ColumnWidths = "100, 100, 100"
.AddItem( 'Cleveland' )
.AddItem( 'Ohio', .NewIndex, 2 )
.AddItem( '44122', .NewIndex, 3 )
.AddItem( 'Caversham' )
.AddItem( 'England', .NewIndex, 2 )
.AddItem( 'RG4 8BX', .NewIndex, 3 )
.AddItem( 'Buffalo' )
.AddItem( 'New York', .NewIndex, 2 )
.AddItem( '14228', .NewIndex, 3 )
.AddItem( 'Milwaukee' )
.AddItem( 'Wisconsin', .NewIndex, 2 )
.AddItem( '43225', .NewIndex, 3 )
.AddItem( 'International Falls')
.AddItem( 'Minnesota', .NewIndex, 2 )
.AddItem( '42666', .NewIndex, 3 )
ENDWITH


以上第1與第2範例執行結果相同應是你所要
但是第三個範例使用AddItem而不是AddListItem
其結果是不同的請自行試用

[小賴]

補充刪除方法：

如果你要刪除其中一列則使用
RemoveItem方法例如
Thisform.List1.RemoveItem(2) && 刪除第二列

但是如果你要刪除的只是某列的某一Column
則使用如
Thisform.List1.List(2,2) = "" && 刪除第二列第二個Column
以上淺見請多指教

[chinyu]