VFP 愛用者社區

[garfield]

***************用windows API 來做 ini檔的寫入和讀取
*!* * test prg
*!* mfile='.\zz.ini' &&--請注意: 如果沒有加路徑名, 內定則會存到windows 目錄下
*!* msec ='區段名稱'
*!* mdata ='path'
*!* ? '>',writeFileIni(mfile,msec,mdata,'aaaaaa' ),'<'
*!* lcComputadora = ReadFileIni(mfile,msec , mdata )
*!* ? '=',lcComputadora,'='
*!* Return

Function writeFileIni(tcFileName,tcSection,tcEntry,tcWritedata)
Declare Integer WritePrivateProfileString ;
IN WIN32API ;
STRING lpAppName,;
STRING lpKeyName,;
STRING lpString,;
STRING tcFileName
RETURN WritePrivateProfileString(tcSection,tcEntry,tcWritedata,tcFileName)

********************
Function ReadFileIni(tcFileName,tcSection,tcEntry)
Local lcIniValue, lnResult, lnBufferSize
Declare Integer GetPrivateProfileString ;
IN WIN32API ;
STRING cSection,;
STRING cEntry,;
STRING cDefault,;
STRING @cRetVal,;
INTEGER nSize,;
STRING cFileName
lnBufferSize = 255
lcIniValue = Spac(lnBufferSize)
lnResult=GetPrivateProfileString(tcSection,tcEntry,"*NULL*",;
@lcIniValue,lnBufferSize,tcFileName)
lcIniValue=Substr(lcIniValue,1,lnResult)
If lcIniValue="*NULL*"
lcIniValue=.Null.
Endif
Return lcIniValue
*************garfield*********
Function deleteFileIni(tcFileName,tcSection,tcEntry)
RETURN writeFileIni(tcFileName,tcSection,tcEntry, null )
*************garfield*********
Function delSectionFileIni(tcFileName,tcSection)
RETURN writeFileIni(tcFileName,tcSection,null, null )

[garfield]